طلب دالة معرفة رقم الصف في اكسس

[أبو يحيى الجبلاوي]

السلام عليكم ورحمة الله وبركاته حياكم الله جميعا
هل يوجد دالة في اكسس تعطي رقم الصف كما هو الحال في برنامج اكسيل حيث توجد دالة row تعطيك رقم الصف 
فما هو بديل هذه الدالة في اكسس 

تم تعديل نوفمبر 13, 2018 بواسطه أبو يحيى الجبلاوي

[jjafferr]

وعليكم السلام

 

لو تشرح المطلوب بمثال ، فقد نستطيع مساعدتك بشكل افضل

 

جعفر

[أبو يحيى الجبلاوي]

في ١٤‏/١١‏/٢٠١٨ at 17:33, jjafferr said:

وعليكم السلام

 

لو تشرح المطلوب بمثال ، فقد نستطيع مساعدتك بشكل افضل

 

جعفر

السلام عليكم اخي جعفر 
على الاكسيل توجد هذه الدالة اسمها Row  تعطيك رقم الصف كما هو موضح بالصورة التالية :

 

هل يوجد دالة تقوم بنفس العملية في اكسس

تم تعديل نوفمبر 19, 2018 بواسطه أبو يحيى الجبلاوي

[jjafferr]

وعليكم السلام 🙂

 

نعم يوجد ، واسمه Recordset Absoluteposition ، وهذا شرح له من مايكروسوفت:

https://docs.microsoft.com/en-us/office/client-developer/access/desktop-database-reference/recordset-absoluteposition-property-dao

 

ولكني لا اعتقد بأنك تبحث عن هذا !!

اخبرنا لماذا كنت تريد ان تستعمل هذه الداله ، وماذا تريد استخراج من بياناتك؟

 

جعفر

[أبو يحيى الجبلاوي]

9 دقائق مضت, jjafferr said:

وعليكم السلام 🙂

 

نعم يوجد ، واسمه Recordset Absoluteposition ، وهذا شرح له من مايكروسوفت:

https://docs.microsoft.com/en-us/office/client-developer/access/desktop-database-reference/recordset-absoluteposition-property-dao

 

ولكني لا اعتقد بأنك تبحث عن هذا !!

اخبرنا لماذا كنت تريد ان تستعمل هذه الداله ، وماذا تريد استخراج من بياناتك؟

 

جعفر

حياك الله اخي جعفر سأجربها ان شاء الله 

 

انا احتاجها بوضعها بدالة iif الشرطية في حال كان الصف الاول يكتب اسم العملة الرئيسية والصف الثانية العملة رقم ٢ وهكذا فضمن الدالة احتاج لرقم الصف

جزيت خيرا اخي الفاضل

 

[jjafferr]

لازلت اعتقد بانه هناك طريقة اسهل للذي تريد الوصول اليه ،

لذا لوسمحت ارفق الموجود من بياناتك ، ثم اشرح لنا بالاكسل (من واقع بياناتك) النتيجة اللي تريد توصل لها 🙂

 

جعفر

[أبو يحيى الجبلاوي]

20 دقائق مضت, jjafferr said:

لازلت اعتقد بانه هناك طريقة اسهل للذي تريد الوصول اليه ،

لذا لوسمحت ارفق الموجود من بياناتك ، ثم اشرح لنا بالاكسل (من واقع بياناتك) النتيجة اللي تريد توصل لها 🙂

 

جعفر

ربي يكرمك انا اسف كان لازم حط شرح واضح للمطلوب من الاول 
تفضل اخي هذا ما اريده بالضبط صورة + ملف مرفق

 

 

test 2.accdb

 

[أبو يحيى الجبلاوي]

اتمنى منك اخي جعفر تطبقلي الحل على المثال سواءاً بالكود او بكود آخر وجزاك الله خيرا

تم تعديل نوفمبر 20, 2018 بواسطه أبو يحيى الجبلاوي

[jjafferr]

تفضل 🙂

 

انا لعبت في الجدول:

1. اضفت سجل ثم حذفته ، وبهذه الطريقة فقدنا التسلسل رقم 4 من حقل الرقم التلقائي ID ،
2. ثم اضفت سجل جديد لعملة جديدة وهي الريال العماني ،
3. ثم اضفت حقل Seq وهو لإدخال التسلسل اليدوي ، واردت التسلسل يكون هكذا :

.

على هذا الاساس ، عملت استعلامين:

الاول ليعطينا التسلسل حسب فرز الحقل ID ،

والثاني يعطينا التسلسل حسب فرز الحقل Seq :

.

والنتيجة:

.

والوحدة النمطية اللي تقوم بإرجاع البيانات مكتوبة هي :

Public Function Row_Number(N) As String

    'N = Number sent from the Query
    
    If Len(N & "") = 0 Then
        Row_Number = ""
        
    ElseIf N = 1 Then
        Row_Number = "العملة الرئيسية"
    
    Else
        Row_Number = "العملة رقم " & N
    
    End If
    
End Function

.

والتي يمكن استبدالها بوضع هذا الحقل الجديد في الاستعلام (طبعا حسب اسم الحقل) ، ولكني أفضل الوحدة النمطية لسهولة التعديل عليها :

Curr: IIf(Len([ID] & "")=0,"",IIf([ID]=1,"العملة الرئيسية","العملة رقم " & [ID]))

.

 

طيب لو اردت التسلسل (الفرز) يكون بإسم العملة ، فالطريقة الاولى لفرز الحقل ID لا ينفع ، ولم ارد استعمال الحقل Seq !!

 

فالطريقة تكون ، بأن نعمل تسلسل للإستعلام حسب حقل الفرز ،

وهناك عدة طرق لعمل هذا التسلسل ، ولكني أفضل هذه الوحدة النمطية:

       
Public Function RowCounter( _
  ByVal strKey As String, _
  ByVal booReset As Boolean, _
  Optional ByVal strGroupKey As String) _
  As Long
  
' Builds consecutive RowIDs in select, append or create query
' with the possibility of automatic reset.
' Optionally a grouping key can be passed to reset the row count
' for every group key.
'
' Usage (typical select query):
'   SELECT RowCounter(CStr([ID]),False) AS RowID, *
'   FROM tblSomeTable
'   WHERE (RowCounter(CStr([ID]),False) <> RowCounter("",True));
'
' Usage (with group key):
'   SELECT RowCounter(CStr([ID]),False,CStr([GroupID])) AS RowID, *
'   FROM tblSomeTable
'   WHERE (RowCounter(CStr([ID]),False) <> RowCounter("",True));
'
' The Where statement resets the counter when the query is run
' and is needed for browsing a select query.
'
' Usage (typical append query, manual reset):
' 1. Reset counter manually:
'   Call RowCounter(vbNullString, False)
' 2. Run query:
'   INSERT INTO tblTemp ( RowID )
'   SELECT RowCounter(CStr([ID]),False) AS RowID, *
'   FROM tblSomeTable;
'
' Usage (typical append query, automatic reset):
'   INSERT INTO tblTemp ( RowID )
'   SELECT RowCounter(CStr([ID]),False) AS RowID, *
'   FROM tblSomeTable
'   WHERE (RowCounter("",True)=0);
'
' 2002-04-13. Cactus Data ApS. CPH
' 2002-09-09. Str() sometimes fails. Replaced with CStr().
' 2005-10-21. Str(col.Count + 1) reduced to col.Count + 1.
' 2008-02-27. Optional group parameter added.
' 2010-08-04. Corrected that group key missed first row in group.

  Static col      As New Collection
  Static strGroup As String
  
  On Error GoTo Err_RowCounter
  
  If booReset = True Then
    Set col = Nothing
  ElseIf strGroup <> strGroupKey Then
    Set col = Nothing
    strGroup = strGroupKey
    col.Add 1, strKey
  Else
    col.Add col.Count + 1, strKey
  End If
  
  RowCounter = col(strKey)
  
Exit_RowCounter:
  Exit Function
  
Err_RowCounter:
  Select Case Err
    Case 457
      ' Key is present.
      Resume Next
    Case Else
      ' Some other error.
      Resume Exit_RowCounter
  End Select

End Function


Public Function Reset_RowCounter()

    Call RowCounter(vbNullString, False)
End Function

.

ثم ننادي هذه الوحدة النمطية من الاستعلام ، حتى تعطينا التسلسل ،

ثم نستعمل الوحدة النمطية السابقة لكتاية المطلوب:

.

 

ملاحظة:

الحقل الذي يكون محسوب ، ويتغير بإستمرار ، فإننا لا نحفظ قيمته في الجدول ،

لهذا السبب ، لم نستعمل الحقل N  ، ولم نحفظ قيمتها في الجدول 🙂

 

جعفر

988.test 2.accdb.zip

[أبو يحيى الجبلاوي]

جزاك الله خيرا وبارك الله فيك انا اريد كتابة بغض النظر عن ال id المهم انه السطر الاول هو العملة الرئيسية والباقي يكون العملة رقم 2 العملة رقم 3 وهكذا حتى لو كان id 100 وهو سطر 3 تكون العملة رقم 3

بكل الاحوال اجدت وشرحك واضح شكرا الك اخي الفاضل وتحياتي لفريق العمل في هذا المنتدى واتمنى ان اكون عنصر فاعل في منتداكم الرائع