كيفية منع التعديل على الملفات

[قيس111]

عندي ملف اكسل عامل عليه كود او مايكرو يمنع التعديل على بياناته ولكن تفاجأت بأن بالضغط على مفتاح كنترول CTRL تستطيع التعديل على اي ملف اكسل بالعربي ( تستطيع ايقاف عمل اي مايكرو في اي ملف اكسل  ) فأرجو من الخبراء بمساعدتي لكي امنع التعديل على الملفات.

 

 

[maxstreets]

أفضل حل تحول ملفك إلى ملف تنفيذي exe وتجعله للقراءة فقط والتعديل عن طريق رقم سري

[بن علية حاجي]

السلام عليكم

طريقة أخرى لعمل ذلك هي باستعمال خاصية "أدوات Tools" في أمر "حفظ باسم... Save As" (يمكن حفظه بالاسم نفسه أو باسم آخر) بعد وضع كلمة سرية للتعديل مع اختيار خاصية "للقراءة فقط"... والله أعلى وأعلم

ملاحظة: باستعمال هذه الخاصية الملف لا يفتح للتعديل إلا بإدخال الكلمة السرية أو يمكن فتحه للقراءة فقط (أي لا يمكن التعديل عليه)... 

بن علية حاجي 

[Ali Mohamed Ali]

تفضل هذا كود حماية المدخلات بمعنى يمكنك الإدخال مرة واحدة فى الخلايا ولا يمكن ولا يمكن التعديل على المدخلات الأولى

وهذا الكود يوضع فى حدث الورقة

Option Explicit
 Dim Old_value
 Dim New_value

 Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Old_value = Target.Cells(1, 1).Value
 End Sub
'==============================================
Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False
On Error GoTo Final_Step
If Intersect(Target, Range("A1:XFD10000")) Is Nothing Then GoTo Final_Step
   New_value = Target.Value
    If Target.Cells.Count > 1 Then
      Application.Undo
     GoTo Final_Step
    End If
    If Old_value = "" And Target.Cells.Count > 1 Then
     Application.Undo
     GoTo Final_Step
    End If
     If Old_value = "" Then
      Target.Value = New_value
      Else
     Application.Undo
    End If
Final_Step:
 Application.EnableEvents = True
End Sub

وهذا كود اخر لحماية الخلايا بعد المدخلات مباشرة بكلمة سر ويوضع ايضا فى حدث الصفحة -وكلمة السر هى 123

Private Sub Worksheet_Change(ByVal Target As Range)
Dim xRg As Range
On Error Resume Next
Set xRg = Intersect(Range("A1:XFD10000"), Target)
If xRg Is Nothing Then Exit Sub
Target.Worksheet.Unprotect Password:="123"
xRg.Locked = True
Target.Worksheet.Protect Password:="123"
End Sub

 

[Hamdi Edlbi-khalf]

إذا كنت تبحث عن طريقة لمنع التخريب الغير مقصود ففي الطرق التي أفادك بها الأخوة الحل 

أما إن كنت تخشى من كسر الحماية من قبل مخترق

الأوفيس لا يصلح لمثل هذه الحماية ...( أياً كان هذا البرنامج أكسس - إكسل - ورد ..... ) 

[قيس111]

أحتاج  الى كود يعطل أو يمنع استخدام زر Ctrl

 

أتمنى المساعده 

[Hamdi Edlbi-khalf]

أعتقد أنك ترغب بتعطيل الاختصارات التي تستخدم 

Ctrl

و حتى لو عطلت هذا المفتاح فإن الاختصار سيعمل ، عليك - في سبيل ذلك- عمل ماكرو لتعطيل الاختصار واحداً واحداً .

مثال  :

""  , "Application.onkey "^s

* لا أستطيع لصق الكود بالصورة المناسبة لأن الخيار الخاص بذلك لا يظهر حيث أستخدم الجوال .

[Ali Mohamed Ali]

تفضل اخى الكريم -هذا الكود للتعطيل

Sub Disable_Keys()
    Dim StartKeyCombination As Variant
    Dim KeysArray As Variant
    Dim Key As Variant
    Dim I As Long
    On Error Resume Next
    'Shift key = "+"  (plus sign)
    'Ctrl key = "^"   (caret)
    'Alt key = "%"    (percent sign
    'We fill the array with this keys and the key combinations
    'Shift-Ctrl, Shift- Alt, Ctrl-Alt, Shift-Ctrl-Alt
    For Each StartKeyCombination In Array("+", "^", "%", "+^", "+%", "^%", "+^%")
        KeysArray = Array("{BS}", "{BREAK}", "{CAPSLOCK}", "{CLEAR}", "{DEL}", _
                    "{DOWN}", "{END}", "{ENTER}", "~", "{ESC}", "{HELP}", "{HOME}", _
                    "{INSERT}", "{LEFT}", "{NUMLOCK}", "{PGDN}", "{PGUP}", _
                    "{RETURN}", "{RIGHT}", "{SCROLLLOCK}", "{TAB}", "{UP}")
        'Disable the StartKeyCombination key(s) with every key in the KeysArray
        For Each Key In KeysArray
            Application.OnKey StartKeyCombination & Key, ""
        Next Key
        'Disable the StartKeyCombination key(s) with every other key
        For I = 0 To 255
            Application.OnKey StartKeyCombination & Chr$(I), ""
        Next I
        'Disable the F1 - F15 keys in combination with the Shift, Ctrl or Alt key
        For I = 1 To 15
            Application.OnKey StartKeyCombination & "{F" & I & "}", ""
        Next I
    Next StartKeyCombination
    'Disable the F1 - F15 keys
    For I = 1 To 15
        Application.OnKey "{F" & I & "}", ""
    Next I
    'Disable the PGDN and PGUP keys
    Application.OnKey "{PGDN}", ""
    Application.OnKey "{PGUP}", ""
End Sub

وهذا لإرجاع الحال الى السابق والطبيعى اى لعمل الإختصارات مرة أخرى

Sub Enable_Keys()
    Dim StartKeyCombination As Variant
    Dim KeysArray As Variant
    Dim Key As Variant
    Dim I As Long
    On Error Resume Next
    'Shift key = "+"  (plus sign)
    'Ctrl key = "^"   (caret)
    'Alt key = "%"    (percent sign
    'We fill the array with this keys and the key combinations
    'Shift-Ctrl, Shift- Alt, Ctrl-Alt, Shift-Ctrl-Alt
    For Each StartKeyCombination In Array("+", "^", "%", "+^", "+%", "^%", "+^%")
        KeysArray = Array("{BS}", "{BREAK}", "{CAPSLOCK}", "{CLEAR}", "{DEL}", _
                    "{DOWN}", "{END}", "{ENTER}", "~", "{ESC}", "{HELP}", "{HOME}", _
                    "{INSERT}", "{LEFT}", "{NUMLOCK}", "{PGDN}", "{PGUP}", _
                    "{RETURN}", "{RIGHT}", "{SCROLLLOCK}", "{TAB}", "{UP}")
        'Enable the StartKeyCombination key(s) with every key in the KeysArray
        For Each Key In KeysArray
            Application.OnKey StartKeyCombination & Key
        Next Key
        'Enable the StartKeyCombination key(s) with every other key
        For I = 0 To 255
            Application.OnKey StartKeyCombination & Chr$(I)
        Next I
        'Enable the F1 - F15 keys in combination with the Shift, Ctrl or Alt key
        For I = 1 To 15
            Application.OnKey StartKeyCombination & "{F" & I & "}"
        Next I
    Next StartKeyCombination
    'Enable the F1 - F15 keys
    For I = 1 To 15
        Application.OnKey "{F" & I & "}"
    Next I
    'Enable the PGDN and PGUP keys
    Application.OnKey "{PGDN}"
    Application.OnKey "{PGUP}"
End Sub
 

أتمنى الإفادة بارك الله فيك 

[Hamdi Edlbi-khalf]

السلام عليكم بعد إذن الأخوة

هنا طلبك ... إن شاء الله

تعطيل كنترول.xlsm تعطيل معظم الاختصارات.xlsm

[قيس111]

الله يبارك فيك ويحفظك ويجزاك خير 

شاكر لك أخي مساعدتك .

الله يجزاك خير ويحفظك ويوفقك .

 

شاكر لك جهودك