جمع القيم الموجبة بشرط

[مراد الجزائر]

أريد الحصول على معادلة لجمع القيم الموجبةفقط بدلالة اليوم 

شكرا

Nouveau Feuille de calcul Microsoft Excel.rar

[سليم حاصبيا]

هذه المعادلة

=SUMPRODUCT(--($B$7:$B$21=$B$4),--($C$7:$C$21>0),$C$7:$C$21)

 

[محمد طاهر عرفه]

جرب المعادلة التالية كما فى المثال 

=SUMIFS($C$7:$C$21,$B$7:$B$21,B24,$C$7:$C$21,">0")

 

SumIFFs.zip

[مراد الجزائر]

السلام عليكم و رحمة الله تعالى و بركاته 

 

شكرا  على اجابتكما 

المعادلتان صحيحتان 

شكرا لكما

 

[مراد الجزائر]

 

السلام عليكم و رحمة الله تعالى و بركاته 

أريد الحصول على معادلة لجمع القيم الموجبة فقط بدلالة اليوم و العميل

 

شكرا

الجمع بدلالة القيمة الموجبة و العميل.rar

[shreif mohamed]

وعليكم السلام  و رحمة الله تعالى و بركاته 

لنفرض ان التاريخ موجود في الخلية 

b1

والعميل موجود في الخلية 

b2

تكن المعادلة 

=SUMPRODUCT(--($B$1=$B$7:$B$21)*--($B$2=$A$7:$A$21)*--($C$7:$C$21>0),$C$7:$C$21)

[محمد طاهر عرفه]

مرفق الحل بالطريفتين

=SUMPRODUCT(--($B$7:$B$21=B7),--($C$7:$C$21>0),$C$7:$C$21,--($A$7:$A$21=A7))

او

=SUMIFS($C$7:$C$21,$B$7:$B$21,B7,$C$7:$C$21,">0",$A$7:$A$21,A7)

مرفق المثال

الجمع بدلالة القيمة الموجبة و العميل.zip

[أ / محمد صالح]

أخي الكريم مراد

المثل يقول: لا تعطني سمكة ولكن علمني كيف أصطاد

وبالفعل قدم لك الأساتذة السمكة وفن الصيد لكن اعذرني

لم تحاول أن تجهد نفسك فيما قدموه

********

فشرح الدالة الأولى من الأستاذ سليم (سلمه الله من كل سوء)

=SUMPRODUCT(--($B$7:$B$21=$B$4),--($C$7:$C$21>0),$C$7:$C$21)

تعني جمع المدى الأخير c1:c21 إذا تحقق شرط تساوي النطاق من b7:b21 بقيمة الخلية b4 وكذلك بشرط أن تكون قيمة النطاق c7:c21 أكبر من صفر

ويمكنك أيضا إضافة الشرط الثالث بنفس الطريقة

بإضافة فاصلة ثم -- ثم المدى الذي به أسماء العملاء ثم = ثم الخلية التي بها العميل المطلوب

**************

وشرح دالة البشمهندس محمد (أعانه الله على فعل الخير)

=SUMIFS($C$7:$C$21,$B$7:$B$21,B24,$C$7:$C$21,">0")

تعني جمع المدى الأول ثم فاصلة ثم المدى الخاص بالتاريخ ثم فاصلة ثم شرط التاريخ وهكذا المدى ثم الشرط

وإن تعددت الشروط

=====

جرب وأخبرنا بالنتيجة

[محمد طاهر عرفه]

أجب أن أضيف أنه فى حالة استخدام * بدلا من الفاصلة يمكن الاستغناء عن ال -- 

=SUMPRODUCT(($B$7:$B$21=B7)*($C$7:$C$21>0)*$C$7:$C$21)

 

[سليم حاصبيا]

بالاضافة الى ما سبق

هذه المعادلة (Ctrl+Shift+Enter)

=SUM(IF(($B$7:$B$21=$B$4)+($C$7:$C$21>0)=2,$C$7:$C$21))