مطلوب كود فتح ملف من مسار اخر

[صلاح الصغير]

السادة الافاضل

 المطلوب كود ليفتح ملف فى مسار اخر و اذا كان مفتوح لاتظهر رسالة ان الملف مفتوح مسبقا و ليكن

d:new folder/salah/123.xls

 

تم تعديل يوليو 19, 2017 بواسطه صلاح الصغير

[صلاح الصغير]

عفوا هو اكثر من ملف فى اكثر من مسار

للتوضيح و السؤال مرة واحدة

[صلاح الصغير]

للرفع

[صلاح الصغير]

للرفع

[ياسر خليل أبو البراء]

السلام عليكم أخي صلاح

جرب الكود التالي

Sub OpenClosedWB()
    Const strInput  As String = "123.xlsx"
    Dim wbk         As Workbook

    On Error Resume Next
        Set wbk = Workbooks(strInput)
        If wbk Is Nothing Then
            Set wbk = Workbooks.Open(Filename:=ThisWorkbook.Path & "\" & strInput, ReadOnly:=True)
            If wbk Is Nothing Then
                MsgBox strInput & " Not Found!", vbCritical
                Exit Sub
            End If
        Else
            wbk.Activate
        End If
    On Error GoTo 0
End Sub

 

[صلاح الصغير]

و عليكم السلام اخى ياسر

هاجربه بعد الاجازة ان شاء الله 

بس انا كنت طالب لو فيه ملفات اخرى عايز افتحها

التعديل هيكون ازاى

و اسف للاطالة

[ياسر خليل أبو البراء]

لم أفهم النقطة التي تتكلم فيها .. ملفات أخرى بأي شكل 

الكود يتعامل مع ملف مغلق تحدد اسمه ومساره .. 

هل تقصد هذه الطريقة ؟؟!!

Private Declare Function SetCurrentDirectoryA Lib "kernel32" (ByVal lpPathName As String) As Long

Sub Test()
    Dim openFile    As Variant
    Dim wbk         As Workbook

    SetCurrentDirectoryA ThisWorkbook.Path & "\"
    openFile = Application.GetOpenFilename(FileFilter:="Excel Files (*.XLS*), *.XLS*", Title:="Select File To Be Opened")
    If openFile = False Then Exit Sub

    On Error Resume Next
        Set wbk = openFile
        If wbk Is Nothing Then
            Set wbk = Workbooks.Open(Filename:=openFile, ReadOnly:=True)
            If wbk Is Nothing Then
                MsgBox openFile & " Not Found!", vbCritical
                Exit Sub
            End If
        Else
            wbk.Activate
            ActiveWindow.WindowState = xlMaximized
        End If
    On Error GoTo 0
End Sub

 

[صلاح الصغير]

ا / ياسر

شكرا لاهتمامك كالعادة

طبعا انا مش عارف الفرق بين الكودين لانى مجربتش

بس انا كان قصدى ان فى اكثر من ملف فى اكثر من مسار اريد فتحهم مع الملف الاصلى

مثال للتوضيح

عندى ملف اسمه س

 عايز لما افتحه يفتح ملف ص و ع و ل

و لو فيه ملف مفتوح منهم ميحصلش مشكلة

و ليكن مثلا المسار كالاتى

d:/salah/ص.xls

d:/yasser/ع.xls

d:/salah/yasser/ل.xls

اتمنى اكون وضحت المطلوب

و شكرا

تم تعديل يوليو 22, 2017 بواسطه صلاح الصغير
edit

[ياسر خليل أبو البراء]

المطلوب قد يكون واضح بالنسبة لك ..لكن المشكلة أنك تتكلم بشكل عام مما يجعل من يريد المساعدة لا يدري من أين يبدأ ..

لابد من وضع معالم للطلب داخل الموضوع ..كن محدد الهدف BE SPECIFIC ...

ارفق مثال أو نموذج مصغر من بعض الملفات مع توضيح كيفية تريد تنفيذ طلبك .. وأين هي أسماء الملفات لديك هل هي في خلايا أم تريدها مدمجة بالأكواد؟ إلخ تلك الأسئلة التي ستطرح إذا كان الطلب بشكل عام

تقبل تحياتي

[صلاح الصغير]

ا / ياسر

اولا عذرا لعدم التوضيح و لكن بشكل عام سوف اوافيكم بالشكل المطلوب لاحقا 

و ردا على سؤال حضرتك افكارك دائما تعجبنى كنت اريد اسماء الملفات المراد فتحها مدمجة داخل الكود

و لكن حضرتك طرحت فكرة اجمل و أسهل للمستخدم و هى وضع اسماء الملفات داخل خلايا و ذلك لسهولة إضافة ملف في ما بعد و ممكن كمان نضع مسار الملف فى نفس الخانة بطريقة او اخرى

و اتمنى الموضوع اكون وصلته لحضرتك و يفيد الجميع

و شكرا

[ياسر خليل أبو البراء]

أنتظر نموذج مصغر للعمل عليه لكي تتضح الصورة أكثر وسأحاول في الموضوع قدر استطاعتي

[صلاح الصغير]

شكرا لسيادتك

ان شاء الله بيكون عندك يوم الاثنين

[صلاح الصغير]

ا / ياسر

عفوا ليس تحت يدى جهاز الان

و كيف ارسل مثلا فولدر به الملف الاصلى و ثلاثة ملفات اخرى و انا اريد فتح الملفات الثلاثة من اكثر من مسار مختلف كما زكرت

لو امكن حضرتك ترسلى كود و ليكن مثلا يتم تحديد او كتابة اسماء الملفات و مسارها فى ثلاث خلايه مع امكانية زيادة عدد الملفات و عند فتح الملف يتم قراءة هذه المسارات من الخلايا الثلاثة او اكثر و فتحها

[ياسر خليل أبو البراء]

أخي الكريم صلاح

أنا في معظم الوقت لا أعمل على التخمين لأنه لن يفيد .. قم بإرفاق ملف إكسيل فيه التصور الذي تتخيله مع بعض الملفات الوهمية .. ليس شرط الملفات الأصليه ..أي ملفات تكون بنفس الاسم والامتداد ولا يهم المضمون ... المهم الفكرة المطلوبة أنت تقوم ببلورتها في ملف لنفهم مقصدك

 

[صلاح الصغير]

اخى / ياسر

تمام حاضر غدا يكون عندك الملف و به شرح وافى ان شاء الله

[صلاح الصغير]

ا/ ياسر

اليك الملف

فتح ملفات من اكثر من مسار.rar

[ياسر خليل أبو البراء]

أخي الكريم صلاح

جرب الكود التالي ويمكن وضعه في حدث فتح المصنف .. أو كما ترغب فيما بعد

Sub OpenClosedWBs()
    Dim wbk         As Workbook
    Dim ws          As Worksheet
    Dim strInput    As String
    Dim i           As Long
    Dim p           As Long
    Dim lr          As Long
    
    Application.ScreenUpdating = False
        On Error Resume Next
            Set ws = ThisWorkbook.Sheets("Sheet1")
            For i = 2 To ws.Cells(Rows.Count, "H").End(xlUp).Row
                p = InStrRev(ws.Range("H" & i), "\") + 1
                strInput = Mid(ws.Range("H" & i), p)
                Set wbk = Workbooks(strInput)
        
                If wbk Is Nothing Then
                    Set wbk = Workbooks.Open(Filename:=ws.Range("H" & i))
                    If wbk Is Nothing Then
                        MsgBox ws.Range("H" & i) & " Not Found!", vbCritical
                        Exit Sub
                    End If
                End If
                
                With wbk.Sheets(1)
                    Range("B" & .Cells(Rows.Count, 2).End(xlUp).Row + 1).Activate
                End With
                
                Set wbk = Nothing
            Next i
        On Error GoTo 0
    Application.ScreenUpdating = True
End Sub

 

[صلاح الصغير]

ا / ياسر

شكرا لسرعة الرد

و لكن دائما يعطى رسالة not found

هل ممكن اكون انا بكتب المسار غلط

انا كتبت المسار بالكامل فى الخلية h2

و شكرا

تم تعديل يوليو 24, 2017 بواسطه صلاح الصغير
edit

[ياسر خليل أبو البراء]

تأكد من المسار الصحيح بالكامل مع اسم الملف بالامتداد 
..

[عبدللرحيم]

وضع ال / غلط 

صحتها

d:\salah\ص.xls

جزيل الشكر والعرفان للأستاذ الافاضل

المبدع دائما

ربنا يزيدك علما وحكمة

ولجميع الخبراء والاصدقاء اصحاب المنتدى العظيم 

جامعة أوفسينا 

تعلمنا منكم الكثير والكثير فى صمت وادب وحب

[صلاح الصغير]

ا / عبد الرحيم

ا/ ياسر

تم تصحيح المسار

و الملف يعمل بشكل جيد جدا

شكرااااا

[ياسر خليل أبو البراء]

الحمد لله أن تم المطلوب على خير والحمد لله الذي بنعمته تتم الصالحات ..

أين الإعجاب بالمشاركة الصحيحة واختيار أفضل إجابة ليكون مرجع لمن أراد البحث فيما بعد .. :)