كيفية فرز عدة أرقام في خلايا مختلفة

[شوارسكوف]

لدي جدول يحتوي على عدة خلايا

أرغب في فرز الأرقام التي بالخلايا تصاعدياً من الخلية الأولى (A1) حتى الخلية الأخيرة (D7)

في الجدول المرفق لدي عدد من الطلبة في صفوف دراسية ولكل طالب رقم تدر يبي وأرغب في ترتيب الطلبة في الفصل الواحد حسب أرقامهم التدريبية تصاعدياً

فهل من معاون ؟؟؟؟؟

وإن لم يكن فيكفيني مشاركتكم أحبائي فأنا من قدماء أعضائكم وأستفدت كثيرا من خبراتكم وبرامجكم

جعلها الله في موازين حسناتكم موقع المثال في البرامج المؤقته

[محمد حجازي]

السلام عليكم ...

هل يروق لك هذا التعديل (بالنسبة لطلبة الفصل الأول).

لقد توخيت البساطة في هذا التعديل ، ومن الممكن انجاز المهمة بطرق أكثر احترافية و تعقيداً مثل كود الفيجوال .

تحياتي

SALEH1.zip

[شوارسكوف]

(y)

أكيد يا أستاذنا محمد يروق لي هذا التعديل وخصوصاً أنه من شخص خبير و رائع مثلك

وإن كان هناك معادلة أخرى أو كود يقوم بترتيب كل جدول على حده في الصفحة الواحدة فأنا لا أستغني عن خبرتك .

دمتم لنا

[محمد حجازي]

السلام عليكم ...

جرب الكود التالي:

Sub Sort()
  On Error GoTo NoRange
  Dim MyRange As Range
  Dim MyData() As Double
  Dim i As Long
  Set MyRange = Application.InputBox(prompt:="أدخل مجال البيانات", Title:="مجال البيانات", Type:=8)
  If MyRange.Areas.Count > 1 Then
    MsgBox prompt:="يجب أن يكون المجال مؤلف من كتلة واحدة فقط", Title:="خطأ"
  ElseIf Application.WorksheetFunction.Count(MyRange) <> Application.WorksheetFunction.CountA(MyRange) Then
    MsgBox prompt:="يجب أن تكون البيانات عبارة عن أرقام فقط", Title:="خطأ"
  Else
    ReDim MyData(Application.WorksheetFunction.Count(MyRange) - 1)
    For i = 0 To Application.WorksheetFunction.Count(MyRange) - 1
      MyData(i) = Application.WorksheetFunction.Small(MyRange, i + 1)
    Next i
    MyRange.ClearContents
    i = 0
    For Each MyCell In MyRange.Cells
      MyCell.Value = MyData(i)
      i = i + 1
      If i > UBound(MyData) Then Exit Sub
    Next MyCell
  End If
Exit Sub

NoRange:
If Err = 424 Then
  Exit Sub
ElseIf Err = 9 Then
  MsgBox prompt:="المجال المحدد لا يحتوي على أرقام", Title:="خطأ"
Else
  MsgBox Err.Description
End If
End Sub

استخدم الكود السابق لفرز أرقام كل فصل على حدى.

بالتوفيق

Sort_Range.zip

[شوارسكوف]

الله ينور عليك ويسعدك ويعافيك وينفعك بعلمك ويفتح على قلبك يا محمد حجازي

الكود 100% يا خبير (y)

وصراحة محرج منك ما أدري كيف أستطيع شكرك ؟؟