شرح كود الترحيل الراسب والناجح الخاص ب الاخ رجب جاويش

[يثرب]

لم استطع تطبيق الشرح على الشيت الخاص بى و اريد ان اعرف ما اغيره فى كود الاخ رجب جاويش ليتناسب مع شيتى علما بان الشيت الخاص بى يبدأ المسلسل من a10 و الدرجات من i10 و كلنة راسب او ناجح تظهر فى الخلية bh10  و اخر الصفوف 300 و آخر خليه فى الشيت هى bh10

 و هذا هو كود الاخ رجب جاويش ارجو توضيح ما يجب تغييره ليتناسب مع الشيت الخاص بى و شكرا

sub ragab()

Dim lr As Integer, y As Integer

lr = [b10000].End(xlUp).Row

Sheets("ناجحون").Range("a9:ho1000").ClearContents

Sheets("راسبون").Range("a9:ho1000").ClearContents

Application.ScreenUpdating = False

x = 9: y = 9

For i = 9 To lr

If Cells(i, 3).Value = "ناجح" And Cells(i, 4) <> " " Then

Range("a" & i).Resize(1, 223).Copy

Sheets("ناجحون").Range("a" & x).PasteSpecial xlPasteValues

Application.CutCopyMode = False

x = x + 1

ElseIf Cells(i, 3).Value = "له دور ثان" And Cells(i, 4) <> " " Then

Range("a" & i).Resize(1, 223).Copy

Sheets("راسبون").Range("a" & y).PasteSpecial xlPasteValues

Application.CutCopyMode = False

y = y + 1

End If

Next i

MsgBox "تم بحمد الله فصل الناجحين والراسبين فى كشوف منفصلة", vbOKOnly, "ترحيل الناجحون والراسبون"

Application.ScreenUpdating = True

End Sub

[ابو عبدالبارى]

بالرجاء ارسال الملف الذى تعمل به حتى يتم التعديل علية وتكون الصورة اوضح

[يثرب]

هذا هو الشيت و شاكر لسرعة الردالرابع.rar

[ابو عبدالبارى]

1 ساعه مضت, yathreb said:

هذا هو الشيت و شاكر لسرعة الردالرابع.rar

الأخ العزيزyathreb

بعد التحية ارجو ان يفى الملف بالغرض

abo_abary_الرابع.rar

[يثرب]

اللهم اجعل هذا العمل فى ميزان حسناتك لا استطيع ان اوفيك حقك فى سرعة الرد و حل مشكلتى بارك الله لك فى رزقك و عافيتك

[ابو عبدالبارى]

الأخ العزيزyathreb

مشكور ولك بمثل ما دعيت به

[ياسر خليل أبو البراء]

الموضوع مكرر ؟؟؟!!!

[asdhamdey]

Sub Tarhil_Ragab()
    'تعريف المتغيرات
    Dim Sh As Worksheet
    Dim strSh As String
    Dim I As Long
    Dim AA As Long

    'سطر لإيقاف تحديث الشاشة
    Application.ScreenUpdating = False
    
        'مسح محتويات النطاق في ورقة العمل ناجح
        Sheets("ناجح").Range("A12:X1000").ClearContents
    
        'مسح محتويات النطاق في ورقة العمل دور ثان
        Sheets("دور ثان").Range("A12:X1000").ClearContents
    
        'مسح محتويات النطاق في ورقة العمل راسب
        Sheets("راسب").Range("A12:X1000").ClearContents
    
        'بدء التعامل مع ورقة العمل الأولى التي تعتبر الورقة الرئيسية
        With Sheet1
        
            '[Y] حلقة تكرارية بدايةً من الصف الـ 12 وحتى آخر صف به بيانات بالاعتماد على العمود
            For I = 12 To .Cells(10000, "Y").End(xlUp).Row
    
                '[Y] تعيين قيمة المتغير ليساوي قيمة الخلية في الصف المحدد في العمود
                'ففي أول حلقة تكرارية سيكون الصف هو رقم 12 [I] المقصود بالصف المحدد الصف الذي يحمل قيمة المتغير
                'وفي الحلقة التالية سيكون الصف رقم 13 وهكذا مع كل حلقة تكرارية يتغير الصف
                strSh = .Cells(I, "Y").Value
    
                'تعيين المتغير ليساوي آخر صف في الورقة التي سيتم الترحيل إليها
                'أو يمكنك القول معرفة رقم صف أول صف فارغ
                AA = Sheets(strSh).Cells(10000, 2).End(xlUp).Row + 1
    
                'إذا كان المتغير أقل من 12 الذي من المفترض أنه صف البداية لعمليات الترحيل فإنه يتم تعيين المتغير ليساوي 12
                If AA < 12 Then AA = 12
    
                'في حالة حدوث خطأ يتم تجنبه بهذا السطر
                On Error Resume Next
    
                'نسخ النطاق في الصف المحدد من العمود الثاني إلى العمود الرابع والعشرون
                .Range(.Cells(I, "B"), .Cells(I, "X")).Copy
    
                'لصق النطاق المنسوخ إلى ورقة العمل المناسبة واللصق يكون لصق قيم فقط
                Sheets(strSh).Range("B" & AA).PasteSpecial xlPasteValues
    
                'إلغاء خاصية النسخ واللصق
                Application.CutCopyMode = False
    
                'هذا السطر يقوم بترقيم الصف الذي تم ترحيله في الورقة الهدف
                'حيث يعتمد على إنقاص 11 من رقم الصف الحالي
                'فإذا كان الصف الحالي هو رقم 12 ألا وهو رقم البداية فإن الرقم
                'المسلسل سيكون 12 - 11 أي سيكون الرقم المسلسل 1
                Sheets(strSh).Cells(AA, "A").Value = Sheets(strSh).Cells(AA, "A").Row - 11
    
                'الانتقال للصف التالي في الحلقة التكرارية
            Next I
    
            'حلقة تكرارية لكل أوراق العمل لتحديد الخلية الأولى في ورقةالعمل
            For Each Sh In ThisWorkbook.Worksheets
                Application.Goto Sh.Range("A1")
            Next Sh
    
            'تنشيط ورقة العمل الأولى
            .Activate
    
        'انتهاء التعامل مع ورقة العمل الأولى
        End With
        
    'سطر لإعادة تفعيل اهتزاز الشاشة
    Application.ScreenUpdating = True

    'إظهار رسالة تفيد بانتهاء عمل الكود
    MsgBox "تم الفصل بنجاح", 64
End Sub