فرز الطلاب الذين يحملون علامة Faux في الخانة الأخيرة

[mourad76]

أنا مبتدىء في الإكسال أرجو من الأساتذة مساعدتي في فرز الخانة الأخيرة" faux "  و "x"

بحيث أستطيع محو خانة التلاميذ الذين يحملون علامة faux في الخانة الأخيرة

و جزاكم الله خير

Classeur1.rar

[ياسر خليل أبو البراء]

أخي الكريم مراد

أهلاً بك في المنتدى ونورت بين إخوانك

يرجى توضيح المطلوب أكثر .هل تريد فرز وترتيب ؟ أم تريد تصفية Filter ؟

وهل تريد حذف الصفوف التي تحتوي في الخانة الأخيرة faux أو x ؟ أم مجرد تصفية عادية ؟

يرجى إرفاق شكل النتائج المتوقعة لكي يسهل تقديم المساعدة من إخوانك بالمنتدى

تقبل تحياتي

 

[mourad76]

بارك الله فيك استاذنا الكريم أريد حذف الصفوف التي تحتوي على خانة faux

[ياسر خليل أبو البراء]

أخي الكريم مراد

يرجى تغيير اسم الظهور للغة العربية

إليك الكود التالي ..قف في أي خلية في الجدول الذي يحتوي البيانات ثم نفذ الكود

Sub FilterDeleteRows()
    Dim rTable As Range
    Dim rCol As Range, rCell As Range
    Dim lCol As Long, iRow As Long
    Dim xlCalc As XlCalculation
    Dim vCriteria
    
    On Error Resume Next
        With Selection
            If .Cells.Count > 1 Then
                Set rTable = Selection
            Else
                Set rTable = .CurrentRegion
            End If
        End With
    On Error GoTo 0
    
    If rTable Is Nothing Or rTable.Cells.Count = 1 Or WorksheetFunction.CountA(rTable) < 2 Then
        MsgBox "Could Not Determine Your Table Range.", vbCritical, "Exit Sub"
        Exit Sub
    End If
    
    '''''''''''''''''''''''''''''''''''''''''''''
    'الشرط
     vCriteria = "False"
     
    'رقم أول صف للبيانات
     iRow = 6
     
    'رقم العمود المراد فلترته
     lCol = 19
    '''''''''''''''''''''''''''''''''''''''''''''
    
    If lCol = 0 Then Exit Sub
    
    Set rCol = rTable.Columns(lCol)
    Set rCell = rCol.Cells(iRow, 1)
    
    With Application
        .Calculation = xlCalculationManual: .EnableEvents = False: .ScreenUpdating = False
    End With
    
        For lCol = 1 To WorksheetFunction.CountIf(rCol, vCriteria)
            Set rCell = rCol.Find(What:=vCriteria, After:=rCell, LookIn:=xlValues, LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False).Offset(-1, 0)
            rCell.Offset(1, 0).EntireRow.Delete
        Next lCol
    
    With Application
        .Calculation = xlCalculationAutomatic: .EnableEvents = True: .ScreenUpdating = True
    End With
End Sub

تقبل تحياتي

[mourad76]

بارك الله فيك استاذنا

[ا بو سليمان]

كم انت رائع 

 

وكم اتمني ان اتعلم كيف يتم وضع الاكواد  في صفحات الاكسل 

[ياسر خليل أبو البراء]

فيه موضوع في فهرس الموضوعات الخاصة بي اسمه بداية الطريق لإنقاذ الغريق

قم بالإطلاع عليه أخي الحبيب أبو سليمان لمعرفة البدايات التي يجب ان تعرفها للتعامل مع محرر الأكواد

تقبل تحياتي