تحسس الحروف الصغيرة والكبيرة في صلاحية المستخدمين

[وسيم الحمادة]

كيف احدد لمستخدم الدخول اذا ادخل البيانات باحرف كبيرة لايدخل للبرنامج

 

لازم يدخلها حسب جدول الصلاحيات 

 

يعني اذا كتب USER وكانت في الجدول user لايدخل للبرنامج

اظهار كلمة المرور.rar

[jjafferr]

وعليكم السلام ورحمة الله وبركاته

 

حيا الله من سألنا سؤال غير عن كل يوم 

 

الاكسس لا يفرق بين الحروف الكبيرة UpperCase/Ucase و LowerCase/LCase ، فلهذا السبب يجب ان نحل المسألة بطريقة اخرى.

 

هناك أكثر من طريقة لعمل المطلوب:

1. قراءة رقم كل حرف (انا احتفظ بالصورة الاولى ascii table في الرابط التالي ، وهي جدا مفيدة للمبرمج): http://www.asciitable.com/

من الجدول ، قيمة A = 65 ، بينما قيمة a = 97

جرب هذا الكود:

msgbox asc("A")
msgbox asc("a")

ففي هذه الحالة ، يجب ان نقارن قيم الاحرف بين القيمة في النموذج والتي في الجدول 

 

ومادمنا في سياق ascii table ، فترى اننا في بعض الاوقات في الكود ، عندما نريد استخدام الرمز " وقد يكون من الصعب استخدامه مباشرة ، فاننا نستخدم (chr(34 

 

2. طريقة نستخدم الامر StrComp وهو يقوم بمقارنة جملتين ، ولكن علينا التاكد باننا نقارن vbBinaryCompare ، مثل:

Comp_User = StrComp(rst!username, Me.username, vbBinaryCompare)

فاذا كانت النتيجة تساوي صفر ، فمعناه ان الجملتين متشابهتين 

 

هذا كود برنامجك للمقارنة:

Private Sub login_Click()

    If trycount > 2 Then
        MsgBox " من حُسن إسلام المرء تركه ما لا يعنيه ", vbOKOnly + vbMsgBoxRight + vbInformation, "تحذير "
        MsgBox " سيتم إغلاق البرنامج الآن ،،، يجب مراجعة المسؤول ", vbOKOnly + vbMsgBoxRight + vbInformation, "تحذير !"
        DoCmd.Quit
    End If

    Dim rst As DAO.Recordset
    
    Set rst = CurrentDb.OpenRecordset("Select * From users")
    rst.MoveLast: rst.MoveFirst
    RC = rst.RecordCount
    
    For i = 1 To RC
    
        If rst!depart = 1 Then
            Comp_User = StrComp(rst!username, Me.username, vbBinaryCompare)
            Comp_Pass = StrComp(rst!txtpassword, Me.txtpassword, vbBinaryCompare)
            
            If Comp_User = 0 And Comp_Pass = 0 Then
                MsgBox "مرحباً بك " & Me.username
                DoCmd.OpenForm "ادارة الجوازات", acNormal
                DoCmd.SelectObject acForm, "login2"
                Me.Visible = False
                Exit Sub
            End If
            
        End If
        rst.MoveNext
    Next i
    
    MsgBox "تاكد من صحة اسم المستخدم وكلمة المرور"
    trycount = trycount + 1
    
End Sub

وانا عملت المقارنة للحقلين username  و txtpassword 

 

 

جعفر

 

 

59.اظهار كلمة المرور.accdb.zip