طريقة ارسال الشيت عبر الايميل

[همام محمد أحمد]

الاساتذه الكرام

أريد طريقة لارسال الشيت عبر الايميل

سواء كان اكسل 2007 أو اكسل 2010

شاكرين لكم ومقدرين

[همام محمد أحمد]

فضلا لا امرا مساعدتي للضرورة

[حمادة باشا]

الأخ الكريم/ همام محمد أحمد

السلام عليكم ورحمة الله وبركاته

إذا كان القصد إرساله كمرفق عبر البريد الإلكتروني - فتختلف الطريقة حسب الموقع مستضيف الإيميل

مثال ياهو - جوجل - تقوم بإختيار Attach File/Attachment - يفتح لك نافذة تختار منها الملف

لرفعه من جهاز الكمبيوتر - تضغط موافق - أرسل الإيميل - تقبل تحياتي

[همام محمد أحمد]

أخي الفاض شكرا على تجاوبك

لكن ماقصدته انا ارسال جدول معين في ورقة الاكسل وليس الملف بأكمله

او ارسال ورقة واحده من الملف

وشكرا

[توكل]

Sub Mail_ActiveSheet()
'Working in Excel 2000-2013

    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim OutApp As Object
    Dim OutMail As Object

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set Sourcewb = ActiveWorkbook

    'Copy the ActiveSheet to a new workbook
    ActiveSheet.Copy
    Set Destwb = ActiveWorkbook

    'Determine the Excel version and file extension/format
    With Destwb
        If Val(Application.Version) < 12 Then
            'You use Excel 97-2003
            FileExtStr = ".xls": FileFormatNum = -4143
        Else
            'You use Excel 2007-2013
            Select Case Sourcewb.FileFormat
            Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
            Case 52:
                If .HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsx": FileFormatNum = 51
                End If
            Case 56: FileExtStr = ".xls": FileFormatNum = 56
            Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
            End Select
        End If
    End With

    '    'Change all cells in the worksheet to values if you want
    '    With Destwb.Sheets(1).UsedRange
    '        .Cells.Copy
    '        .Cells.PasteSpecial xlPasteValues
    '        .Cells(1).Select
    '    End With
    '    Application.CutCopyMode = False

    'Save the new workbook/Mail it/Delete it
    TempFilePath = Environ$("temp") & "\"
    TempFileName = "Part of " & Sourcewb.Name & " " & Format(Now, "dd-mmm-yy h-mm-ss")

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With Destwb
        .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
        On Error Resume Next
        With OutMail
            .to = "tawakoolah@gmail.com"
            .CC = ""
            .BCC = ""
            .Subject = "This is the Subject line"
            .Body = "Hi there"
            .Attachments.Add Destwb.FullName
            'You can add other files also like this
            '.Attachments.Add ("C:\test.txt")
            .Send   'or use .Display
        End With
        On Error GoTo 0
        .Close savechanges:=False
    End With

    'Delete the file you have send
    Kill TempFilePath & TempFileName & FileExtStr

    Set OutMail = Nothing
    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

[توكل]

أخي يمكنك إستعمال الكود السابق لإرسال صفحة واحدة من الملف وهذا الكود لا يعمل إلا من أوتلوك

[همام محمد أحمد]

أخي يمكنك إستعمال الكود السابق لإرسال صفحة واحدة من الملف وهذا الكود لا يعمل إلا من أوتلوك

 

فضلا اخي هل من الممكن ان تشرح لي أين وكيف اضع الكود لان لاخلفيه لدي تماما بهذه الامور

[توكل]

أخي الكريم في الملف الذي تود إرسال الصفحة منه قم بفتح محرر الفيجول بيزيك عن طريق الضغط على زر Alt + F11 وقم بإدراج ميديول جديد وإنسخ الكود إلى الموديول وبعد ذلك سيكون الكود جاهز للإستخدام و لا تنسى أن تغير عنوان البريد الإلكتروني في الكود للعنوان الذي تود إرسال الورقة إليه.

أرجو أن أكون وفقت في الشرح

[همام محمد أحمد]

اخي الفاضل يعطيني خطأ في السطر الاول مالمشكله

[همام محمد أحمد]

أرجو النظر ياساده والمعذره على الازعاج

[همام محمد أحمد]

فضلا لا امرا النظر في المشكله

حيث يعطيني خطأ في السطر الأول

[همام محمد أحمد]

لو تكرمتم ياساده مازال يعطيني خطأ في السطر الأول