كيفية تجنب اخطاء المعادلات

[فضل حسين]

الى خبراء واعضاء منتداى العزيز والعظيم

سلام الله عليكم ورحمته وبركاته

مرفق الملف الموضح به المطلوب

وجزاكم الله كل خير وبارك الله فيكم جميعا

New ورقة عمل Microsoft Excel.rar

[أ/حكيم]

قم بنسخ المعادلة من h6 الى أسفل مرة أخرى ... الخطأ أن المعادلة في h16  تشير إلى  c15   ... حسب مافهمت .

[فضل حسين]

الاستاذ الفاضل /حكيم

للاسف ليس هذا هو المطلوب وهذا ليس المقصود من طلبى . وقد يكون العيب عندى اننى لم اوضح المطلوب بشكل واضح او كافى .

ولكن دعنى اوضح المطلوب باكثر دقة

انا عندى ياسيدى معادلات كثيرة جدا فى الشيت من هذا النوع لجميع المواد ولعدد من الطلبة يتجاوز 600 أسم طالب

فأنا لااستطيع مراجعة هذة المعادلات كلها قبل الطباعة وأقوم بنسخ المعادلة الصحيحة مرة اخرى لباقى الخلايا  . لمعرفة ماهى المعادلة الى قرأت من المكان المضبوط .وماهى المعادلات التى قرأت بطريقة غير مضبوطه . 

فأنا اريد معادلة او كود فى حالة اما تكون المعادلة فى أى مكان بتقرأ خطأ . أعرف بمجرد النظر او بمجرد هذة المعادلة او الكود

الخطأ مباشرة ومعرفة مكان هذا الخطأ  بسهوله وأقوم فى ثوانى بضبط المعادلة . 

يارب تكون وصلت الفكرة

جزاك الله كل خير ياأستاذ حكيم

وشاكر جدا لردك واهتمامك

 

[بن علية حاجي]

السلام عليكم ورحمة الله

الاستاذ الفاضل /حكيم

للاسف ليس هذا هو المطلوب وهذا ليس المقصود من طلبى . وقد يكون العيب عندى اننى لم اوضح المطلوب بشكل واضح او كافى .

ولكن دعنى اوضح المطلوب باكثر دقة

انا عندى ياسيدى معادلات كثيرة جدا فى الشيت من هذا النوع لجميع المواد ولعدد من الطلبة يتجاوز 600 أسم طالب

فأنا لااستطيع مراجعة هذة المعادلات كلها قبل الطباعة وأقوم بنسخ المعادلة الصحيحة مرة اخرى لباقى الخلايا  . لمعرفة ماهى المعادلة الى قرأت من المكان المضبوط .وماهى المعادلات التى قرأت بطريقة غير مضبوطه . 

فأنا اريد معادلة او كود فى حالة اما تكون المعادلة فى أى مكان بتقرأ خطأ . أعرف بمجرد النظر او بمجرد هذة المعادلة او الكود

الخطأ مباشرة ومعرفة مكان هذا الخطأ  بسهوله وأقوم فى ثوانى بضبط المعادلة . 

يارب تكون وصلت الفكرة

جزاك الله كل خير ياأستاذ حكيم

وشاكر جدا لردك واهتمامك

أخي الكريم فضل 1، لا أعتقد (جازما) أن ما تريده (معادلة أو كود لتعرف مكان أو حتى المعادلة الخاطئة) متاح في أي نسخة من نسخ الإكسيل... لذا ما يجب فعله هو تصحيح المعادلات في السطر الأول (عند أول طالب) ثم نسخها إلى آخر طالب... يمكن (بعد تصحيح المعادلات لأول طالب) استعمال خاصية التسميات لهذه المعادلات مثل Formula1 لأول مادة، Formula2 للمادة الثانية وهكذا إلى آخر مادة... ثم القيام بنسخ هذه التسميات إلى الأسفل لآخر طالب أو يمكن أيضا إدراج المعادلات (أو نتائجها - قيمها) بطريقة تلقائية بواسطة كود ... والله أعلم 

 

أخوك بن علية

[الخالدي]

السلام عليكم ورحمة الله وبركاته

هنا محاولة للحل ارجو ان تنجح

الكود المرفق يقوم بتلوين خلايا المعادلات المختلفة وكل مجموعة بلون

Sub ALKHALEDI_اختلاف_المعادلات()
Dim Rn As Range, Cr As Byte
Set Rn = Intersect(Range([H6], Cells.SpecialCells(xlCellTypeLastCell)), [H:H])
Set Rn = Rn.SpecialCells(xlCellTypeFormulas, 23)
Rn.Interior.ColorIndex = 0
On Error GoTo Error:
For Cr = 3 To 56
    Set Rn = Rn.ColumnDifferences(Rn(1, 1))
    Rn.Interior.ColorIndex = Cr
Next
Error:
Set Rn = Nothing
End Sub

ارجو ان يكون المطلوب

في امان الله

اختلاف المعادلات.rar

[بن علية حاجي]

السلام علبكم ورحمة الله

 

السلام عليكم ورحمة الله وبركاته

هنا محاولة للحل ارجو ان تنجح

الكود المرفق يقوم بتلوين خلايا المعادلات المختلفة وكل مجموعة بلون

Sub ALKHALEDI_اختلاف_المعادلات()
Dim Rn As Range, Cr As Byte
Set Rn = Intersect(Range([H6], Cells.SpecialCells(xlCellTypeLastCell)), [H:H])
Set Rn = Rn.SpecialCells(xlCellTypeFormulas, 23)
Rn.Interior.ColorIndex = 0
On Error GoTo Error:
For Cr = 3 To 56
    Set Rn = Rn.ColumnDifferences(Rn(1, 1))
    Rn.Interior.ColorIndex = Cr
Next
Error:
Set Rn = Nothing
End Sub

ارجو ان يكون المطلوب

في امان الله

 

أخي الحبيب الخالدي، رائع روعة صاحبها، والله لم أكن أعرف أن ذلك ممكنا وأسحب اعتقادي الجازم، بارك الله فيك وجازاك الله خيرا وزادك الله من فضله...

ويبقى مشكل بسيط في عمل الكود (أرجو أن تنظر في إمكانية حله) وهو إن وُجدت في النطاق المعني بالمعادلة خلية فارغة (عند مسح المعادلة بالخطأ) أو كانت الخلية تحوي قيمة ثابتة (عددا أو غيره) فالكود لا يقوم بتلوين الخلية المعنية...

 

رغم هذا الخلل البسيط يبقى الكود رائعا... شكرا

 

أخوك بن علية

تم تعديل يناير 28, 2014 بواسطه بن علية حاجي

[فضل حسين]

ساحر الاكسل

حبيب قلبى الخالدى باشا

كالعادة ياحبيبى عمل رائع مبهر من شخصية متميزة رائعة  . أعمالك دائما تبهرنى وتسعدنى وتحسسنى دائما عندما اقرأ أسم الخالدى فى اى مشاركة أعرف اننى امام حلول غير تقليدية امام جمال وسحر وفن لساحر الاكسل ( الخالدى باشا ) وأن مع ساحر الاكسل لايوجد مستحيل مع  الاكسل . 

اسعدتنى كثيرا ياحبيبى بهذة المشاركة الجميلة مثلك . جزاك الله كل خير ياحبيبى وبارك الله فيك وزادك الله علما وتوفيقا . وامتعك الله بكل جميل كما تمتعنا .

حبيب قلبى ساحر الاكسل

كود رائع بلا نزاع او خلاف ويقوم بالمطلوب منه على اكمل وجه ولكن تبقى ملاحظات بسيطة ليكون كود كامل الاوصاف وبالفعل نتجنب اخطاء المعادلات .

1  -  وهو انا اريد ان يعطينى الكود لون ايضا فى حالة اما تعطينى المعادلة !value#

2  -  وكذلك ايضا عندما تعطينى المعادلة  !ref# 

3  -  وكذلك ملحوظة اخى واستاذى بن علية حاجى

انا عارف انى طماع أرجو ان تسامحنى فأنا ضعيف امام ساحر الاكسل وامام الابهار والجمال

كل الاحترام والتقدير لشخصكم الكريم وفى انتظار مزيد من الابهار والجمال كالعادة ياحبيبى

[الخالدي]

السلام عليكم ورحمة الله وبركاته

أخي الحبيب والعزيز بن علية

جزاك الله خيرا واتمنى لك تمام الصحة والعافية

كما تعلم الاكسل عالم كبير لا يمكننا الالمام بكله

تميز اختلاف المعادلات خاصية موجود بالاكسل اكتشفتها بالصدفة ويمكن الوصول اليها من اختيار اختلافات الصفوف او اختلافات الاعمدة في نافذة الانتقال الخاص

والخاصية تميز بين اختلاف النصوص وفي حال كان هناك معادلات تميز بين المعادلات المختلفة وان كانت متشابة في النتائج . ولهذا السبب الكود السابق  يعمل على الخلايا التي بها معادلات فقط حتى لا تختلط اختلافات النصوص مع اختلافات المعادلات

وجهة نظرك عن الخلايا الفارغة ومنشأ اسبابها صحيحة ومهمة والكود التالي يعمل ايضا على تلوين الخلايا الفارغة

Sub ALKHALEDI_اختلاف_المعادلات_والفراغات()
Application.ScreenUpdating = False
Dim Rn As Range, Cr As Byte
Set Rn = Range([H6], Cells(Rows.Count, "H").End(xlUp))
Rn.Interior.ColorIndex = 0
 'تلوين الخلايا الفارغة
On Error Resume Next
Rn.SpecialCells(xlCellTypeBlanks).Interior.ColorIndex = 3
On Error GoTo 0
 'تهاية اوامر تلوين الخلايا الفارغة
On Error GoTo Error:
Set Rn = Rn.SpecialCells(xlCellTypeFormulas, 23)
For Cr = 4 To 56
    Set Rn = Rn.ColumnDifferences(Rn(1, 1))
    Rn.Interior.ColorIndex = Cr
Next
Error:
Set Rn = Nothing
Application.ScreenUpdating = True
End Sub

في امان الله

اختلاف المعادلات والفراغات.rar

[الخالدي]

السلام عليكم ورحمة الله وبركاته

جزاك الله خيرا اخي الكريم/ فضل

وشكرا للثناء الطيب

بالنسبة للخلايا الفارغة تم اضافتها في كود المشاركة السابقة

وبالنسبة للبقية ربما لا استطيع اليوم تنفيذها بسب انقطاعات الكهرباء

ربما احد الاخوة يكمل ذلك

في امان الله

[الخالدي]

السلام عليكم ورحمة الله وبركاته

عذارا لتأخر الرد عليك اخي الكريم/ فضل

لتحقيق طلبك في اخر مشاركة اعرض عليك تعديلات يمكن ان تعملها على الكود السابق في مشاركتي الاخيرة لتختار منها ما يناسبك

لتلوين اختلاف المعادلات بدون ان يشمل التلوين اخطأ المعادلات عدل في الكود السابق الامر التالي

Set Rn = Rn.SpecialCells(xlCellTypeFormulas, 23)

عدل الرقم 23 الى رقم 7 بحيث يكون الامر بعد التعديل كالتالي

Set Rn = Rn.SpecialCells(xlCellTypeFormulas, 7)

واذا ترغب في ان يكون تلوين اختلاف المعادلات (كل الاختلافات عن اول معادلة) بلون واحد بدلا من تلوين كل اختلاف بلون مختلف . عدل في الكود السابق الاوامر التالية

Set Rn = Rn.SpecialCells(xlCellTypeFormulas, 23)
For Cr = 4 To 56
    Set Rn = Rn.ColumnDifferences(Rn(1, 1))
    Rn.Interior.ColorIndex = Cr
Next

عدلها الى امر واحد التالي

Rn.SpecialCells(xlCellTypeFormulas, 7).Interior.ColorIndex = 4

بالنسبة لأخطأ المعادلات

واذا ترغب في تلوين اخطأ المعادلات بلون مختلف عليك اضافة الامر التالي الى الكود السابق

Rn.SpecialCells(xlCellTypeFormulas, 16).Interior.ColorIndex = 5

اما اذا ترغب بتلوين اخطأ المعادلات مع تلوين كل خطأ بلون مختلف عليك بدلا من اضافة الامر السابق اضافة الاوامر التالية الى الكود السابق

For Each C In Rn.SpecialCells(xlCellTypeFormulas, 16)
C.Interior.ColorIndex = 5 + Application.Evaluate("ERROR.TYPE(" & C.Address & ")")
Next

ارجو ان يكون المطلوب

في امان الله

[الخالدي]

السلام عليكم ورحمة الله وبركاته

هنا كود اخر ربما يكون مفيد في المعادلات

الكود التالي يقوم بتلوين المعادلات في العمود H  والمرتبطة بالخلية D5

والكود يلون المعادلات المرتبطة بشكل مباشر بلون   و لون اخر مختلف للمعادلات  المرتبطة بشكل غير مباشر(غير مباشر مثلا المعادلة مرتبطة بخلية اخرى والخلية الاخرى مرتبطة بالخلية D5)

Sub ALKHALEDI_ارتباط_المعادلات()
Application.ScreenUpdating = False
Dim Rn As Range, C As Range
Set Rn = Range([H6], Cells(Rows.Count, "H").End(xlUp))
Rn.Interior.ColorIndex = 0
On Error Resume Next
Intersect(Rn, Range("D5").DirectDependents).Interior.ColorIndex = 3
For Each C In Intersect(Rn, Range("D5").Dependents)
If Intersect(C, Intersect(Rn, Range("D5").DirectDependents)) Is Nothing Then C.Interior.ColorIndex = 4
Next
Set Rn = Nothing
Application.ScreenUpdating = True
End Sub

ايضا وللفائدة الكود التالي يلون خلايا التحقق من الصحة في العمود H  ويلون كل مجموعة تحقق متشابه بلون مختلف عن مجموعات التحقق الاخرى

ويمكن استخدام الكود مع خلايا التنسيق الشرطي بعد تغير الخاصة في الكود من التحقق من الصحة الى خاصية التنسيق الشرطي

Sub ALKHALEDI_اختلافات_التحقق_من_الصحة()
Dim Rn As Range, RnA As Range, RnS As Range, Rnx As Range, C As Range
Dim Cr As Byte
Set Rn = [H:H]
Rn.Interior.ColorIndex = 0
On Error Resume Next
Set RnA = Intersect(Rn, Cells.SpecialCells(xlCellTypeAllValidation))
Set RnS = Intersect(RnA, RnA.SpecialCells(xlCellTypeSameValidation))
RnS.Interior.ColorIndex = 3
For Each C In RnA
If Intersect(C, RnS) Is Nothing Then
Cr = Cr + 1
Set Rnx = Intersect(RnA, C.SpecialCells(xlCellTypeSameValidation))
Rnx.Interior.ColorIndex = Cr + 3
Set RnS = Union(RnS, Rnx)
End If
Next
Set Rn = Nothing: Set RnA = Nothing: Set RnS = Nothing: Set Rnx = Nothing
End Sub

في امان الله