كيفية الربط بين برنامج أكسيس فى مكانين مختلفين

[waeelahmed]

أود مساعدتكم أخوانى فى طريقة تحل لى هذه المشكلة :

1- لدى برنامج يعمل فى عدة مخازن فرعية لشركة حيث يتم البيع مباشرة من خلال

المخزن الفرعى .

2- البرنامج الموجود بالشركة الرئيسية يحتوى على جدول لكل مخزن به الكميات المتوفرة

فى هذا المخزن.

كيف يمكننى تحديث الجدول الخاص بالمخزن الفرعى فى الشركة الرئبسية بطريقة سهلة جداً حيث من سيعمل على البرنامج غير محترف كمبيوتر .

أتمنى أن أكون أستطعت توضيح المشكلة ، وفى إنتظار مساعدتكم أخوانى الأفاضل

[أمجد جمالي]

السلام عليكم

تقصد بأنه يوجد قاعدتين بيانات الاولى في الفرع الرئيسي والثانية في الفرعي

طيب هل الفرع مربوطة مع الفرع الرئيسي وطرق الربط كثيرة منها ليز لاين او DSL

اذ كان نعم فالطريقة سهلة

تحياتي

[waeelahmed]

أخى (دبلوم غلبان) لابد أولاً أن يكون هناك شبكة بين الجهازين وأنظر إلى هذا الرابط

http://www.officena.net/ib/index.php?showtopic=561

[أمجد جمالي]

السلام عليكم

اعتذر اخواني عن تأخير بإرفاق ملف نظراً لضيق الوقت

اخ الكريم وليد هذا هو الكود

سوف ارفق الملف في القريب العاجل لكي اسهل عليك المهمة

تحياتي

Option Compare Database
Option Explicit

Public Const apErrInvalidSQL = -2147217900
Public Const apErrDBCorrupted1 = 3049

Public pstrAppPath As String
Public pstrBackEndPath As String
Public pstrBackEndName As String

Public intRepEdited As Integer

Public flgLeaveApplication As Boolean

Public Const apProvider = "Provider=Microsoft.Jet.OLEDB.4.0;"
Function ap_AppInit()
   
    Dim cnnLocal As New ADODB.Connection
    Dim rstSharedTables As New ADODB.Recordset
    Dim lngCurrError As Long, strCurrError As String
          
    DoEvents
    DoCmd.Echo True, "Checking Connections..."
   
    flgLeaveApplication = False
    
    Set cnnLocal = CurrentProject.Connection
    
    '-- Section 1: Initialize database properties
    ap_InitializeDBProps cnnLocal
    
    '-- Section 2: User requested to logout, quit the application
    If ap_LogOutCheck(pstrBackEndPath) Then
        Beep
        MsgBox "Maintenance is being performed on the backend" & vbCrLf _
             & vbCrLf & "All users are requested to log out at this time.", _
             vbOKOnly + vbCritical, "Logging Out for Maintenance"
        Application.Quit
        Exit Function
    End If
   
    '-- Section 3: Open the table containing the list of linked tables
        ' Open employee table.
    rstSharedTables.Open "tblSharedTables", cnnLocal, adOpenStatic
    
    On Error Resume Next
    
    rstSharedTables.MoveLast
    
    Dim rstTestTable As New ADODB.Recordset
    Dim strTableName As String
    
    strTableName = rstSharedTables!TableName
    rstTestTable.Open strTableName, cnnLocal, adOpenStatic
    
      
    lngCurrError = Err.Number
      
    If lngCurrError = 0 Then
        
        Dim varTest As Variant
        varTest = rstTestTable(0).Name
        lngCurrError = Err.Number
    
    End If
    strCurrError = Err.Description
    
    Do Until lngCurrError = 0

       On Error GoTo Error_ap_App_Init
      
        
       Select Case lngCurrError
         
         Case apErrInvalidSQL
         
         
            '-- Section 4: If the Data MDB is found in the App Directory,
            '--            link the files.
               
             If Dir(pstrAppPath & "\" & pstrBackEndName) = pstrBackEndName Then
                 
                ap_LinkTables rstSharedTables, pstrAppPath & "\" & _
                               pstrBackEndName
                pstrBackEndPath = pstrAppPath & "\"
                 
             Else
            
                '-- Section 5: Allow the user to locate the BackEnd MDB
                If Not ap_LocateBackend(rstSharedTables, _
                       strCurrError) Then
                   flgLeaveApplication = True
                End If
             
             End If
              
         Case apErrDBCorrupted1
            
            '-- Section 6: Backend Corrupted. Repair?
            Beep
            
            If MsgBox("The Backend Database is Corrupted." & vbCrLf & _
               vbCrLf & "Would you like to log users out and " & _
               " attempt to compact/repair it?", vbYesNo + vbCritical, _
               "Corrupted Backend!") = vbYes Then
                
               DoCmd.OpenForm "ap_CompactDatabase", acForm
                
            Else
               
               flgLeaveApplication = True
            
            End If
          
       End Select
       
       '-- Section 7: Leave the application if requested
       If flgLeaveApplication Then
          Application.Quit
          Exit Function
       End If
       
       On Error Resume Next
       
       '-- Section 8: Let's try and open the first table again.
       rstTestTable.Open strTableName, cnnLocal, adOpenStatic
       lngCurrError = Err.Number
       strCurrError = Err.Description
       
    Loop
      
    On Error GoTo Error_ap_App_Init
     
    '-- Section 9: Check the version of the front end,
    '--            and point to a new one if necessary.
    If Not CheckFEVersion() Then
        Application.Quit
    End If
      
    '-- Section 10: Save the BackEnd path in the BackEndPath property
    '--             for future use.
    ap_SetDatabaseProp "LastBackEndPath", pstrBackEndPath
      
    '-- Check for locally logged errors
    ap_ErrorCheckLocal

    '-- Check for Replicated Tables
    ap_CheckReplicatedTables
        
    '-- Turn on the Monitor Form
    DoCmd.OpenForm "UserLogOutMonitor", , , , , acHidden
    
    DoCmd.Close acForm, "SplashScreen"
    DoCmd.Echo True
    rstSharedTables.Close
   
Exit_ap_App_Init:
   Exit Function
    
Error_ap_App_Init:
   Beep
   MsgBox "The following error occurred: " & Err.Description & vbCrLf & _
           vbCrLf & "The system will now be closed down!"
   Application.Quit

End Function


Sub ap_InitializeDBProps(cnnLocal As ADODB.Connection)
       
    Dim rstDBProps As New ADODB.Recordset
    
    rstDBProps.Open "ztblDatabaseProperties", cnnLocal
           
    pstrAppPath = CurrentProject.Path
    pstrBackEndName = rstDBProps!BackEndName
    pstrBackEndPath = rstDBProps!LastBackEndPath
    
    rstDBProps.Close
    
End Sub

Function ap_LogOutCheck(strBackEndPath) As Integer
   
   On Error Resume Next
   ap_LogOutCheck = Dir(strBackEndPath & "LogOut.FLG", vbHidden) = "LogOut.FLG"
   
End Function

Function ap_FormIsOpen(strFormName As String) As Integer

   Dim frmCurrent As Form
   
   For Each frmCurrent In Forms
      If frmCurrent.Name = strFormName Then
         ap_FormIsOpen = True
         Exit Function
      End If
   Next frmCurrent
   
End Function


  Function ap_GetDatabaseProp(strPropertyName As String) As Variant
   
      Dim rstDBProps As New ADODB.Recordset
    
      rstDBProps.Open "ztblDatabaseProperties", CurrentProject.Connection, adOpenDynamic, adLockOptimistic
         
      ap_GetDatabaseProp = rstDBProps(strPropertyName)
      
      rstDBProps.Close
      
   
End Function
Sub ap_SetDatabaseProp(strPropertyName As String, varValue As Variant)
   
    Dim rstDBProps As New ADODB.Recordset
    
    rstDBProps.Open "ztblDatabaseProperties", CurrentProject.Connection, adOpenDynamic, adLockOptimistic
        
    rstDBProps(strPropertyName) = varValue
    
    rstDBProps.Update
    rstDBProps.Close
   
End Sub


Public Sub ap_LinkTables(rstSharedTables, strDataMDB As String)
    
    Dim catCurr As New ADOX.Catalog
    
    Dim intTotalTbls As Integer
    Dim intCurrTbl As Integer
    Dim strCurrTable As String
    On Error GoTo Err_LinkTables
    
    '-- Get the total number of linked tables, then display the progress meter.
    rstSharedTables.MoveLast
    intTotalTbls = rstSharedTables.RecordCount
    rstSharedTables.MoveFirst
    
    SysCmd acSysCmdInitMeter, "Linking Tables....", intTotalTbls
    
    catCurr.ActiveConnection = CurrentProject.Connection
        
    intCurrTbl = 1
    Do Until rstSharedTables.EOF
            
        '-- Update the progress meter
        SysCmd acSysCmdUpdateMeter, intCurrTbl
        
        '-- Attempt to open the current link
        On Error Resume Next
        
        strCurrTable = rstSharedTables!TableName
        catCurr.Tables.Delete strCurrTable
        catCurr.Tables.Refresh
        
        On Error GoTo Err_LinkTables
        
        Dim tblCurr As New ADOX.Table
        Set tblCurr.ParentCatalog = catCurr
    
        
        tblCurr.Name = rstSharedTables!TableName
            
        tblCurr.Properties("Jet OLEDB:Link Datasource") = strDataMDB
        tblCurr.Properties("Jet OLEDB:Create Link") = True
        tblCurr.Properties("Jet OLEDB:Remote Table Name") = rstSharedTables!TableName
            
        catCurr.Tables.Append tblCurr
        
        Set tblCurr = Nothing
        
        rstSharedTables.MoveNext
        intCurrTbl = intCurrTbl + 1
        
    Loop
    
Exit_LinkTables:

    SysCmd acSysCmdRemoveMeter
    
    Exit Sub

Err_LinkTables:
    
    Resume Exit_LinkTables


End Sub

Public Sub ap_LogOutRemove()
    
    On Error Resume Next
    
    SetAttr pstrBackEndPath & "LogOut.FLG", vbNormal
    Kill pstrBackEndPath & "LogOut.FLG"

End Sub

Public Sub ap_LogOutCreate()
    
    On Error Resume Next
    
    '-- Create flag file
    Open pstrBackEndPath & "LogOut.FLG" For Output Shared As #1
    Close #1
    SetAttr pstrBackEndPath & "LogOut.FLG", vbHidden

End Sub

Public Function ap_LocateBackend(rstSharedTables, strCurrError) As Boolean
    
    Dim ocxDialog As Object
    
    ap_LocateBackend = True
    
    DoCmd.Echo True
    Beep
    
    If MsgBox("A problem has occurred accessing the linked tables." & _
         vbCrLf & vbCrLf & "The error was: " & strCurrError & vbCrLf & _
         vbCrLf & "Would you like to locate the backend?", vbCritical + _
         vbYesNo, "Error with Backend") = vbYes Then
       
       Dim strFileName As String
       strFileName = ap_OpenFile(pstrBackEndName, "Locate backend database")
        
       If Len(strFileName) <> 0 Then
          DoEvents
          ap_LinkTables rstSharedTables, strFileName
          pstrBackEndPath = Left$(strFileName, _
                                InStrRev(strFileName, "\"))
             
       Else
    
          ap_LocateBackend = False
           
       End If
        
    Else
       
       ap_LocateBackend = False
    
    End If
    
Exit_ap_LocateBackend:
    Exit Function
    
Error_ap_LocateBackend:
    ap_LocateBackend = False
    Resume Exit_ap_LocateBackend

End Function

Sub ap_CheckReplicatedTables()

   Dim catLocal As New ADOX.Catalog
   Dim rstCheckRep As New ADODB.Recordset
   Dim cmdUpdateRep As New ADODB.Command
   Dim strTableName As String
      
   On Error GoTo Error_ap_CheckReplicatedTables
      
   Set catLocal.ActiveConnection = CurrentProject.Connection
   
   DoCmd.Echo True, "Checking for Replicated Tables..."
   
   '-- Attach the backend replicated table
   '-- and open the query that shows updated replicated tables
   On Error Resume Next
   
   catLocal.Tables.Delete "tblBackEndReplicatedTables"
   catLocal.Tables.Refresh
   
   On Error GoTo Error_ap_CheckReplicatedTables
   
   ap_CreateLinkedTableWithADO catLocal, _
                "tblBackEndReplicatedTables", _
                "tblReplicatedTables", pstrBackEndPath & _
                pstrBackEndName
   catLocal.Tables.Refresh
   
   Set cmdUpdateRep = catLocal. _
                Procedures("qryUpdateLastReplication").Command
   
   rstCheckRep.Open "qryCheckBackEndReplication", _
                CurrentProject.Connection, adOpenStatic
   
   '-- If a table has been updated, loop through
   
    
    Do Until rstCheckRep.EOF
       
       DoCmd.Echo True, "Replicating " & rstCheckRep!TableName & _
                ", Please wait..."
       
       '-- Delete the current local table,
       '-- and import the backend table
       On Error Resume Next
       strTableName = rstCheckRep!TableName
      
       catLocal.Tables.Delete strTableName
       catLocal.Tables.Refresh
       
       On Error GoTo Error_ap_CheckReplicatedTables
       
       DoCmd.TransferDatabase acImport, "Microsoft Access", _
                pstrBackEndPath & pstrBackEndName, _
                acTable, rstCheckRep!TableName, rstCheckRep!TableName
       
       catLocal.Tables.Refresh
       
       cmdUpdateRep.Parameters("CurrReplicatedTable") = strTableName
       cmdUpdateRep.Execute
    
       rstCheckRep.MoveNext
    
   Loop
    
   catLocal.Tables.Delete "tblBackEndReplicatedTables"
   
   DoCmd.Echo True
   
   '-- Clean up
   rstCheckRep.Close
  
   Exit Sub

Error_ap_CheckReplicatedTables:
   MsgBox Err.Description
   Exit Sub
   
End Sub



Sub ap_CreateLinkedTableWithADO(catCurr As ADOX.Catalog, strDestTableName As String, _
            strSourceTableName As String, strDataMDB As String)

    Dim tblCurr As New ADOX.Table
    
    tblCurr.Name = strDestTableName
    Set tblCurr.ParentCatalog = catCurr
            
    tblCurr.Properties("Jet OLEDB:Link Datasource") = strDataMDB
    tblCurr.Properties("Jet OLEDB:Create Link") = True
    tblCurr.Properties("Jet OLEDB:Remote Table Name") = strSourceTableName
           
    catCurr.Tables.Append tblCurr

End Sub

Public Function CheckFEVersion() As Boolean
    
    Dim cnnNet As New ADODB.Connection
    Dim rstBEDefault As New ADODB.Recordset
   
    '-- Open a connection to the backend database
    cnnNet.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & _
            pstrBackEndPath & pstrBackEndName
    
    '-- Open the database properties table
    rstBEDefault.Open "zstblDatabaseProperties", cnnNet
    
    '-- Compare frontend version
    If rstBEDefault!FrontEndVersion <> _
            ap_GetDatabaseProp("FrontEndVersion") Then
        
        MsgBox rstBEDefault!FrontEndMessage, vbCritical
        
        CheckFEVersion = False
    
    Else
        
        CheckFEVersion = True
    
    End If
    
    '-- Clean up
    rstBEDefault.Close
    cnnNet.Close
    
    Set rstBEDefault = Nothing
    Set cnnNet = Nothing
    
    
End Function

[رضا عقيل]

ماذا لو أردنا ربط برنامجين في مكانين مختلفين عن طريق الهاتف .....

لا نقل الملفات فقط ... بل ربط مثل الشبكة المحلية إرسال بيانات عن طريق البرنامج نفسه ..

[biskra]

مجرد رأي في الموضوع هناك برامج تمكنك من التحكم في جهاز شخص آخر بواسطة الأنترنيت حسب وصف أصحابها في أحد المنتديات العربية بشكل يجعلك و كأنك تعمل على جهازك, لمن أراد الرابط فباٍمكاني وضعه

[أمجد جمالي]

صحيح كلامك اخ biskra

وانا اعرف هذه البرامج مثل Pc AnyWhere لشركة Symantec خير معرفة

حتى بإمكانك التحكم بجهاز شخص اخر في اصدار ويندوز اكس بي من خلال Remote Desktop Connection

بس وين الفائدة اذا انا اتحكمت بسطح مكتب جهاز غيري

مافي شك صار اتصال بين جهازين واقدر ارسل واستقبل الملفات من الطرفين

بس الاخ وائل طلب اتصال بين فرعين يعني على مدار 24 ساعة يكون الفرعي متصل مع الرئيسي من خلال Host Name

وعلى فكرة هذه البرامج تستخدم لصيانة ال SoftWare من اماكن بعيدة اما عن طريق TCP/IP او خط الهاتف او Dicret Line او NetBios

وهي مفيدة جداً للشركات الكبيرة بحيث يمكن لموظفين الدعم الفني او IT حل اي مشكلة تتعلق ب SoftWare وهو جالس عى مكتبه

تحياتي للجميع

[أمجد جمالي]

السلام عليكم ورحمة الله وبركاته

كما وعدتكم اخواني الكرام بإرفاق مثال لربط قاعدتين بيانات في شبكة محلية واعتذر عن التأخير لكن والله اني مشغول للغاية .

الرجاء ممن يرغب بتجريب المثال ان يتبع هذه الخطوات مع مراعاة تنفيذها بالتسلسل وهذه المثال ليس سهل ابداً بل صعب ومعقد بعض الشيئ لكن الي يهم هو النتيجة ..... .

تكون قاعدة البيانات الأولى في الخادم او ال Server وفي مثالي هي BackEnd وهي عبارة عن جداول فقط

والثانية موزعة لكل مستخدم او Client في الشبكة وفي مثالي هي FrontEnd ويكون فيها النماذج والتقارير والماكرو والوحدات النمطية .

1-من بعد فك ضغط المثال قم بنسخ المجلد DataBase بمحتوياته ووضعه في السيرفر

2-من بعد نسخ الملف ووضعه في السيرفر اضغط باليمين الماوس عى هذه المجلد واختر Sharing And Sequrity لمستخدمين ويندوز 2000 /أو أكس بي واعمل مشاركة او Sharing لهذا المجلد وسميه DataBase

الرجاء قبل الانتقال الى الخطوة الثالثة مراعاة ما يلي :-

تحقق من الدرايف الذي وضعت فيه المجلد اذا كان نظام الملفات Fat32 او NTFS وذلك من خلال اضغط بيمين الماوس على الدرايف سي او دي مهما يكن واختر خصائص وشوف ماهو نظام الملفات

اذا كان Fat32 اذهب الى Sharing كما هو موضح في الصورة

ثم الى Permmision وعلم صح على هذه الصلاحيات

اما اذا كان نظام الملفات NTFS افعل الأتي

نفذ نفس الخطوات السابقة لنظام الملفات FAT32 بالإضافة الى

اذهب الى Sequrity واختر ADD ثم اكتب EveryOne كما هو موضح

ثم علم صح على جميع الصلاحيات كما هو مضح ادناه لهذه المستخدم

الجزء الاصعب من المثال انتهى

3-افتح المجلد DataBase وشغل قاعدة البيانات BackEnd

ثم اذهب الى الماكرو ثم اعمل RUn ل MacSetHostNameAndIPAdress

الأن افتح الجدول DatabaseProperties سوف تجد رقم ال IP Address And Host Name

مخزن عندك في الجدول سجل هذه البيانات على ورقة .

4-انتهى العمل على السيرفر باقي جهاز المستخدم وانا مفترض الأن عندك شبكة داخلية ومتصلة مع السيرفر

انسخ قاعدة البيانات FrontEnd وضعها على جهاز المستخدم

5-قم بتشغيل هذه القاعدة مع الأخذ بالاعتبار عند الفتح الضغط عى زر ال Shift فقط لأول مرة

6-افتح الجدول DatabaseProperties وعند الخانة LastBackEndPath اكتب مايلي

\\MyServer\DataBase\

وغير MyServer الى رقم ال IP Address تبع السيرفر او

\\MyServerHostName\DataBase\

وغير MyServerHostName الى اسم السيرفر الي سجلناه على الورقة

كلا الطريقتين تعمل

7-اغلق الجدول وقاعدة البيانات وشغل ال FrontEnd بدون الضغط على Shift

8-اذا طلعت هذه المسج

اضغط موافق و اختر موقع السيرفر من على الشبكة واتبع المسار الخاص بال Backend

اذا نجح الاتصال بين القاعدتين سوف يتم عمل لينك ل 5 جداول و يفتح معك جدول مكتوب فيه اسمي

وتحياتي للجميع

وانا جاهز لأي مساعدة

طريقة عمل اللينك للجداول مقتبسة من احد الكتب الاجنبية للأسف لا اذكر اسم الكتاب ولا اسم المؤلف

طريقة Get IP Address And Host Name من احد المواقع الأجنبية

وباجتهادي الخاص عملت الطريقة و

تحياتي للجميع وانا جاهز لأي دعم

MyExample.zip

تم تعديل نوفمبر 7, 2004 بواسطه أمجد جمالي

[رضا عقيل]

عافاك الله أخي امجد على هذه المعلومات القيمة

عندي تعجب شديد !!!!!

هناك العديد من الطرق لربط البرامج على شبكة داخلية

وكذلك الأمثلة

- طريقة للتأكد من الرابط كلما تم فتح البرنامج

- طريقة للربط ووتتبع الرابط بمربعات حوار ويندوز

..... إلخ

ولكن ورغم كثرة التساؤلات لم نستطيع الوصول بوضح لحد أو تفسير واضح لطريقة ربط الفروع عن طريق خط الهاتف ...

وقد رايتها بنفسي في برامج كبيرة أي ليس الأمر بصعب أومستحيل ولكن كيف السبيل لا جواب مفصل على الإطلاق

برامج التحدكم في سطح المكتب البعيد لا تفيد مطلقاً في هذه الناحية كما تفضلت واشرت

لذلك أتمنى أن تفيدنا بعملك في هذه الناحية ربما نصل لحل يرضي الجميع

حتى وإن كان الأمر يتطلب هاردوير إضافي .... المهم هو الوصول لحل

مرة أخى عافاك الله على هذا المجهود المميز ونتمنى المزيد

[سهل احمد العريشي]

بسم الله الرحمن الرحيم

روابط من المنتدى لمن يريد حول نفس الموضوع

مااهي افضل وأسهل الخطوات لوضع البرنامج على شبكة ( ربط الجداول بين قاعدتين Link Tables )-بادئ الموضوعofficenamember

http://www.officena.net/ib/index.php?showtopic=561

تبادل الرسائل على الشبكة من خلال الأكسس

POP UP Messages

http://www.officena.net/ib/index.php?showtopic=260

الحصول على أسماء المحطات للشبكات ( ابو هادي )

Windows 2000 Server

http://www.officena.net/ib/index.php?showtopic=3081

نقل البيانات عبر المودم دون انترنت ، كيف ؟؟

http://www.officena.net/ib/index.php?showtopic=2675

وهذا رابط مفيد للأوتولوك

التحكم فى الاوتلوك 2003 من الاكسيس 2003 ( محمد طاهر )

http://www.officena.net/ib/index.php?showtopic=3497

أخيكم سهل احمد ( ابو نعيم )

[أمجد جمالي]

السلام عليكم

اشكر مشاركتك اخ رضا

شعاري في هذه الحياة هو "مافي شي مستحيل في هذه الدنية"

ربنا سبحانه وتعالى أعطانا العقل لحتى نفكر فيه إذاً فأحنا قادرين على عمل اي شيء طبعاً بأستثناء قضية الشرق الأوسط :d

الأنترنت ما هو الا ارسال واستقبال بيانات

اذا انا عرفت ال IP Address لجهاز المستقبل وعرفت IP Address لجهاز المرسل خلص تقريبأ انا وصلت

وأشرت اخ رضا بمشاركتك

ولكن ورغم كثرة التساؤلات لم نستطيع الوصول بوضح لحد أو تفسير واضح لطريقة ربط الفروع عن طريق خط الهاتف ...

وقد رايتها بنفسي في برامج كبيرة أي ليس الأمر بصعب أومستحيل

فارجو ان تعطيني برنامجين او واحد على الأقل مع Source Code إن أمكن وانشاء سوف اعمل انا واصدقائي على حل هذه المشكلة بإذن الله

تحياتي لك وابقى على اتصال معنا

أبو نادر

[waeelahmed]

بس كده لازالت المشكلة ستكون التكلفة عالية ، فمثلاً نحن لا نحتاج أن يكون التحديث مستمر ويكون العمل على سيرفر .

فمثلاً :

1- المطلوب أنه سيكون فى كل فرع برنامج كامل قائم بذاته .

2- فى الإدارة الرئيسية مجرد نماذج ستعمل على الجداول التى سيتم إرسالها من الأفرع كلما أرادت الإدارة معرفة أخر التطورات.

بمعنى ملخص أنه وعلى سبيل الافتراض فأنا فقط أريد فى نهاية كل يوم للأفرع تحديث بيانات الإدارة الرئيسية بكل ما تم على مدار اليوم.

ملحوظة : دون استخدام الايميل لعدم دراية المستخدمين نهائياً بالانترنت ، ودون أن يقوم شخص بالتحرك من الفرع يحمل ديسك للإدارة للبعد الجغرافى.

فى إنتظار ردك أخى أمجد.

[HUSSIN]

شكراً لك يا أخ سهل احمد العريشي ... معلومة جديدة

[أمجد جمالي]

أخواني الأعزاء وائل و رضا عقيل متل ما وعدتكم

تم بحمد الله ربط الفروع البعيدة عن طريق ال Ip Address بغض النظر عن طريقة الإتصال سواء كانت

Leased Line او DSL Connection او Dial Up Connection

حمل الملف وفك الضغط الملف إضغط بيمين الماوس واختر تحرير او Edit

وشوف الأوامر وأظنها سهلة مو محتاجة شرح وعدل عليها حسب ال IP Address ال عندك

تحياتي

اخوكم ابو نادر

المثال جربته داخل فرعين تابعين للشركة التي اعمل بها في الرياض ونجح والحمدلله

فرع رئيسي وفرع اخر مربوطين مع بعضهم البعض عن طريق ال DSL

SubSetDrive.zip

[رضا عقيل]

إخواني

أعتذر للتأخر في الرد

بالنسبة للبرامج التي رأيتها لا أستطيع حتى الحصول علىنسخة لنفسي لأنها برامج صيدليات ولن أستيطع الحصول عليها

الطريقة التي رأيتها

يقوم المستخدم بقتح شاشة اتصال بالفرع أو المركز الرئيسي

يقوم بإدخال اسم المستخدم

كلمة السر

هاتف الفرع

يقوم البرنامج بالربط مع الطرف الآخر

يتسطيع إرسال طلبيات واستقبال بيانات وتنفيذ استعلامات إلحاق للبيانات تقوم بإلحاق البيانات إلىالطرف الآخر

سأقوم بتنزيل الملف وتجربته

ونشكرم أخي أمجد والإخوان جميعاً للاهتمام والمشاركة

[أمجد جمالي]

السلام عليكم

اخ رضا عقيل

لقيت الكود بنفس الطريقة الي شرحتها

كيف تتصل بهاتف من خلال المودم

وكيف ترسل بيانات عن طريق منفذ المودم

والكود عندي مخزن في الهارد :pp:

ولحتى اعطيك ياه بدي الحلوان :pp:

رح جرب الطريقة بالأول

ويكون الحلوان شيء محرز

تحياتي

[أمجد جمالي]

السلام عليكم

هذا هو الرابط

http://www.scientificcomponent.com/begin_p...er_download.htm

وهذا

http://www.fabalou.com/Access/General/dialing_modem.asp

وهذا

http://www.pclubricant.com/easydial/

وانا اخدت منه رؤوس أقلام وبديت في عمل البرنامج وبدي مساعده

تحياتي

تم تعديل نوفمبر 23, 2004 بواسطه أمجد جمالي

[رضا عقيل]

أخي أمجد لك كل الشكر والتقدير على هذه الوصلات

وعلى اهتمامك الزائد بهذا الموضع

وأعتذر عن التأخر في الرد لإنشغالي هذه الأيام

ولكني أتابع الموضوع باستمرار وسأتدخل بالمساعدة عندما اصل إلى أي شيء جديد بأمر الله

استمر في المحاولة ولكل مجتهد نصيب فإن تم هذا الموضوع فسيكون بصمة واضحة في البرمجة بالأكسس

مع خالص تحياتي

[أمجد جمالي]

اخ رضا عقيل مساء الخير

شكراً لردك الجميل الذي يرفع المعنويات

ومازلت اجري التجارب بين جهازين وبس يطلع معي نتيجة رح ارفق المثال على طول

تحياتي لكم

[waeelahmed]

أعانك الله أخى أمجد ونحن فى الانتظار

[ayekga]

On 11/20/2004 at 9:28 PM, أمجد جمالي said:

أخواني الأعزاء وائل و رضا عقيل متل ما وعدتكم

تم بحمد الله ربط الفروع البعيدة عن طريق ال Ip Address بغض النظر عن طريقة الإتصال سواء كانت

Leased Line او DSL Connection او Dial Up Connection

حمل الملف وفك الضغط الملف إضغط بيمين الماوس واختر تحرير او Edit

وشوف الأوامر وأظنها سهلة مو محتاجة شرح وعدل عليها حسب ال IP Address ال عندك

تحياتي

اخوكم ابو نادر

 

المثال جربته داخل فرعين تابعين للشركة التي اعمل بها في الرياض ونجح والحمدلله

 

فرع رئيسي وفرع اخر مربوطين مع بعضهم البعض عن طريق ال DSL

SubSetDrive.zip