كود لعمود الحاله وعمود مواد الدور الثاني

**ناصر سعيد** · يونيو 29, 2012

هذا مرفق به عمود الحاله وعمود مواد الدور الثاني

اريد ان تظهر بيان الحاله ومواد الدور الثاني عن طريق كود

جزاكم الله خيرا

الحالة ومواد الدور الثاني.rar

**ناصر سعيد** · يونيو 30, 2012

يارب ارزقني باحد الأفاضل يأتي بالحل

**ناصر سعيد** · يوليو 1, 2012

يارب ارزقني باحد الأفاضل يأتي بالحل

يارب

**عبدالله باقشير** · يوليو 2, 2012

السلام عليكم

اخي الفاضل ناصر حفظه الله

المعادلات المطلوبة مرتبطة بمعادلات اخرى والمعادلات الاخرى مرتبطة باخرى وهكذا

يعني الواحد لازم يعرف آلية عمل كل معادلة

والملف كبير !!!

وهذا يفسر عدم وجود اي محاولات من الاعضاء

تقبل تحياتي وشكري

**ناصر سعيد** · يوليو 2, 2012

الحمد والشكر لله الذي رزقنا بالعلامة الكبير عبد الله

يعني الواحد لازم يعرف آلية عمل كل معادلة ... اقتباس

من حقك اخي العلامة

**عبدالله باقشير** · يوليو 2, 2012

الحمد والشكر لله الذي رزقنا بالعلامة الكبير عبد الله

يعني الواحد لازم يعرف آلية عمل كل معادلة ... اقتباس

من حقك اخي العلامة

هل تريد تحويل عملها عن طريق كود ؟؟

هذا الذي فهمته

ام تريد لصق قيمة المعادلة عن طريق الكود

يعني يقوم بتنفيذ المعادلة ثم يبقي قيمتها فقط ؟؟

**ناصر سعيد** · يوليو 2, 2012

قي هذا المرفق ازلت جميع الخلايا المدمجة

اختبارالفصل الدراسى الثانى لأي طالب في أي ماده

يجب

أن يساوي أو أكبر من 30 % من الدرجة النهائيه للماده ولاتكون غ

الدرجة الأصلية لأي طالب في أي ماده يجب أن تساوي أو أكبر من 50% من الدرجة النهائيه للماده ولاتكون غ

في الحالتين السابقتين يكون الطالب في هذه الماده ناجح

أما إذا كان الطالب غايب في اختبار الفصل الدراسي الثاني أو أقل من 30 %

أو (أقل من 50 % أو غايب في الدرجة الأصليه) يكون الطالب عتده دور ثاني في هذه الماذة

حالة الطاالب.rar

**ناصر سعيد** · يوليو 2, 2012

استدراك

في العمود 113 قبل عمود النتيجة ... الخاله يعني ناجح أم دور تاني

وعمود النتيجه معنناه مواد الدور الثاني

ربنا يجزيك استاذنا الغلامة عنا كل خير

**ناصر سعيد** · يوليو 2, 2012

اريد تحويل عملها عن طريق كود

تم تعديل يوليو 2, 2012 بواسطه nasersaeed

**عبدالله باقشير** · يوليو 3, 2012

السلام عليكم

هذه للتجربة

ويجب ان تعمل اجماليات لعمود المجموع

علشان تجرب الكود كويس

الكود يعمل من الصف 11 ال 17


Option Explicit


'         اسماء المواد

Const nTEST As String = "عريى" & "," & _

                        "رياضيات" & "," & _

                        "دراسات" & "," & _

                        "انجليزى" & "," & _

                        "علوم" & "," & _

                        "مجموع" & "," & _

                        "دين"

'--------------------------------------

'         ارقام اعمدة الدرجة الاصلية

'          بالتسلسل حسب اسماء المواد

Const ColmnTotal As String = "26,35,44,53,64,65,82"

'         ارقام اعمدة الفصل الثاني

'         هنا المجموع ليس له عمود جعلناه صفراً

Const ColmnTest2 As String = "22,31,40,49,60,0,78"


'         رقم صف النهاية الصغرى

Const iRs As Integer = 10


Sub kh_Tgrba()

Dim r As Integer

Dim tst As String

For r = 11 To 17

    tst = kh_test(r)

    If Len(tst) Then Cells(r, 113) = "له دور ثانى فى" Else Cells(r, 113) = "ناجح"

    Cells(r, 114) = kh_test(r)

Next

End Sub


Function kh_test(iRow As Integer) As String

Dim vT, sT

Dim NN As String, TT As String

Dim ctlt As Integer, ctst As Integer

Dim c As Integer, cc As Integer

Dim ib As Boolean

cc = UBound(Split(nTEST, ","))


For c = 0 To cc

    ib = False

    NN = Split(nTEST, ",")(c)

    ctlt = Split(ColmnTotal, ",")(c)

    ctst = Split(ColmnTest2, ",")(c)

    vT = Cells(iRow, ctlt)

    If Not IsEmpty(vT) Then

        Select Case vT

            Case Is = "غ": ib = True

            Case Is < Cells(iRs, ctlt): ib = True

        End Select

    End If

    If ctst = 0 Then GoTo 1

    sT = Cells(iRow, ctst)

    If Not IsEmpty(sT) Then

        Select Case sT

            Case Is = "غ": ib = True

            Case Is < Cells(iRs, ctst): ib = True

        End Select

    End If

1:

    If ib Then TT = TT & NN & " - "

Next

kh_test = TT

End Function

المرفق 2003

حالة الطاالب.rar

**ناصر سعيد** · يوليو 4, 2012

بسم الله

الحمد لله الذي رزقنا بك ايها العالم الكبير

وجاري التجربه

mhrrd · يوليو 4, 2012

كود ولا في الاحلام

صغير دقيق

كما عودتنا اسناذنا الكبير

عبد الله

جزاك الله خيرا

mhrrd · يوليو 4, 2012

لو سمحت اضافه

لو الطالب في اختبار الفصل النامي عايب أو اقل من ثلث الدرجة

يكنب بجوار اسم المادة لثلث الدرجة

**ناصر سعيد** · يوليو 4, 2012

تمام

الله يحرسك الف شكر

**محمدي عبد السميع** · يوليو 4, 2012

بسم الله ... ماشاء الله

اللهم بحق اسمك الأعظم ان تبارك

للعالم العلامة والبحر الفهامة عبد الله باقشير

وان تجزيه عن كل ثانيه قضاها في تذليل الصعاب لنا

بكل خير

**عبدالله باقشير** · يوليو 4, 2012

السلام عليكم

لو سمحت اضافه

لو الطالب في اختبار الفصل النامي عايب أو اقل من ثلث الدرجة

يكنب بجوار اسم المادة لثلث الدرجة


Option Explicit


'         اسماء المواد

Const nTEST As String = "عريى" & "," & _

                        "رياضيات" & "," & _

                        "دراسات" & "," & _

                        "انجليزى" & "," & _

                        "علوم" & "," & _

                        "مجموع" & "," & _

                        "دين"

'--------------------------------------

'         ارقام اعمدة الدرجة الاصلية

'          بالتسلسل حسب اسماء المواد

Const ColmnTotal As String = "26,35,44,53,64,65,82"

'         ارقام اعمدة الفصل الثاني

'         هنا المجموع ليس له عمود جعلناه صفراً

Const ColmnTest2 As String = "22,31,40,49,60,0,78"


'         رقم صف النهاية الصغرى

Const iRs As Integer = 10

'         اول صف للبيانات

Const TopRow As Integer = 11



Sub kh_Tgrba()

Dim sCont As Integer, R As Integer

Dim Tst As String

On Error GoTo 1

'------------------

'   عدد  الطلبة

'    ممكن يؤخذ من خلية او يكتب كتابة

sCont = 500

'---------------------------------------

Application.ScreenUpdating = False

Application.Calculation = xlCalculationManual

'------------------

sCont = sCont + TopRow

With ActiveSheet

    For R = TopRow To sCont

        If Not IsEmpty(.Cells(R, "C")) Then

            Tst = kh_Test(R)

            If Len(Tst) Then .Cells(R, "DI") = "له دور ثانى فى" Else .Cells(R, 113) = "ناجح"

            .Cells(R, "DJ") = kh_Test(R)

        End If

    Next

End With


1:

Application.ScreenUpdating = True

Application.Calculation = xlCalculationAutomatic

If Err Then

    MsgBox "Err.Number : " & Err.Number

    Err.Clear

    Else: MsgBox "تم اظهار النتيجة بنجاح"

End If


End Sub


Function kh_Test(iRow As Integer) As String

Dim vT, sT

Dim NN As String, TT As String

Dim ctlt As Integer, ctst As Integer

Dim c As Integer, cc As Integer

Dim ib As Boolean

cc = UBound(Split(nTEST, ","))


For c = 0 To cc

    ib = False

    NN = Split(nTEST, ",")(c)

    ctlt = Split(ColmnTotal, ",")(c)

    ctst = Split(ColmnTest2, ",")(c)

    vT = Cells(iRow, ctlt)

    If Not IsEmpty(vT) Then

        Select Case vT

            Case Is = "غ", "غـ": ib = True

            Case Is < Cells(iRs, ctlt): ib = True

        End Select

    End If

    If ctst = 0 Then GoTo 1

    sT = Cells(iRow, ctst)

    If Not IsEmpty(sT) Then

        Select Case sT

            Case Is = "غ", "غـ"

                NN = NN & " لثلث الدرجة": ib = True

            Case Is < Cells(iRs, ctst)

                NN = NN & " لثلث الدرجة": ib = True

        End Select

    End If

1:

    If ib Then TT = TT & IIf(Len(TT), " - ", "") & NN

Next

kh_Test = TT

End Function

شاهد المرفق 2003

حالة الطاالب.rar

**عبدالله باقشير** · يوليو 4, 2012

تمام

الله يحرسك الف شكر

ولك مثله اضعاف مضاعفة

في المرفق الاخير تمت تعديلات اخرى

ملاحظة :

تم تعديل العنوان ليسهل البحث

عن الكود

تقبل تحياتي وشكري

**عبدالله باقشير** · يوليو 4, 2012

بسم الله ... ماشاء الله

اللهم بحق اسمك الأعظم ان تبارك

للعالم العلامة والبحر الفهامة عبد الله باقشير

وان تجزيه عن كل ثانيه قضاها في تذليل الصعاب لنا

بكل خير

اكرمك الله اكرام الصالحين

ورزقك الفردوس انت واهلك وذويك ومن تحب

تقبل تحياتي وشكري

**محمدي عبد السميع** · يوليو 5, 2012

عمل ولاأروع

فقد سهلت لمحبي أعمال الكنترول من كتابة معادلات كثيره

بكود صغير ومتقن

وقد ازداد روعه باضافتك

حفظك الله ورعاك

ابن بنها · أغسطس 6, 2012


عدد  الطلبة

'    ممكن يؤخذ من خلية او يكتب كتابة

sCont = 500

ممكن يؤخذ من خلية .. ; كيف هل يمكن وضع مثال كرما

عبد الحميد شقير · مايو 25, 2013

صحبة ولاأروع ولاأصدق ولاأجل منها صحبة ..صدق وأمانة ....جزاكم الله كل الخير وأدخل علي نفوسكم الهناء والسرور وحفطكم الله وزويكم من كل سوء

تم تعديل مايو 25, 2013 بواسطه عبد الحميد شقير

عز أبو أنس · مارس 6, 2014

جزاك الله كل خير

mrgamal66 · سبتمبر 14, 2014

هذا مرفق به عمود الحاله وعمود مواد الدور الثاني

اريد ان تظهر بيان الحاله ومواد الدور الثاني عن طريق كود

جزاكم الله خيرا

نرجو حذف مادة اللغة الفرنسية وتعديل الدرجات للغة العربية من 100 بدلا من 80 ولكم جزيل الشكر

**ناصر سعيد** · أبريل 3, 2016

الله يحفظكم

ابن بنها · أبريل 4, 2016

Option Explicit

'         اسماء المواد
Const nTEST As String = "عريى" & "," & _
                        "رياضيات" & "," & _
                        "دراسات" & "," & _
                        "انجليزى" & "," & _
                        "علوم" & "," & _
                        "مجموع" & "," & _
                         "رسم" & "," & _
                          "العاب" & "," & _
                           "نشاط1" & "," & _
                            "نشلط 2" & "," & _
                        "دين"
'--------------------------------------
'         ارقام اعمدة الدرجة الاصلية
'          بالتسلسل حسب اسماء الموادوعددها
Const ColmnTotal As String = "13,22,31,40,51,57,62,67,72,73,82"


'         ارقام اعمدة الفصل الثاني
'ويجب ان يتساوى عددها
'مع عدد اسماء المواد 'لعليا التي كتبت
'         وهنا المجموع ً
Const ColmnTest2 As String = "9,18,27,36,47,54,59,64,69,73,77"


'         رقم صف النهاية الصغرى
Const iRs As Integer = 6

'         اول صف للبيانات
Const TopRow As Integer = 7


Sub kh_Tgrba()
Dim sCont As Integer, R As Integer
Dim Tst As String
On Error GoTo 0
'------------------
'   عدد  الطلبة
'    ممكن يؤخذ من خلية او يكتب كتابة
sCont = 700
'---------------------------------------
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
'------------------
sCont = sCont + TopRow
With ActiveSheet
    For R = TopRow To sCont
        If Not IsEmpty(.Cells(R, "C")) Then
            Tst = kh_Test(R)
            
            '--متغير اســم ورقم العمود
            If Len(Tst) Then .Cells(R, "CW") = "له دور ثانى فى" Else .Cells(R, 101) = "ناجح"
            
                       '--متغيررقم العمود
            .Cells(R, "CX") = kh_Test(R)
        End If
    Next
End With

1:
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
If Err Then
    MsgBox "Err.Number : " & Err.Number
    Err.Clear
    Else: MsgBox "تم اظهار النتيجة بنجاح"
End If

End Sub

Function kh_Test(iRow As Integer) As String
Dim vT, sT
Dim NN As String, TT As String
Dim ctlt As Integer, ctst As Integer
Dim c As Integer, cc As Integer
Dim ib As Boolean
cc = UBound(Split(nTEST, ","))

For c = 0 To cc
    ib = False
    NN = Split(nTEST, ",")(c)
    ctlt = Split(ColmnTotal, ",")(c)
    ctst = Split(ColmnTest2, ",")(c)
    vT = Cells(iRow, ctlt)
    If Not IsEmpty(vT) Then
        Select Case vT
            Case Is = "غ", "غـ": ib = True
            Case Is < Cells(iRs, ctlt): ib = True
        End Select
    End If
    If ctst = 0 Then GoTo 1
    sT = Cells(iRow, ctst)
    If Not IsEmpty(sT) Then
        Select Case sT
            Case Is = "غ", "غـ"
                NN = NN & " لثلث الدرجة": ib = True
            Case Is < Cells(iRs, ctst)
                NN = NN & " لثلث الدرجة": ib = True
        End Select
    End If
1:
    If ib Then TT = TT & IIf(Len(TT), " - ", "") & NN
Next
kh_Test = TT
End Function

'   عدد  الطلبة
'    ممكن يؤخذ من خلية او يكتب كتابة
sCont = 700

اريدعدد الطلبه مشكورين يكون من خليه اس 1 ... في صفحة بيلنات المدرسه

تسجيل الدخول

كود لعمود الحاله وعمود مواد الدور الثاني

الردود الموصى بها

ناصر سعيد

ناصر سعيد

ناصر سعيد

عبدالله باقشير

ناصر سعيد

عبدالله باقشير

ناصر سعيد

ناصر سعيد

ناصر سعيد

عبدالله باقشير

ناصر سعيد

mhrrd

mhrrd

ناصر سعيد

محمدي عبد السميع

عبدالله باقشير

عبدالله باقشير

عبدالله باقشير

محمدي عبد السميع

ابن بنها

عبد الحميد شقير

عز أبو أنس

mrgamal66

ناصر سعيد

ابن بنها

Join the conversation

تصفح هذا الموضوع مؤخراً 0 اعضاء متواجدين الان

تصفح الموقع

تصفح جديد الموقع

Support

Important Information