هل من إمكانية لإلغاء وتمكين عمل زر Shift عند فتح قاعدة البيانات؟

[sweety]

السلام عليكم

في الملف المرفق مثال لقاعدة بينانات عند فتحها تلقائياً تقوم بفتح الصفحة الرئسية بأمر من (بدأ التشغيل Startup) وإخفاء (قاعدة البيانات-الجداول-النماذج... إلخ). ولكن عند الضغط على زر Shift في حالة الفتح يتم إلغاء هذه الخاصية.

هل بالإمكان تعطيل عمل زر Shift بأي طريقة ومنع المستخدمين الباقين من الدخول على قاعدة البيانات إلا من خلال (كلمة سر) مثلاً الأمر الذي يتيح لي أنا فقط هذه الصلاحية، مع العلم أنني أريد قاعدة البيانات مفتوحة المصدر للتعديل على الجداول والنماذج...إلخ من قبلي في اي وقت لذلك لا أود تحويلها إلى mde.

أتمنى أن أجد الحل لديكم

تحياااتي

test4.rar

[محب العلم]

وعليكم السلام ورحمة الله

لعمل المطلوب أتبع الخطوات الآتية :

1. قم بإنشاء وحدة نمطية وضع فيها الكود الآتي وخزنها في أي أسم تريد

'---------------------------------------------------------------------'
' Module: DisableShiftKey                                             '
' Date: July 18, 2003                                                 '
'                                                                     '
' Purpose: To stop the user from holding the shift key on startup to  '
'          access the database window.                                '
'---------------------------------------------------------------------'

Option Compare Database
Option Explicit
'----------------------------------------------------------------------

Function ChangeProperty(strPropName As String, varPropType As Variant, varPropValue As Variant) As Integer
   Dim dbs As Object, prp As Variant
   Const conPropNotFoundError = 3270

   Set dbs = CurrentDb
   On Error GoTo Change_Err
   dbs.Properties(strPropName) = varPropValue
   ChangeProperty = True

Change_Bye:
   Exit Function

Change_Err:
   If Err = conPropNotFoundError Then    ' Property not found.
       Set prp = dbs.CreateProperty(strPropName, _
           varPropType, varPropValue)
       dbs.Properties.Append prp
       Resume Next
   Else
       ' Unknown error.
       ChangeProperty = False
       Resume Change_Bye
   End If
End Function
'----------------------------------------------------------------------

Function BypassKey(onoff As Boolean)
   Const DB_Boolean As Long = 1
   ChangeProperty "AllowBypassKey", DB_Boolean, onoff
End Function
'-----------------------------------------------------------------------

2. قم بإنشاء ماكروات جديدة هي : اسم الماكرو الأول: ByPassKeyOff الإجراء: Runcode الإقتران:

 BypassKey(False)

اسم الماكرو الثاني: ByPassKeyOn الإجراء: Runcode الإقتران:

 BypassKey(True)

3. نموذج الدخول للنظام الخاص بك قم بإنشاء مستطيل بدون إطار ولون خلفية نفس خلفية النموذج أو إذا كان عندك صورة في نموذج الدخول يمكن استخدامها مكان المستطيل وعرف حدث عند النقر وقم باختيار الماكرو ByPassKeyOn.

4. قم بتشغيل المكرو ByPassKeyOff خزن وأخرج من قاعدة البيانات.

5. الآن عندما تدخل إلى قاعدة البيانات وأنت ضاغط على Shift لن تظهر لك نافذة قاعدة البيانات . لإظهار قاعدة البيانات اضغط بالماوس حيثما وضعت المستطيل المخفي أو الصورة ثم أعد تشغيل القاعدة مع shift ستظهر ولإعادة المنع كرر الخطوة رقم 4.

وتعتبر هذه إحدى طرق الحماية لقاعدة البيانات .

أملا لك التوفيق في المحاولة

مع وافر الاحترام

[sweety]

شكرا لك أخي محب العلم على تواصلك الدائم

لقد طبقت العملية ونجحت والحمدلله

تحياااتي لك