كود إفراغ الحافظة

[abofayez1]

السلام عليكم ورحمة الله 
كما في العنوان  أريد كود يقوم بإفراغ الحافظة بحيث مثلا لو قمت بعملية نسخ ولصق في البرنامج أريد إفراغ الحافظة بحيث لا يمكن اللصق مرة ثانية ،
وجزاكم الله خيرا

[Foksh]

وعليكم السلام ورحمة الله وبركاته..

في مديول جديد ، الصق الكود التالي :-

Private Declare PtrSafe Function OpenClipboard Lib "user32" (ByVal hwnd As LongPtr) As Long
Private Declare PtrSafe Function EmptyClipboard Lib "user32" () As Long
Private Declare PtrSafe Function CloseClipboard Lib "user32" () As Long

Sub ClearClipboard()
    If OpenClipboard(0) Then
        EmptyClipboard
        CloseClipboard
    End If
End Sub

ويتم الاستدعاء باسم الصب ClearClipboard

 

تم تعديل يناير 20 بواسطه Foksh
حذف الدالة بالاقتراح الثاني = لا تعمل بعد التجربة

[ناقل]

مشاركة

Sub ClearClipboardAndFreeMemory()
    ' تحرير محتوى الحافظة
    On Error Resume Next
    Dim DataObject As Object
    Set DataObject = CreateObject("MSForms.DataObject")
    DataObject.SetText ""
    DataObject.PutInClipboard
    Set DataObject = Nothing
    On Error GoTo 0
    
    ' تحرير الذاكرة
    DoEvents
    Application.Echo True, "Memory cleared"
End Sub

 

[abofayez1]

جزاكم الله خيرا وبارك فيكم

[Foksh]

أعتذر من الأستاذ @ناقل ، ولكن الأخ العزيز @abofayez1 ، هل قمت بتجربة الكود الذي اخترته كأفضل إجابة  ؟؟؟

هل لديك المكتبة أو قمت بإضافتها Microsoft Forms 2.0 Object Library (MSForms) ؟؟؟؟؟

[abofayez1]

حياك الله أخي Foksh

للأمانة جربت الكود الأول وحاولت فيه ولم يعمل معي ثم سافرت وفتحت المنتدى من الجوال ولقيت رد جديد فقلت ربما يكون صحيح. وللأن ما جربته 

 

[Foksh]

1 ساعه مضت, abofayez1 said:

للأمانة جربت الكود الأول وحاولت فيه ولم يعمل معي

[abofayez1]

بيض الله وجهك .... فعلا عملت قاعدة جديدة فارغة وطبقت الخطوات وعمل بشكل سليم

 

ما رأيك بهذا وجدته في أحد المنتديات الاجنبية ويقوم بنفس العمل 

 

  With CreateObject("htmlfile")
        .parentWindow.clipboardData.clearData ("Text")
    End With

 

[Moosak]

للإثراء ،،، من مكتبتي العامرة 😊
 

3 أكواد لـ ( نسخ - لصق - تفريغ الذاكرة )

شرح الكود:
ضع الكود كاملا في موديول ثم استخدمه في البرنامج كما هو واضح في الأسفل ..

الكود:

'==================================================(Copy)
Public Function CopyText(ByVal Text As Variant) As Boolean
    CopyText = CreateObject("htmlfile").ParentWindow.ClipboardData.SetData("Text", Text)
End Function

'==================================================(Paste)
Public Function PasteText() As String
    On Error Resume Next
    PasteText = CreateObject("htmlfile").ParentWindow.ClipboardData.getData("Text")
End Function

'==================================================(Clear The ClipBoard)
Public Function ClearClipBoardText() As Boolean
    ClearClipBoardText = CreateObject("htmlfile").ParentWindow.ClipboardData.clearData("Text")
End Function

طريقة الاستدعاء (الاستخدام):

CopyText(Text)          <------ للنسخ
PasteText()                <------ للصق
ClearClipBoardText()     <------ تفريغ الذاكرة

مرجع:
#https://www.mrexcel.com/board/threads/vba-post-to-clipboard.1142841/#

مكتبة الأكواد