تعديل كود حذف مرفقات

[jo_2010]

الاستاذ والخبير الفاضل 

بعد التحية

ممكن لو تكرمت مساعدتى فى الاستفادة من البرنامج الخاص بالاخ الفاضل moho58

تعديل كود الخذف

ارجو اصلاح كود الحذف واضافة كود لحذف فولد الخاص     باسم الشخص    اذا كان فارغ ليس بة ملفات

 

base_s_w.accdb

تم تعديل منذ 23 ساعات بواسطه jo_2010

[Foksh]

أخي @jo_2010 ، قمت بتعديل بسيط على ملفك ، وهو إضافة حقل جديد = PathPic في الجدول لتخزين المسار فيه بشكل صريح بدلاً من الطريقة التي يم فيها جلب مسار الملف لحذفه ،

وأصبح الكود بعد تعديله في زر الحذف بالشكل التالي :-

On Error GoTo HandleError
    Dim fileToDelete As String
    Dim response As VbMsgBoxResult
    Dim db As DAO.Database
    Dim sql As String
    Dim recordID As String
    Dim subFolderPath As String
    recordID = [Forms]![frm_sader_wared]![Pname].Value
    subFolderPath = CurrentProject.Path & "\AttachedFiles\" & recordID
    fileToDelete = Me.PathPic.Value
    If Not IsNull(fileToDelete) And Dir(fileToDelete) <> "" Then
        response = MsgBox("هل تريد حقاً حذف هذا الملف؟", vbYesNo + vbQuestion, "تأكيد الحذف")
        If response = vbYes Then
            Kill fileToDelete
            Set db = CurrentDb()
            sql = "DELETE FROM TblAttchedFiles WHERE id=" & Me.ID
            db.Execute sql, dbFailOnError
            On Error Resume Next
            RmDir subFolderPath
            On Error GoTo HandleError
            Me.Requery
        End If
    Else
        MsgBox "لا يوجد شئ لحذفه", vbExclamation, "خطأ"
    End If
    
HandleExit:
    Exit Sub
    
HandleError:
    Select Case Err.Number
        Case 94
            MsgBox "لا يوجد شئ لحذفه", vbExclamation, "خطأ"
        Case Else
            MsgBox "خطأ رقم: " & Err.Number & vbNewLine & Err.Description, vbCritical, "خطأ"
    End Select
    Resume HandleExit

 

وهذا ملفك بعد التعديل

 

base_s_w.accdb

[jo_2010]

الخبير الفاضل Foksh

خالص الشكر