بحث بجزء من الجملة

[mohamed322]

السلام عليكم

 اريد بحث بجزء من كلمه  فى الجمله 

و شكراااا

بحث بجزء من الجمله.xls

[عبدالله بشير عبدالله]

وعليكم السلام ورحمة الله وبركاته 

 هناك بعض الغموض في الطلب ع

ما تم تنفبذه حسب الملف 

البحث فى العمود A باي حرف او كلمة  عند العثور عليها يضعها فى  C4   ونسبتها في E4

اذا تكرر البحث يدرج ما تم البحث عنه في صف جديد مع نسبته وهكذا 

اذا لم يجد الكلمة تانى رسالة بعدم وجودها

اذا لم يكن هذا طلبك ارجو التوضيح اكثر 

الكود 

Sub SearchAndCopy()
    Dim ws As Worksheet
    Dim searchWord As String
    Dim cell As Range
    Dim outputRow As Long
    Dim found As Boolean
    Set ws = ThisWorkbook.Sheets("SHEET1")
    searchWord = InputBox("أدخل الكلمة التي تريد البحث عنها:")
    If searchWord = "" Then Exit Sub
    outputRow = ws.Cells(ws.Rows.Count, 3).End(xlUp).Row + 1
    If outputRow < 4 Then outputRow = 4
    
    found = False
    For Each cell In ws.Range("A1:A" & ws.Cells(ws.Rows.Count, "A").End(xlUp).Row)
        If InStr(1, cell.Value, searchWord, vbTextCompare) > 0 Then
            ws.Cells(outputRow, 3).Value = searchWord
            ws.Cells(outputRow, 5).Value = cell.Offset(0, 1).Value
            outputRow = outputRow + 1
            found = True
        End If
    Next cell
    
    If Not found Then
        MsgBox "لم يتم العثور على الكلمة المطلوبة.", vbExclamation
    Else
        MsgBox "تم البحث والنقل بنجاح.", vbInformation
    End If
End Sub

الملف

بحث بجزء من الجمله.xls

[mohamed322]

السلام عليكم

انا محتاج مثال على ذالك لو اسمه  (مهندس ميكانيكا القاهرة) .80%

انا محتاج مثال على ذالك لو اسمه  (مهندس كهرباءالقاهرة) .70%

انا كنت محتاج اعمل بحث اكتب كهرباء فيجيب نسبه 70% زى vllokup محتاج اعمل بحث باى جزء من مهندس ميكانيكا القاهرة فيجيب ليا النسبة

وشكراااا

تم تعديل أكتوبر 23 بواسطه mohamed322

[mohamed322]

                    عمود a                              عمود b                                   c                                      e

  (مهندس ميكانيكا القاهرة)                     80%                                       ميكانيكا                               هنا اعمل بحث فى c فى عمود a e فيجيب نسبة e 80 %

                                                                                                                              زى  vlookup اعمل بحث ميكانيكا فى عمود a و e واحط شرط عاوز نسبه عمود 2

  (مهندس كهرباءالقاهرة)                         70%                                       كهرباء

(مهندس سيارات الشرقية )                       70%                                     سيارات

     محتاج اعمل بحث زى vllokup بس باأى جزء اعمل بحث فى الجدول سيارات 70 %

تم تعديل أكتوبر 23 بواسطه mohamed322

[عبدالله بشير عبدالله]

وعليكم السلام ورحمة الله وبركاته

ما قمت به انا حسب ملفك المرفق

اكتب فى العمود C  كلمة البحث بكلمة كاملة او بحرف منها  تجد النسبة مكتوبة فى العمود E

الكود

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim cell As Range
    Dim searchRange As Range
    Dim foundCell As Range
    If Not Intersect(Target, Me.Range("C4:C" & Me.Rows.Count)) Is Nothing Then
        Set searchRange = Me.Range("A1:A" & Me.Cells(Me.Rows.Count, "A").End(xlUp).Row)
        For Each cell In Intersect(Target, Me.Range("C4:C" & Me.Rows.Count))
            If cell.Value <> "" Then
                Set foundCell = searchRange.Find(What:=cell.Value, LookIn:=xlValues, LookAt:=xlPart, MatchCase:=False)
                If Not foundCell Is Nothing Then
                    cell.Offset(0, 2).Value = foundCell.Offset(0, 1).Value
                Else
                    cell.Offset(0, 2).Value = "لا يوجد"
                End If
            Else
                cell.Offset(0, 2).ClearContents
            End If
        Next cell
    End If
End Sub

الملف

بحث بجزء من الجمله1.xls

تم تعديل أكتوبر 23 بواسطه عبدالله بشير عبدالله

[mohamed322]

بعد لما ضيفت الكود مش شغال معايا 

هل ممكن حضرتك تضيف الكود فى الاكسيل وترفعه اكون شاكر ليك

[عبدالله بشير عبدالله]

الكود بضاف في حدث الورقة  بدون زر وبوجد ملفك وبه الكود فى المشاركة السابقة

حمل الملف واذا كان الماكرو غير مفعل فقم بتفعيله تمكبن المحتوى

بعد فتح الملف اكتب فى العمو دC كلمة البحث فقط تاتى لك بالنسبة%

الملف مرة اخرى وشغال 100%

بحث بجزء من الجمله1.xls

تم تعديل أكتوبر 23 بواسطه عبدالله بشير عبدالله

[mohamed322]

شكرااااااااااااااا جدااااااااااااااااا  على الاهتمام