عدم تكرار التسجيل

[mohamed.youssef]

السلام عليكم 

الاخوة الافاضل لو سمحتو لي محتاج في الملف المرفق اضافة كود تنبيه برسالة لو قمت بتسجيل صنف مرة اخرى عن طريق الخطأ تظهر الرسالة الصنف مسجل مسبقا 

مع الشكر 

عدم تكرار.xlsm

[محمد هشام.]

وعليكم السلام ورحمة الله تعالى وبركاته 

الملف مليئ بالاكواد ممكن توضح الكود بالظبط او اسم اليوزرفورم المطلوب التعديل عليه 

[mohamed.youssef]

السلام عليكم 

اخي الفاصل على الشاشة الرئيسية عند اضافة كود صنف جديد وملئ خانات الشاشة من لون ومقاس اذا كان الصنف المسجل مسجل مسبقا تأتي رسالة تنبيه بانه مسجل من بل واذا اردت اخي هناك لينك على الشاشة للدخول الى الملف اتمنى ان اكون وصلت طرح مشكلتي مع الشكر

[محمد هشام.]

تفضل جرب هدا

Private Sub CommandButton1_Click()
    Dim ws As Worksheet, src As Range, i As Long
    Dim arr() As Variant, columns() As Variant
    Dim Code As String, lastrow As Long, exists As Long
    
    Set ws = Sheets("التكويد")
    
    lastrow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
    Code = Me.TextBox4.Value

    If Code = "" Then: MsgBox "الرجاء إدخال كود الصنف", vbExclamation, "خطأ": Exit Sub
    
    exists = WorksheetFunction.CountIf(ws.Range("a2:a" & lastrow), Code)

    If exists > 0 Then: MsgBox "كود الصنف موجود مسبقا", vbExclamation, "إنتبـــاه": Me.TextBox4.Value = "": Exit Sub
    
   With Application
        .ScreenUpdating = False
        .Calculation = xlCalculationManual
    End With
    
    Set src = ws.Range("A" & ws.Rows.Count).End(xlUp).Offset(1, 0)
    
    columns = Array("A", "B", "C", "D", "F", "G", "H")
    arr = Array(Me.TextBox4.Value, Me.TextBox1.Value, Me.TextBox7.Value, Me.TextBox2.Value, _
                Me.TextBox3.Value, Me.TextBox5.Value, Me.TextBox6.Value)

    For i = LBound(arr) To UBound(arr)
        If i <= UBound(columns) Then
            ws.Cells(src.Row, columns(i)).Value = arr(i)
        End If
    Next i
    
        For Each ctrl In Me.Controls
            If TypeName(ctrl) = "TextBox" Then
                ctrl.Value = ""
            End If
        Next ctrl
 
With Application
        .ScreenUpdating = True
        .Calculation = xlCalculationAutomatic
    End With
   MsgBox "تم إدخال البيانات بنجاح", vbInformation, "نجاح"
End Sub

 

عدم تكرار .xlsm

[mohamed.youssef]

السلام عليكم 

اخي الفاصل على الشاشة الرئيسية عند اضافة كود صنف جديد وملئ خانات الشاشة من لون ومقاس اذا كان الصنف المسجل مسجل مسبقا تأتي رسالة تنبيه بانه مسجل من بل واذا اردت اخي هناك لينك على الشاشة للدخول الى الملف اتمنى ان اكون وصلت طرح مشكلتي مع الشكر

السلام عليكم اخي الفاضل

الف شكر على المساعدة والاهتمام بارك الله فيك شكرا مرة اخرى

[محمد هشام.]

العفو اخي يسعدنا أننا إستطعنا مساعدتك