تغيير اسم تقرير ( pdf او ورد ) الذي يتم تصديرة الى قيمة (لمتغير او حقل ) مع تاريخ والوقت

[qathi]

السلام عليكم
حياكم الله اساتذتنا الافاضل واعضاء منتدانا الشامخ
طبتم وطابت ايامكم .. أسأل الله أن تكونوا في أتم الصحة والعافيه

المطلوب كالتالي:
في نموذج prin الخاص بشريط الطباعة
عند الضغط على زر ( حفظ Word ) أو زر ( حفظ pdf ) يتم تصدير الملف الناتج باسم ياخذ قيمته من ( متغير أو حقل الموجود في النموذج Namea ) والتاريخ والوقت

مثال:

 محمد طاهر 2024/10/14-08:40ص.pdf

 

مع العلم أن التقرير الحالي يتم تصدير باسم التقرير الاساسي (rpt_rensen) بالرغم تغير اسماء الاشخاص وهذه مشكلة

مرفق ملف للتعديل علية

شريط طباعة.accdb

[محمد احمد لطفى]

تفضل 

pdf
 

    Dim fileName As String
    fileName = Me.Namea & " - " & Format(Now(), "yyyy-mm-dd") & " " & Format(Now(), "hh mm AM/PM") & ".pdf"
    DoCmd.OutputTo acOutputReport, namerpts, acFormatPDF, fileName, True, , , acExportQualityPrint

Word

 

    Dim fileName As String
    fileName = Me.Namea & " - " & Format(Now(), "yyyy-mm-dd") & " " & Format(Now(), "hh mm AM/PM") & ".doc"
    DoCmd.OutputTo acOutputReport, namerpts, acFormatRTF, fileName, True, , , acExportQualityPrint

 

شريط طباعة.rar

[Foksh]

ومشاركة مع الأستاذ محمد لطفي ، قمت بإنشاء دالة واحدة يتم استدعائها في اي من الزرين لتنفيذ المهمة حسب الزر .

 

Private Sub أمر17_Click()
    ExportReport "PDF", Me.Namea.Value
End Sub

Private Sub أمر18_Click()
    ExportReport "RTF", Me.Namea.Value
End Sub

Private Sub ExportReport(formatType As String, userName As String)
    On Error Resume Next
    Dim fileName As String
    fileName = userName & " - " & Format(Now(), "yyyy-mm-dd") & " " & Format(Now(), "hh nn AM/PM") & IIf(formatType = "PDF", ".pdf", ".doc")
    Dim filePath As String
    filePath = CurrentProject.Path & "\" & fileName
    DoCmd.OutputTo acOutputReport, namerpts, IIf(formatType = "PDF", acFormatPDF, acFormatRTF), filePath, True, , , acExportQualityPrint
End Sub

 

ملفك بعد التعديل (   شريط طباعة.accdb   )

[qathi]

أهلا بك استاذنا @محمد احمد لطفى 

وشكرا لك على مجهودك الرائع

يتم تغيير اسم التقرير ويظهر الملف الناتج بشكل مباشر

متبقي عرض نافذة حفظ التقرير حتى يتم تحديد مكان حفظ التقرير الناتج كما في الملف السابق

 

مع شكري لك

4 دقائق مضت, Foksh said:

ملفك بعد التعديل

أهلا بك استاذنا @Foksh

ساقوم بتجربته الان واوافيك بالنتائج

[ابوخليل]

عندي استفساران

الأول لأخوتي واحبتي الخبراء 

الى تكفي الدالة NOW  لوحدها بدون تنسيقات مصاحبة .. لأن التنسيقات موجودة بها فعلا ... انا لم اجرب فقط استفسار

الثاني لصاحب الموضوع :

لماذا تفتح مربع الحوار لحفظ الملفات .. عادة الحفظ يكون في مجلد محدد مسبقا  .. وهذا المجلد سيعرفه اكسس فيما لو اردنا مستقبلا الطباعة او الفتح

غالبا مربع الحوار نحتاجه عند الجلب 

[qathi]

26 دقائق مضت, Foksh said:

ومشاركة مع الأستاذ محمد لطفي ، قمت بإنشاء دالة واحدة يتم استدعائها في اي من الزرين لتنفيذ المهمة حسب الزر .

استاذنا @Foksh

قمت بتجربت الملف أكثر من رائع ينقصة هو كذلك مربع الحوار لتحديد مكان الحفظ

 

وياريت تكتمل الدالة بحفظ ملف بصيغة اكسل

 

اكرر شكري لكم

 

15 دقائق مضت, ابوخليل said:

لماذا تفتح مربع الحوار لحفظ الملفات .. عادة الحفظ يكون في مجلد محدد مسبقا  .. وهذا المجلد سيعرفه اكسس فيما لو اردنا مستقبلا الطباعة او الفتح

أهلا باستاذنا الكبير والغالي @ابو خالد
@ابوخليل

 

أعتذر من تخبط الكيبورد وصعوبه التعديل من الجوال

والله اشتقنى لكم جميعا

أسأل الله أن تكون في اتم الصحة والعافية

بالنسبة لسؤالك فعلا استفاد منه في عدة حالات اوتوقع ولم اجرب منها إرسال الملف عبر الواتس

لكن ما اريدة أن المستخدم النهائي له حرية حفظ الملف في أي مكان يريده

تم تعديل الإثنين at 16:49 بواسطه qathi
أخطاء نصية

[محمد احمد لطفى]

أستاذى @ابوخليل 

عند استخدم الدالة NOW 
فإن وجود الفواصل (/ و  : سيؤدي إلى عدم إمكانية حفظ الملف، نظرًا لأن نظام الملفات لا يسمح بهذه الرموز في أسماء الملفات 


 

[Foksh]

37 دقائق مضت, ابوخليل said:

الى تكفي الدالة NOW  لوحدها بدون تنسيقات مصاحبة .. لأن التنسيقات موجودة بها فعلا ... انا لم اجرب فقط استفسار

 

معلمي القدير وأستاذنا الجليل @ابوخليل :-

 

في الدالة Now ، لن ينجح الأمر والسبب باعتقادي هو احتواء التنسيق على حروف غير مسموح بها كإسم لملف أو مجلد = " : " وهو النقطتين

هذا رأيي ما لم يكن هناك سبب آخر ، حيث أنه في التنسيق المصاحب للدالة Now في الأكواد تم ضبط التنسيق بإزالة النقطتين .

لم انتبه لرد الأستاذ @محمد احمد لطفى ، فلم يكن الرد موجوداً قبل ردي واعتقد أنني كنت في الصفحة مسبقاً ولم أعمل تحديث 

[ابوخليل]

@محمد احمد لطفى  @Foksh

 

جزاكما الله خيرا .. هذه معلومة خفية جميلة قد لا تتبادر الى الذهن 

.

.

36 دقائق مضت, qathi said:

بالنسبة لسؤالك فعلا استفاد منه في عدة حالات اوتوقع ولم اجرب منها إرسال الملف عبر الواتس

يكفي الرابط .. بدلالة الاسم او المعرف

36 دقائق مضت, qathi said:

لكن ما اريدة أن المستخدم النهائي له حرية حفظ الملف في أي مكان يريده

انت حر .. لكن في هذه الحالة سيتسع الفتق على الراتق

[qathi]

3 دقائق مضت, ابوخليل said:

يكفي الرابط .. بدلالة الاسم او المعرف

ممكن توضيح أكثر معلمنا القدير @ابوخليل

[Foksh]

42 دقائق مضت, qathi said:

قمت بتجربت الملف أكثر من رائع ينقصة هو كذلك مربع الحوار لتحديد مكان الحفظ

 

استبدل الدالة السابقة بالتالي :-

Private Sub ExportReport(formatType As String, userName As String)
    On Error Resume Next
    Dim fileName As String
    fileName = userName & " - " & Format(Now(), "yyyy-mm-dd") & " " & Format(Now(), "hh nn AM/PM") & IIf(formatType = "PDF", ".pdf", ".doc")
    Dim filePath As String
    With Application.FileDialog(2)
        .Title = "اختر موقع الحفظ"
        .AllowMultiSelect = False
        .InitialFileName = fileName
        If .Show = -1 Then
            filePath = .SelectedItems(1)
        Else
            Exit Sub
        End If
    End With
    DoCmd.OutputTo acOutputReport, namerpts, IIf(formatType = "PDF", acFormatPDF, acFormatRTF), filePath, True, , , acExportQualityPrint
End Sub

أما فيما يتعلق بالتصدير كملف Excel فأعتقد أنه قد يختلف عما يدور في خيالك وله ضبط خاص .

[qathi]

ماشاء الله عليك هذا هو المطلوب استاذنا الغالي @Foksh
.

حفظك الله وبارك الله فيك وزادك الله علما ونورا

 

22 دقائق مضت, Foksh said:

أما فيما يتعلق بالتصدير كملف Excel فأعتقد أنه قد يختلف عما يدور في خيالك وله ضبط خاص .

ياريت استاذنا الغالي تتكرم عليه به

ولك دعوه في ظهر العيب

أكون شاكرا لك

وجزاك الله عني خير

[ابوخليل]

25 دقائق مضت, qathi said:

ممكن توضيح أكثر معلمنا القدير @ابوخليل

في نموذج التصدير تسمية  الازرار  = حفظ وورد ، حفظpdf

فأنا اتكلم من هذا المنطلق .. فالحفظ يختلف تماما عن عملية تصدير فقط

اذا الملفات غير مهمة ( ويمكن التصدير في اي وقت) .. ولست بحاجة الى الرجوع لها مستقبلا .. فلا مشكلة سر في طريقك

[Foksh]

16 دقائق مضت, qathi said:

ياريت استاذنا الغالي تتكرم عليه به

 

تفضل ، هذا تعديل سريع ، جربه وأخبرني بالنتيجة :-

Private Sub ExportReport(formatType As String, userName As String)
    On Error Resume Next
    Dim fileName As String
    fileName = userName & " - " & Format(Now(), "yyyy-mm-dd") & " " & Format(Now(), "hh nn AM/PM") & IIf(formatType = "PDF", ".pdf", IIf(formatType = "Excel", ".xls", ".doc"))
    Dim filePath As String
    With Application.FileDialog(2)
        .Title = "اختر موقع الحفظ"
        .AllowMultiSelect = False
        .InitialFileName = fileName
        If .Show = -1 Then
            filePath = .SelectedItems(1)
        Else
            Exit Sub
        End If
    End With
    Dim outputFormat As Integer
    Select Case formatType
        Case "PDF"
            outputFormat = acFormatPDF
        Case "RTF"
            outputFormat = acFormatRTF
        Case "Excel"
            outputFormat = acFormatXLSX
        Case Else
            Exit Sub
    End Select
    If outputFormat = acFormatXLSX Then
        DoCmd.OutputTo acOutputReport, namerpts, outputFormat, filePath, True, , , acExportQualityPrint
    Else
        DoCmd.OutputTo acOutputReport, namerpts, outputFormat, filePath, True, , , acExportQualityPrint
    End If
End Sub

وعليه فأن الإستدعاء لزر الحفظ Excel سيكون على الشكل التالي :-

ExportReport "Excel", Me.Namea.Value

 

الملف بعد الإضافة والتعديل (  شريط طباعة.accdb  )

تم تعديل الإثنين at 18:09 بواسطه Foksh
اضافة المرفق

[qathi]

13 دقائق مضت, Foksh said:

هذا تعديل سريع ، جربه وأخبرني بالنتيجة

استاذنا @Foksh

قمت بتجربة الملف الان

ملف الاكسل يتم تصديرة نعم أنه ترتيبه بشكل آخر لكن لاباس به

لكن تضهر مشكلة تلف في تصدير ملف لورد وال PDF

 

هل ممكن جعل الدالة اكسل مستقله عن دالة الورد وال pdf

[Foksh]

قمت بتغيير النهج عن السابق ، ويبدو انني قد اغفلت عن تجربة زري الـ Pdf و الـ Rtf . 🤦

حالما اصل المنزل سأقوم بالتعديل إن شاء الله 

[Foksh]

تفضل يا صديقي ،، التعديل الجديد :-

 

Private Sub ExportReport(formatType As String, userName As String)
    On Error Resume Next
    Dim fileName As String
    Select Case formatType
        Case "PDF"
            fileName = userName & " - " & Format(Now(), "yyyy-mm-dd") & " " & Format(Now(), "hh nn AM/PM") & ".pdf"
        Case "RTF"
            fileName = userName & " - " & Format(Now(), "yyyy-mm-dd") & " " & Format(Now(), "hh nn AM/PM") & ".doc"
        Case "Excel"
            fileName = userName & " - " & Format(Now(), "yyyy-mm-dd") & " " & Format(Now(), "hh nn AM/PM") & ".xls"
    End Select
    Dim filePath As String
    With Application.FileDialog(2)
        .Title = "اختر موقع الحفظ"
        .AllowMultiSelect = False
        .InitialFileName = fileName
        If .Show = -1 Then
            filePath = .SelectedItems(1)
        Else
            Exit Sub
        End If
    End With
    Dim outputFormat As Variant
    Select Case formatType
        Case "PDF"
            outputFormat = acFormatPDF
        Case "RTF"
            outputFormat = acFormatRTF
        Case "Excel"
            outputFormat = acFormatXLS
    End Select
    DoCmd.OutputTo acOutputReport, namerpts, outputFormat, filePath, True, , , acExportQualityPrint
End Sub

 

الملف بعد التعديل :- (  شريط طباعة.accdb  )

[qathi]

بارك الله فيك استاذنا الغالي @Foksh😚

قمت بتجربة الملف يعمل بنجاح

ساقوم بنقل الاكواد لملفي الخاص واقوم بتجربته

 

جزاك الله عني خيرا

اسأل الله ان يدخلك الجنة الفردوس الاعلى ووالديك وذريتك واهلك

 

أستاذي أن سمحت اتمنى ان تخبرني باسمك الاول والاخير حتى ادعوك لك بضهر الغيب

 

أعتذر من الاموجي يرفض الحذف

تم تعديل الإثنين at 20:09 بواسطه qathi