الجمع حسب نطاق معين

[hussam031]

السلام عليكم

 

يرجى الاطلاع على الملف المرفق و المساعدة في ايحاد المجموع 

 

مع الشكر

Officena.xlsx

[محمد هشام.]

وعليكم السلام ورحمة الله تعالى وبركاته 

الخيار رقم 1

لاستخراج النتائج اظن انك بحاجة لفك الدمج على خلايا العمود A  حيث أن الخلايا المدمجة تعتبر خلية واحدة في Excel  مما يسبب تعارضا مع الدوال

  قم بإلغاء دمج الخلايا في العمود A  (الصفوف 4 و 5)  بحيث تصبح كل صف يحتوي على القيمة الصحيحة  و بعد إلغاء الدمج استخدم المعادلة التالية

=SUMPRODUCT(($A$4:$A$7=I14)*($B$4:$B$7=J14)*($C$4:$E$7))

إذا كنت تريد الاحتفاظ بالدمج  يمكنك استخدام عمود مساعد (على سبيل المثال العمود O ) لتكرار القيم الموجودة في  العمود A

في الخلية O14 مثلا  استخدم المعادلة التالية  مع سحبها للاسفل 

=IF(A4<>"", A4, O13)

استخدم المعادلة التالية في الخلية M14  لتستخدم العمود المساعد بدلًا من العمود المدمج A

=SUMPRODUCT(($O$14:$O$17=I14)*($B$4:$B$7=J14)*($C$4:$E$7))

 

Officena (1).xlsx

تم تعديل سبتمبر 22, 2024 بواسطه محمد هشام.

[hussam031]

شكرا لك استاذ  محمد الله يجزيك الخير

هل يمكن العمل بدالة INDEX + MATCH برأيك ؟؟

 

 

[محمد هشام.]

   INDEX او  MATCH وحدهما لا تسمح لك بجمع نطاق متعدد الأعمدة بناءا على شروط معينة في نطاقات أخرى كما هو الحال مع  SUMPRODUCT  او SUMIFS   لانها  غالبا تستخدم لاستخراج قيمة واحدة من نطاق معين بشرط تطابق صف وعمود وليس لجمع نطاق كامل

اما ادا كنت بحاجة الى بدائل تنفد نفس المهمة يمكنك استخدام احدى المعادلات التالية 

=SUMPRODUCT((($O$14:$O$17=I14)*($B$4:$B$7=J14)), MMULT(($C$4:$E$7), TRANSPOSE(COLUMN($C$4:$E$4)^0)))
او

=SUM(FILTER($C$4:$E$7, ($O$14:$O$17=I14)*($B$4:$B$7=J14)))

او

=SUMPRODUCT(($O$14:$O$17=I14)*($B$4:$B$7=J14)*$C$4:$C$7) +
 SUMPRODUCT(($O$14:$O$17=I14)*($B$4:$B$7=J14)*$D$4:$D$7) +
 SUMPRODUCT(($O$14:$O$17=I14)*($B$4:$B$7=J14)*$E$4:$E$7)

او

=SUMIFS($C$4:$C$7, $O$14:$O$17, I14, $B$4:$B$7, J14) +
 SUMIFS($D$4:$D$7, $O$14:$O$17, I14, $B$4:$B$7, J14) +
 SUMIFS($E$4:$E$7, $O$14:$O$17, I14, $B$4:$B$7, J14)

 

Officena 2.xlsx

[hussam031]

لك كل الشكر استاذ محمد

 

[محمد هشام.]

العفو اخي يسعدنا اننا استطعنا مساعدتك