كود لفتح الورقة واخر لاغلاق

[حليم ناصر]

سلام عليكم ورحمة الله تعالى وبركاته

سادة الاعضاء سلام عليكم اتمنى ان تكونوا في احسن حال ان شاء الله
لي طلبين في نفس الموضوع
الطلب الأول
اعمل الان على برنامج خاص بالعمل فيه عدد  من الأوراق ( Feuil ) واحب ان اجعل لبعض الاوراق العمل  كود (كلمة سر) عند الدخول , 
قد تكون لهذه الاوراق نفس الكود (كلمةالسر) وهذا لكي لا تتعقد  , المهم عند الدخول الى الورقة من هذه الاوراق  تفتح عادي لكن بمجرد محاولة العمل يطلب منك كود 
أي انه عند الدخول الى الورقة  يسمح لك بمعاينة الورقة او بنسخ  لكن بمجرد البدء في تغير او اضافة معلومات  يطلب منك كود( كلمة السر)
الطلب الثاني 
 عند إتمام العمل واغلاق الورقة أو اغلاق الاكسال اريد  كود يقوم باغلاق تلك الأوراق  دون اجراء الخطوات العادية للاغلاق 
وعند فتح الاكسال من جديد والدخول الى احدى هذه الاوراق والشروع بالعمل يطلب منك ( كلمة السر ) وهكذا

أي كود لفتح الورقة للعمل بكلمة سر  وكود ثاني لاغلاق الورقة عند الخروج منها

ارجو ان أكون قد شرحت الطلب بصورة حسنة وان اجد الجوب ان شاء الله

وفي انتظارردكم تقبلو مني فائق التقديروالاحترام
وجزاكم الله عنا وعن كل من تساعدونهم خيرا
 

[محمد هشام.]

وعليكم السلام ورحمة الله تعالى وبركاته 

جرب هدا ربما يناسبك

Module

Sub ProtectWS()
Dim sh As Variant, MyArray As Variant, Password As String
Password = "1234"
MyArray = Array(Sheet1, Sheet2) ' <<=== ' اسماء الاوراق المرغوب حمايتها
For Each sh In MyArray
        sh.Protect Password, UserInterfaceOnly:=True, AllowFiltering:=True
    Next sh
End Sub

ThisWorkbook

Private Sub Workbook_Open()
ProtectWS
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
ProtectWS
End Sub

وفي حدث الاوراق المحددة 

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim Password As String
    Dim Clé As String
    Password = "1234" ' الباسوورد الخاص بك
    If Me.ProtectContents Then
        Clé = InputBox(" الورقة محمية يرجى إدخال كلمة المرور")
                If Clé = Password Then
            Me.Unprotect Password
        Else
            MsgBox "كلمة المرور غير صحيحة", vbCritical
            Exit Sub
        End If
    End If
End Sub
' في جالة الرغبة بنسخ البيانات من ورقة لاخرى يمكنك  تعطيل الكود التالي
Private Sub Worksheet_Deactivate()
    Dim Password As String
    Password = "1234"
    Me.Protect Password
End Sub

 

test.xlsb

[حليم ناصر]

سلام عليكم ورحمة الله تعالى وبركاته

 

اشكرك على الرد وبارك الله فيك

ساجربه

مرة اخرى  شكرا وجزاك الله عنا خير

والسلام عليكم ورحمة الله تعالى وبركاته

[حليم ناصر]

سلام عليكم ورحمة الله تعالى وبركاته

الكود يعمل جيدا

مرة اخرى  شكرا وجزاك الله عنا خير

والسلام عليكم ورحمة الله تعالى وبركاته