طريقة حساب حقل محسوب باكتر من معادله بناء على اختيار من مربع الاختيار

[safaa salem5]

عندى اربع حقول منضمه  كالاتى  S ,U,V,C            

مطلوب حساب حقل ال C 

بواحد من المعادلات الاتيه

  واللى هيتم تحديدها باختيار المستخدم عند التعليم فى مربع الاختيار CHECK BOX

 Creatinine clearence   فى الحالة الاولى عند التعليم امام

C= U× V/1440× S               

-----------------------------------------------------------------------------------------------------------------

Cockcroft formula  الحاله الثانيه  عند التعليم امام

C=    [(140- age)× wt kg / [(72× S)]                  (Male) اذا كان حقل يساوى gender )     

C=    [(140- age)× wt kg / (72× S)]× 0.85       (Female) اذا كان حقل يساوى gender ) 

----------------------------------------------------------------------------------------------------------------

-

MDRD  الحاله الثالثه عند التعليم امام

C= 175×  [S]^-1.154 × [age]^-0.203                                  (Male) اذا كان حقل يساوى gender )       

C= 175×  [S]^-1.154   × [age]^-0.203     × 0.742           (Female) اذا كان حقل يساوى gender )

-----------------------------------------------------------------------------------------------------------------

مع العلم بوجود حقول 

age ,gender

فى نفس الفورم

اما  حقل الوزن wt kg   

  هيتم استدعاؤه من فورم reservation_frm

بشرط تساوى حقول ال id فى كلا الفورمين

تم تعديل أغسطس 6 بواسطه safaa salem5

[safaa salem5]

                     خلاص الحمدلله تم  الحل 
   

Private Sub V_AfterUpdate()
 Dim C As Double
        Dim age As Integer
        Dim wt_kg As Double
        Dim S As Double
    ' تحديد المعادلة بناءً على اختيار المستخدم
    If Me.Creatinine_clearence = True Then
        ' استخدام Creatinine clearance equation
        Me.C = Me.U * Me.V / (1440 * Me.S)
    ElseIf Me.Cockcroft = True Then
        ' Cockcroft formula
       
        
        ' استعادة القيم من النموذج
        age = Me.age
        wt_kg = DLookup("wt_kg", "resrvation_tbl", "id = " & Me.ID)
        S = Me.S
        
        ' حساب قيمة C باستخدام Cockcroft formula
        If Me.gender = "Male" Then
            C = (140 - age) * wt_kg / (72 * S)
        Else
            C = (140 - age) * wt_kg / (72 * S) * 0.85
        End If
        Me.C = C
    ElseIf Me.MDRD = True Then
        ' MDRD equation
      
        
        ' استعادة القيم من النموذج
        age = Me.age
        S = Me.S
        
        ' حساب قيمة C باستخدام MDRD equation
        If Me.gender = "Male" Then
            C = 175 * S ^ (-1.154) * age ^ (-0.203)
        Else
            C = 175 * S ^ (-1.154) * age ^ (-0.203) * 0.742
        End If
        Me.C = C
    End If
End Sub

تم تعديل أغسطس 6 بواسطه safaa salem5

[safaa salem5]

محتاجه حاجه صغيره بس         

            Creatinine_clearenceلما اعلم على

الكود اللى فوق يحصل فى حدث

Private Sub V_Change()

ولما اعلم على    Cockcroft   او    MDRD

 

الكود اللى فوق يحصل فى حدث

Private Sub S_Change()

تم تعديل أغسطس 6 بواسطه safaa salem5

[Foksh]

أختنا الكريمة @safaa salem5 ، تماشياً مع قوانين المنتدى ، أتمنى الإلتزام بما يلي ,,

1. الشرح الوااااااااافي الكافي للمطلوب .

2. إدراج ملف مرفق وهذا أمر ضروري أيضاً .

3. استخدام الرمز المشار إليه بالدائرة الحمراء عند وضع الأكواد  .

 

 وتذكري أن الجميع هنا أخوة وأصدقاء ونساند بعضنا بكل ما نملكه من صفاء النية ولا أحد يحمل في قلبه ذرة حقد أو كره لأحد 

 

تم تعديل أغسطس 6 بواسطه Foksh

[safaa salem5]

15 minutes ago, Foksh said:

أختنا الكريمة @safaa salem5 ، تماشياً مع قوانين المنتدى ، أتمنى الإلتزام بما يلي ,,

1. الشرح الوااااااااافي الكافي للمطلوب .

2. إدراج ملف مرفق وهذا أمر ضروري أيضاً .

3. استخدام الرمز المشار إليه بالدائرة الحمراء عند وضع الأكواد  .

 

 وتذكري أن الجميع هنا أخوة وأصدقاء ونساند بعضنا بكل ما نملكه من صفاء النية ولا أحد يحمل في قلبه ذرة حقد أو كره لأحد 

 

معتقدش فى شرح وافى اكتر من اللى انا شرحاه

وعموما انا عملت الكود مش محتاجه غير اخر نقطه  اللى هى تحديد الحقل اللى هيتم تحته الحدث بناء على الاختيار من مربع الاختيار

تم تعديل أغسطس 6 بواسطه safaa salem5

[Foksh]

1 ساعه مضت, safaa salem5 said:

وعموما انا عملت الكود مش محتاجه غير اخر نقطه  اللى هى تحديد الحقل اللى هيتم تحته الحدث بناء على الاختيار من مربع الاختيار

على العموم ,,

Private Sub V_Change()
    If Me.Creatinine_clearence = True Then
        Dim C As Double
        Dim age As Integer
        Dim wt_kg As Double
        Dim S As Double
        Me.C = Me.U * Me.V / (1440 * Me.S)
    End If
End Sub

Private Sub S_Change()
    If Me.Cockcroft = True Or Me.MDRD = True Then
        Dim C As Double
        Dim age As Integer
        Dim wt_kg As Double
        Dim S As Double

        ' استعادة القيم من النموذج
        age = Me.age
        wt_kg = DLookup("wt_kg", "resrvation_frm", "id = " & Me.ID)
        S = Me.S

        If Me.Cockcroft = True Then
            ' Cockcroft formula
            If Me.gender = "Male" Then
                C = (140 - age) * wt_kg / (72 * S)
            Else
                C = (140 - age) * wt_kg / (72 * S) * 0.85
            End If
            Me.C = C
        ElseIf Me.MDRD = True Then
            ' MDRD equation
            If Me.gender = "Male" Then
                C = 175 * S ^ (-1.154) * age ^ (-0.203)
            Else
                C = 175 * S ^ (-1.154) * age ^ (-0.203) * 0.742
            End If
            Me.C = C
        End If
    End If
End Sub

Private Sub Creatinine_clearence_AfterUpdate()
    If Me.Creatinine_clearence = True Then
        Me.Cockcroft = False
        Me.MDRD = False
        Call V_Change
    End If
End Sub

Private Sub Cockcroft_AfterUpdate()
    If Me.Cockcroft = True Then
        Me.Creatinine_clearence = False
        Me.MDRD = False
        Call S_Change
    End If
End Sub

Private Sub MDRD_AfterUpdate()
    If Me.MDRD = True Then
        Me.Creatinine_clearence = False
        Me.Cockcroft = False
        Call S_Change
    End If
End Sub