مساعدة في ايجاد الخطاء في قرائة الفاتورة الالكترونية عن طريق الكيو اركود

[أمير ادم]

السلام عليكم ورحمة الله وبركاتة

 

لدي جدول به بيانات الفاتورة 

واضافة الكيو اركود ويظهر معي الكيو اركود ولكن عند عمل اسكان على الكيو اركود ياتي لي بعد المسح بان لايوجد كيور ار في الصورة

ماهو السبب واين يوجد الخطاء

لاني تعبت ومللت من كثرة البحث  في حل لاظهار بيانات الكيو اركود ولكن للاسف فشلت

مرفق قاعدة بيانات بها كل شي

شكرا لكم اساتذتي ومعلمي ومشرفي ومبرمجي موقعنا الكريم

Qrcode.accdb

[Foksh]

أخي الكريم @أمير ادم  ، قمت بتعديل جذري على فكرتك بحيث ابتعدت عن الاعتماد على موقع يقوم  بإنشاء كود QR ، واستعنت ببرنامج صغير يدعم اللغة العربية أيضاً ، وأعدت صياغة الكود كما يلي ، مع العلم أن المشكلة لديك كانت في تنسيق مربع النص AD_Invoice_Time_and_Date ..

 

تفضل تجربتي وأخبرني بالنتيجة 

 

QR.zip

تم تعديل مايو 24 بواسطه Foksh

[أمير ادم]

مشكور اخي Foksh الكريم على مرورك الكريم

ولكن قرء لي ولم ياتي لي بالبيانات الصحيه

مثل ماهو بالصوره مالسبب

 

 

 

 

 

 

تم تعديل مايو 24 بواسطه أمير ادم

[Foksh]

2 ساعات مضت, أمير ادم said:

ولكن قرء لي ولم ياتي لي بالبيانات الصحيه

 

فهمتك أخي الكريم @أمير ادم ، ولكن على ما يبدو أنه بسبب عدم وجود البرامج التي تم تثبيتها على جهازك لم يعمل الملف معي بشكل صحيح ، لذا اضطررت الى الاتجاه على طريق آخر ،، على العموم جرب هذا الكود كمحاولة فقط لتحديد التنسيق في حقل الوقت والتاريخ .

On Error Resume Next
Dim apiUrl As String
Dim qrData As String
Dim savePath As String
Dim result As Long
Dim formattedDate As String
formattedDate = Format(Me.AD_Invoice_Time_and_Date, "yyyy-mm-dd hh:nn:ss ampm")
Me.AD_Associatedcells = Me.AD_Company_Vendor_Name & "_" & Me.AD_Tax_Number & "_" & formattedDate & "_" & Me.AD_InvoiceAmountwithaddedvalue & "_" & Me.AD_VAT
qrData = Me.AD_Associatedcells.Value
apiUrl = "https://api.qrserver.com/v1/create-qr-code/?data=" & qrData & "&size=200x200"
savePath = Application.CurrentProject.Path & "\qr_code.bmp"
result = URLDownloadToFile(0, apiUrl, savePath, 0, 0)
If result = 0 Then
    Me.imgQRCode.Picture = savePath
Else
    MsgBox "Failed to download QR code image.", vbExclamation
End If

 

أو ارفق لنا البرامج التي تم تثبيتها على الكمبيوتر عندك والسبب وجود مكتبات ناقصة كما في الصورة

 

[أمير ادم]

شكرا لك اخي على التعاون ولكن يوجد لدينا هنا برنامج E-INVOICE QR READER يعمل على الاند رويد والابل  ومن خلاله نعلم عند قرائة الباركود ياتي لنا ببيانات الفاتورة مثل هذا

 

[Foksh]

8 ساعات مضت, أمير ادم said:

شكرا لك اخي على التعاون ولكن يوجد لدينا هنا برنامج E-INVOICE QR READER يعمل على الاند رويد والابل  ومن خلاله نعلم عند قرائة الباركود ياتي لنا ببيانات الفاتورة مثل هذا

 

 

أخي الكريم إذا تكرمت ، ارفق لنا الملفات الثلاثة في ملف مضغوط وارفعه على جوجل درايف إذا كان الميديافاير لا يعمل عندكم في مصر ( حسب ما ذكر أحد الإخوة لي سابقاً ) 

تم تعديل مايو 25 بواسطه Foksh

[أمير ادم]

https://www.mediafire.com/file/quuf2bcf66alapj/xv.rar/file

هذه هي الملفات التي تلبطها لكن اظن انها ليسى لها علاقه بقرائة الكيو ار كود الخاص بهيئة الذكاء والدخل والجمارك هنا 

مشكور جدا على مجهودك الكريم وعلى اهتمامك بالامر 

[Foksh]

46 دقائق مضت, أمير ادم said:

لكن اظن انها ليسى لها علاقه بقرائة الكيو ار كود الخاص بهيئة الذكاء والدخل والجمارك هنا

أخي الكريم ليست الفكرة بالعلاقة ، ولكن حتى يتم اشاء الـ QR عندي في جهازي وأعرف السبب في عدم تشغيله بشكل صحيح ،

والمشكلة وضحت الآن وهي ان هذا الاسلوب أو النظام الذي تتبعه من خلال الموقع الذي ينشئ الصورة لا تدعم اللغة العربية ، جرب اكتب بدل بنده اسم باللغة الانجليزية تجد انه يعمل بشكل صحيح 100000% في الكود الذي ارسلته لك ..

 

 

[أمير ادم]

اقدر مجهودك اخي الكريم ولكن لايستجيب معي 

تم التعديل للغه الانجليزيه ولاكن لا يستجيب

 

[Foksh]

أخي الكريم @أمير ادم ، أسعد الله أوقاتك ، وأعتذر عن المحاولات السابقة إلى أن توضحت الأمور في متطلبات رمز الـ QR .

من الواضح أن هيئة الزكاة تعتمد على طريقة تشفير وترميز البيانات باستخدام EncodeTLV . ثم يتم تشفير البيانات باستخدام الترميزات EncodeBase64 ، كما كان في تجربة سابقة لفهم آليه التشفير .. والحمد لله أعتقد أنني توصلت إلى حل  .

جرب هذا الكود كاملاً مع وظائف التشفير والإسترداد بالترميز الذي يتعرف عليه نظام الفاتورة الإلكترونية :-

Option Compare Database
Private Declare PtrSafe Function URLDownloadToFile Lib "urlmon" Alias "URLDownloadToFileA" _
    (ByVal pCaller As Long, ByVal szURL As String, ByVal szFileName As String, _
     ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long

Private Sub Command18_Click()
    On Error GoTo ErrorHandler
    Dim apiUrl As String
    Dim qrData As String
    Dim savePath As String
    Dim result As Long
    Dim sellerName As String
    Dim vatNumber As String
    Dim invoiceDate As String
    Dim totalAmount As String
    Dim vatAmount As String
    
    sellerName = Me.AD_Company_Vendor_Name
    vatNumber = Me.AD_Tax_Number
    invoiceDate = Me.AD_Invoice_Time_and_Date
    totalAmount = Me.AD_InvoiceAmountwithaddedvalue
    vatAmount = Me.AD_VAT
    
    Dim tlvData As String
    tlvData = Chr(1) & EncodeTLV(sellerName) & _
              Chr(2) & EncodeTLV(vatNumber) & _
              Chr(3) & EncodeTLV(invoiceDate) & _
              Chr(4) & EncodeTLV(totalAmount) & _
              Chr(5) & EncodeTLV(vatAmount)
    
    qrData = EncodeBase64(tlvData)
    apiUrl = "https://api.qrserver.com/v1/create-qr-code/?data=" & qrData & "&size=200x200"
    savePath = Application.CurrentProject.Path & "\qr_code.bmp"
    result = URLDownloadToFile(0, apiUrl, savePath, 0, 0)
    If result = 0 Then
        Me.imgQRCode.Picture = savePath
    Else
        MsgBox "Failed to download QR code image.", vbExclamation
    End If
    Exit Sub
ErrorHandler:
    MsgBox "An error occurred: " & Err.Description, vbCritical
End Sub

Private Function EncodeTLV(value As String) As String
    EncodeTLV = Chr(Len(value)) & value
End Function

Private Function EncodeBase64(value As String) As String
    Dim bytes() As Byte
    Dim xmlDoc As Object
    Dim xmlNode As Object
    Dim base64Data As String
    
    Set xmlDoc = CreateObject("MSXML2.DOMDocument")
    Set xmlNode = xmlDoc.createElement("Base64Data")
    xmlNode.DataType = "bin.base64"
    
    bytes = StrConv(value, vbFromUnicode)
    xmlNode.nodeTypedValue = bytes
    base64Data = xmlNode.Text
    
    Set xmlNode = Nothing
    Set xmlDoc = Nothing
    
    EncodeBase64 = base64Data
End Function

 

وهذا الملف بعد التعديل 

Qrcode.accdb

تم تعديل مايو 25 بواسطه Foksh

[أمير ادم]

اخي الكريم الله يعطيك الف مليون عافيه هذا هوا المطلوب بالفعل 

جزاك الله خير الجزاء على ماتقدمونه من مساعده وادخلت الفرحه في قلبي بارك الله فيك

 

[Foksh]

19 دقائق مضت, أمير ادم said:

ادخلت الفرحه في قلبي

جزاك الله خير ، وأعاننا على هذه ما حيينا