هل يمكن عمل هذه الجملة الشرطية ؟

[abofayez1]

لدي زر أمر  أريده يقوم بما يلي :

عند النقر

إذا كان متصفح كروم  مغلق تظهر رسالة  : يجب فتح المتصفح .

وإذا كان المتصفح مفتوح يقوم بتنفيذ الأمر

هل يمكن عمل مثل هذه الجملة الشرطية لكشف حالة برنامج خارج القاعدة . وكيف؟

[Foksh]

فكرة !!

في مديول ( وحدة نمطية ) ضع الكود التالي:-

Function IsChromeOpen() As Boolean
    Dim objShell As Object
    Dim objChrome As Object
    
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objChrome = objShell.Windows("chrome.exe")
    
    If Not objChrome Is Nothing Then
        IsChromeOpen = True
    Else
        IsChromeOpen = False
    End If
    
    Set objChrome = Nothing
    Set objShell = Nothing
End Function

ثم في النموذج يمكنك وضع هذه الوظيفة للتأكد من حالة المتصفح :-

Private Sub CheckChromeStatusBtn_Click()
    If IsChromeOpen() Then
        MsgBox "المتصفح Chrome مفتوح."
    Else
        MsgBox "يجب فتح المتصفح Chrome."
    End If
End Sub

وتستطيع توليفه كما تشاء حسب حاجتك 😊

 

جربه واخبرني بالنتيجة 🤗

[abofayez1]

ظهرت لي الرسالة : يجب فتح المتصفح

تظهر سواء كانالمتصفح مغلق أو مفتوح

333.accdb

[سامي الحداد]

مشاركة مع الاخ @Foksh

Option Compare Database
Option Explicit

Private Sub Command0_Click()
    ExecuteIfChromeOpen
End Sub

Function IsChromeRunning() As Boolean
    Dim strCommand As String
    Dim strOutput As String
    Dim objWShell As Object
    Set objWShell = CreateObject("WScript.Shell")
    
    strCommand = "tasklist /FI ""IMAGENAME eq chrome.exe"""
    
    strOutput = objWShell.Exec(strCommand).StdOut.ReadAll
    
    If InStr(strOutput, "chrome.exe") > 0 Then
        IsChromeRunning = True
    Else
        IsChromeRunning = False
    End If
    
    Set objWShell = Nothing
End Function


Sub ExecuteIfChromeOpen()
    If IsChromeRunning() Then
        MsgBox " المتصفح كروم قيد التشغيل. سيتم تنفيذ الأمر", vbInformation, "تأكيد"
        DoCmd.OpenForm "البيانات"
    Else
        MsgBox "يجب فتح المتصفح .", vbExclamation, "المتصفح مغلق"
    End If
End Sub

واليك المرفق 

بالتوفيق

Database313.accdb

[abofayez1]

الله يبيض وجهك أخوي سامي الحداد ... ورحمك الله ووالديك

ألف شكر لك يا عزيزي والشكر موصول للعزيز الغالي Foksh

ايعمل بامتياز👍

[سامي الحداد]

اللهم آمين وإياك إن شاء الله، الله يجعلك من اهل الجنة ويرحم والديك في الدنيا والاخرة

الشكر لله عز وجل ربي يسعدك.