إضافة دالة filter لأوفيس ٢٠١٦

[mohsen mohamed]

الأساتذة الكرام 

كل عام وحضراتكم بخير. 

هل يمكن إضافة دالة  filter لأوفيس ٢٠١٦ و٢٠١٩ وكيف وإن لم يفلح فما بديلها. 

وجزاكم الله خيرا 

[mohsen mohamed]

السادة الأساتذة الكرام 

أريد معرفة كيفية إضافة دالة filter لأوفيس 2016 

وإن لم يمكن الإضافة فما هي الدالة التي تقوم بعملها في أوفيس 2016

ولسيادتكم جزيل الشكر

[أ / محمد صالح]

يمكنك تجربة هذه الدالة المعرفة

Function FILTER_AK(Where, Criteria, Optional If_Empty) As Variant
  Dim Data, Result
  Dim i As Long, j As Long, k As Long
  'Create space for the output (same size as input cells)
  With Application.Caller
    i = .Rows.Count
    j = .Columns.Count
  End With
  'Clear
  ReDim Result(1 To i, 1 To j)
  For i = 1 To UBound(Result)
    For j = 1 To UBound(Result, 2)
      Result(i, j) = ""
    Next
  Next
  'Count the rows to show
  For i = 1 To UBound(Criteria)
    If Criteria(i, 1) Then j = j + 1
  Next
  'Empty?
  If j < 1 Then
    If IsMissing(If_Empty) Then
      Result(1, 1) = CVErr(xlErrNull)
    Else
      Result(1, 1) = If_Empty
    End If
    GoTo ExitPoint
  End If
  'Get all data
  Data = Where.Value
  'Copy the rows to show
  For i = 1 To UBound(Data)
    If Criteria(i, 1) Then
      k = k + 1
      For j = 1 To UBound(Data, 2)
        Result(k, j) = Data(i, j)
      Next
    End If
  Next
  'Return the result
ExitPoint:
  FILTER_AK = Result
End Function

استخدامها مثل الدالة filter في اوفيس 365 مع فارق الضغط على Ctrl+shift+enter

بالتوفيق 

[mohsen mohamed]

شكرا جزيلا أخي الأستاذ /محمد صالح