البحث بقائمة الكومبوبوكس اكسيل vba

[mohamedamrawy]

السلام عليك ورحمه الله وبركاته 

بعد اذن الاساتذة الافاضل اريد كود بحث بقائمة الكومبوبوكس باي حرف من الكلمة لعمودين اكسيلtest1.xlsm

[lionheart]

Try this code

Private f As Boolean

Private Sub ComboBox1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    PopulateComboBox Me.ComboBox1
End Sub

Private Sub UserForm_Initialize()
    f = False
    Me.ComboBox1.MatchEntry = fmMatchEntryNone
    PopulateComboBox Me.ComboBox1
End Sub

Sub PopulateComboBox(ByVal cmb As MSForms.ComboBox)
    Dim arrIn, arrOut(), i As Long, j As Long
    With Sheets(1)
        arrIn = .Range("B2:B" & .Cells(Rows.Count, "B").End(xlUp).Row).Value
    End With
    ReDim arrOut(1 To UBound(arrIn))
    For i = 1 To UBound(arrIn)
        If arrIn(i, 1) Like "*" & cmb.Text & "*" Then
            j = j + 1
            arrOut(j) = arrIn(i, 1)
        End If
    Next i
    If j = 0 Then cmb.Clear: Exit Sub
    ReDim Preserve arrOut(1 To j)
    With cmb
        .Clear
        .List = arrOut
        If j > 0 And f Then .DropDown Else f = True
    End With
End Sub

 

[elmansyeswa]

h

جعله الله فى ميزان حسناتك

[mohamedamrawy]

مشكورا اخي الكريم