التنقل بين الحقول والسجلات في النموذج المستمر ، بالاسهم (معدل)

[moho58]

البرنامج المرفق يحتوي على نموذح واحد من نماذج كثيرة كان الانتقال بين حقول النموذج باستخدام الانتر او التاب

ولكن

اشتكى مستخدمو البرنامج في المدارس من هذه الحركة وخصوصا اذا قاموا بادخال علامة اللغة العربية مثلا لكل طلاب الفصل

لذا عليه الانتقال الى الطالب اللي تحت هذا الطالب الذي ادخل علامته وهكذا لجميع الطلاب

الامر كان بالدرجة الاولى باستخدام الماوس لتفادي هذه السنه ولكنها عملية غير فعالة

لذا كان واجب على ان اضيف هذه الميزة وهي التنقل بجميع الاتجاهات باستخدام الاسهم

ولكني للاسف بعد محاولات عديدة فشلت

فقررت ان اشارككم لتفيدوني

ورجاء لمن يساعدني ان يدلني على الطريقة والكود بالتفصيا لاني ساستخدمها في نماذج عديدة

وبارك الله فيكم

 

UseArrow.rar

تم تعديل نوفمبر 27, 2022 بواسطه moh1701

[Moosak]

طبق هذه الإعدادات هذه أخي :  

وأخبرنا بالنتيجة 🙂 

[moho58]

السلام عليكم

شكرا على الرد اخي 

لكن اريد ان أطبق هذا العمل على نمودج واحد فقط

لاني لو طبقت شرحك سينطبق على جميع قاعدة البيانات وأنا اريد ان اطبقها على نمودج واحد فقط 

وبارك الله فيك اخي 

الرجاء المساعدة وشكرا 

 

 

 

 

 

 

[متقاعد]

22 دقائق مضت, moh1701 said:

وأنا اريد ان اطبقها على نمودج واحد فقط 

في خصائص النموذج في حدث عند مفتاح اسفل ضع الامر

On Error Resume Next
Select Case KeyCode
Case Is = vbKeyDown
DoCmd.GoToRecord , , acNext
Case Is = vbKeyUp
DoCmd.GoToRecord , , acPrevious
End Select

ثم ايضا في خصائص النموذج مفتاح معاينة غير الى نعم

اعتذر لعدم التجربة لعدم توفر اكسس حاليا ولكن من المتوقع ان يؤدي الغرض

اخيرا العنوان مخالف لقواعد المشاركة بالموقع حيث يتطلب

• ان يدل العنوان بشكل واضح عن محتوى المشاركة
• عدم استخدام عناوين مثل عاجل او ... الخ

تحياتي

تم تعديل نوفمبر 27, 2022 بواسطه مبرمج متقاعد

[jjafferr]

السلام عليكم 🙂

 

انا استخدم هذه الوحدة النمطية:

Option Compare Database
Option Explicit

'---------------------------------------------------------------------------------------
' Procedure : EnableArrowsScroll
' Author    : Daniel Pineault, CARDA Consultants Inc.
' Website   : http://www.cardaconsultants.com
' Purpose   : Enable using the up and down arrows to move between records on a
'             continuous form
' Req'd Refs: None
' The Form's Key Preview property must be set to True for this code to work.
'
' Input Variables:
' ~~~~~~~~~~~~~~~~
' iKeyCode  : Keycode from the source form from the KeyDown event
' frm       : form object to apply the new behavior to
'
' Usage:
' ~~~~~~
' KeyCode = EnableArrowsScroll(KeyCode, Me) 'This is placed in the KeyDown event
'                            'Dont forget to set the Key Preview property to Yes
'
' Revision History:
' Rev       Date(yyyy/mm/dd)        Description
' **************************************************************************************
' 1         2011-07-07              Initial Release
' 2         2017-04-08              Added DefaultView check
'---------------------------------------------------------------------------------------
Public Function EnableArrowsScroll(ByVal iKeyCode As Integer, frm As Access.Form) As Integer
    On Error GoTo Error_Handler

    If frm.DefaultView = 1 Then    'Only process for Continuous forms
        Select Case iKeyCode
            Case vbKeyDown
                '            If CurrentRecord <> RecordsetClone.RecordCount Then 'Restrict to existing records
                If frm.NewRecord = False Then    'Allow going to new record for data entry
                    DoCmd.GoToRecord , , acNext
                End If
                EnableArrowsScroll = 0
            Case vbKeyUp
                If frm.CurrentRecord <> 1 Then
                    DoCmd.GoToRecord , , acPrevious
                End If
                EnableArrowsScroll = 0
            Case Else
                EnableArrowsScroll = iKeyCode
        End Select
    Else
        EnableArrowsScroll = iKeyCode
    End If

Error_Handler_Exit:
    On Error Resume Next
    If Not frm Is Nothing Then Set frm = Nothing
    Exit Function

Error_Handler:
    If Err.Number <> 2105 Then
        MsgBox "The following error has occurred" & vbCrLf & vbCrLf & _
               "Error Number: " & Err.Number & vbCrLf & _
               "Error Source: EnableArrowsScroll" & vbCrLf & _
               "Error Description: " & Err.Description & _
               Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
               , vbOKOnly + vbCritical, "An Error has Occurred!"
    End If
    Resume Error_Handler_Exit
End Function

.

وتناديها على حدث "الزر الاسفل" للنموذج ، هكذا

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
    On Error GoTo Error_Handler

    KeyCode = EnableArrowsScroll(KeyCode, Me)

Error_Handler_Exit:
    On Error Resume Next
    Exit Sub

Error_Handler:
    MsgBox "The following error has occurred" & vbCrLf & vbCrLf & _
           "Error Number: " & Err.Number & vbCrLf & _
           "Error Source: Form_KeyDown" & vbCrLf & _
           "Error Description: " & Err.Description & _
           Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
           , vbOKOnly + vbCritical, "An Error has Occurred!"
    Resume Error_Handler_Exit
End Sub

.

جعفر

1532.UseArrow.mdb.zip

[moho58]

السلام عليكم

أشكر كل من الأخ jjafferr

والأخ مبرمج متقاعد على الاجابة بهذه السرعة والتفاعل

فعلا الطريقتين فعاليتين

والمشكل فقط في أسهم اليمين واليسار متعكاسين

السهم اليسار عند الضغط عليه يدهب يمين و السهم اليمين يدهب يسار (ان امكن المساعدة )

 

المهم شكرا لكما كثيرا وبارك الله فيكم

تحياتي

 

 

 

[moho58]

شكرا لكم على كل حال

جربت الكود احيانا  لكل من الاخوين jjafferr  و  مبرمج متقاعد    أحيانا تشتغل عادي واحيانا  تتوقف الرحاء مساعدتي وشكرا - الملف مرفق

في  انتظار ردكم

 

GSTION.accdb

تم تعديل نوفمبر 27, 2022 بواسطه moh1701

[ابو جودي]

اتفضل ملفك بعد التعديل

GSTION.accdb