حساب عدد الايام بين تاريخين

[Ahmed Hassan 2000]

السلام عليكم ورحمه الله وبركاته

اريد المساعدة في ملف اكسيس 

اريد حساب عدد الايام بين تاريخين في اكسيس مع خصم ايام الاجازات ( الجمعة والسبت مع خصم أيضاً ايام المناسبات الرسميه )

وشكراً مقدماً ♥️

 

 

 

[Moosak]

وعليكم السلام ورحمة الله وبركاته .. 🙂 

 

 

[Eng.Qassim]

وعليكم السلام

هذه الدالة من موقع مايكروسوفت ..اذا كان تنسيق اللغة عندك بالعربي ..اما اذا بالانكليزي فقم بتغيير اسماء السبت والجمعة

بالنسبة للعطل الرسمية اجعلها في جدول منفصل ثم استدعي مجموعها لتطرحه من عدد الايام التي تظهر لديك

Function Work_Days(BegDate As Variant, EndDate As Variant) As Integer
 
 Dim WholeWeeks As Variant
 Dim DateCnt As Variant
 Dim EndDays As Integer
 
 On Error GoTo Err_Work_Days
 
 BegDate = DateValue(BegDate)
 EndDate = DateValue(EndDate)
 WholeWeeks = DateDiff("w", BegDate, EndDate)
 DateCnt = DateAdd("ww", WholeWeeks, BegDate)
 EndDays = 0
 
 Do While DateCnt <= EndDate
 If Format(DateCnt, "ddd") <> "السبت" And _
 Format(DateCnt, "ddd") <> "الجمعة" Then
 EndDays = EndDays + 1
 End If
 DateCnt = DateAdd("d", 1, DateCnt)
 Loop
 
 Work_Days = WholeWeeks * 5 + EndDays
 
Exit Function
 
Err_Work_Days:
 
 ' If either BegDate or EndDate is Null, return a zero
 ' to indicate that no workdays passed between the two dates.
 
 If Err.Number = 94 Then
 Work_Days = 0
 Exit Function
 Else
' If some other error occurs, provide a message.
 MsgBox "Error " & Err.Number & ": " & Err.Description
 End If
 
End Function

 

[ابو جودي]

7 ساعات مضت, AHMED0155079 said:

السلام عليكم ورحمه الله وبركاته

اريد المساعدة في ملف اكسيس 

اريد حساب عدد الايام بين تاريخين في اكسيس مع خصم ايام الاجازات ( الجمعة والسبت مع خصم أيضاً ايام المناسبات الرسميه )

وشكراً مقدماً ♥️

 

 

 

اولا انشئ جدول باسم tblHolidays

يتكون هذا الجدول من حقلين 

الحقل الاول باسم    HolidayType   نوع الحقل نصى ليحتوى على اسم او وصف الأعياد والأجازات الرسمية لهذا العام
الحقل الثانى باسم  HolidayDate   نوع الحقل تاريخ  ليحتوى على تاريخ الأعياد والأجازات الرسمية لهذا العام

بعد ذلك انشئ وحدة نمطية وضع بها الروتين الاتى 

Function ActualDays(ByVal dtStartDay As Date, ByVal dtEndDay As Date, Optional nDay As Integer = 0) As Long

Dim dtNominalEndDay   As Date
Dim lngTotalDays      As Long
Dim lngTotalWeeks     As Long
Dim lngTotalHolidays  As Long
Dim lngstart          As Long
Dim lngend            As Long



'Check to see if dtStartDay > dtEndDay.  If so, then switch the dates

If dtStartDay > dtEndDay Then ActualDays = 0: Exit Function

'  If dtStartDay >= dtEndDay Then
'    dtNominalEndDay = dtStartDay
'    dtStartDay = dtEndDay
'    dtEndDay = dtNominalEndDay
'  End If

'Here are how many weeks are between the two dates
lngTotalWeeks = DateDiff("w", dtStartDay, dtEndDay)
'Here are the number of weekdays in that total week
lngTotalDays = lngTotalWeeks * 5
'Here is the date that is at the end of that many weeks
dtNominalEndDay = DateAdd("d", (lngTotalWeeks * 7), dtStartDay)
'Now add the number of weekdays between the nominal end day and the actual end day
  While dtNominalEndDay <= dtEndDay
    If Weekday(dtNominalEndDay, 2) <> 5 Then
      If Weekday(dtNominalEndDay, 2) <> 6 Then
        lngTotalDays = lngTotalDays + 1
      End If
    End If
  dtNominalEndDay = dtNominalEndDay + 1
  Wend
'convert end date and startdate into long integer format for the DCount operation to avoid misreading of dates as US format
  lngstart = dtStartDay
  lngend = dtEndDay

'Here are how many holiday days there are between the two days
  lngTotalHolidays = DCount("HolidayDate", "tblHolidays", "HolidayDate <= " & lngend & " AND HolidayDate >= " & lngstart & " AND Weekday(HolidayDate,2) <> 6 AND Weekday(HolidayDate,2) <> 5")
  ActualDays = lngTotalDays - lngTotalHolidays

'Here are how many holidays between the two dates plus the number of weekends
  'If nDay = 1 Then ActualDays = DateDiff("d", dtStartDay, dtEndDay) - ActualDays + 1

  If nDay = 1 Then ActualDays = DateDiff("d", dtStartDay, dtEndDay) + 1
  If nDay = 2 Then ActualDays = DateDiff("d", dtStartDay, dtEndDay) - ActualDays + 1
  If nDay = 3 Then ActualDays = lngTotalHolidays
  If nDay = 4 Then ActualDays = (DateDiff("d", dtStartDay, dtEndDay) - ActualDays + 1) - lngTotalHolidays
  
End Function

ولاستدعاء الروتين السابق لاحتساب الايام الفعلية بين تاريخين بدون العطل الرسيمة داخل الجدول المحدد لذلك وبدون ايام الجمعة والسبت 

ActualDays([BeginDate],[EndDate])

وان اردت استخلاص عدد العطلات الرسمية بين تاريخين والتى تم تحديدها مسبقا بجدول tblHolidays + العطلات الاسبوعية ( الجمعة + السبت )

قم ياستدعاء الروتين بالشكل الاتى 

ActualDays([BeginDate],[EndDate],1)

 

 

وهذا التعديل الاخير لى على الأكود فى المرفق الذى اشار اليه الباش مهندس @Moosak 

تم تعديل المرفق

 

 

ActualDaysCalcult.accdb

تم تعديل يونيو 26, 2022 بواسطه ابو جودي
تعديل المرفق

[ابو جودي]

4 ساعات مضت, Eng.Qassim said:

وعليكم السلام

هذه الدالة من موقع مايكروسوفت ..اذا كان تنسيق اللغة عندك بالعربي ..اما اذا بالانكليزي فقم بتغيير اسماء السبت والجمعة

بالنسبة للعطل الرسمية اجعلها في جدول منفصل ثم استدعي مجموعها لتطرحه من عدد الايام التي تظهر لديك

اولا جزاكم الله خيرا لبحثكم وتقديم المساعدة

ولكن اسمح لى بعد اذن حضرتك

1- يعيب الدالة من موقع مايكرسوفت استخدام اسم اليوم سواء بالعربية او الانجليزية بسبب اختلاف الاجهزة على الرغم من امكانية تحاشى تلك المشكلة
ولكن هذا شق الاجابه على السؤال وهو الفرق بالايام بين تاريخين مع عدم احتساب ايام الجمعة والسبت

2- وماذا عن الشق الاخر ؟ 

7 ساعات مضت, AHMED0155079 said:

مع خصم أيضاً ايام المناسبات الرسميه

 

[Eng.Qassim]

54 دقائق مضت, ابو جودي said:

هذا شق الاجابه على السؤال وهو الفرق بالايام بين تاريخين مع عدم احتساب ايام الجمعة والسبت

حمد الله على السلامة استاذ محمد ..مشتاقون جدا لمشاركاتك الجميلة

بالنسبة للدالة التي ذكرتها من مايكروسوفت تحسب الفرق بين تاريخين دون الجمعة والسبت ..وبالحقيقة استخدمها في عملي لحساب مدد المشاريع (ايام عمل )

بالنسبة للعطل فاعمل جدول خاص ثم احسب عدد العطل لاطرحها من القيمة الاولى ..صحيح انه فيه نقطة ضعف ان ايام العيد ربما تصادف الجمعة والسبت لكني متجاوز هذه النقطة

منذ ساعه, ابو جودي said:

وماذا عن الشق الاخر ؟

هذا الشق المفروض انك جاوبت عليه حتى يكون البرنامج احترافي وممكن اي شخص يعمل عليه

لكن تظهر لي مشكلة ..انه من تاريخ 01/06/2022 لغاية 12/06/2022 تظهر لي 8 ايام مع العلم اني استخدمت الاستدعاء الاول

[ابو جودي]

37 دقائق مضت, Eng.Qassim said:

حمد الله على السلامة استاذ محمد ..مشتاقون جدا لمشاركاتك الجميلة

الله يسلمك ويحفظك يا باش مهندس قاسم

 

37 دقائق مضت, Eng.Qassim said:

لكن تظهر لي مشكلة ..انه من تاريخ 01/06/2022 لغاية 12/06/2022 تظهر لي 8 ايام مع العلم اني استخدمت الاستدعاء الاول

وما هى المشكلة

01/06/2022   >>--->   يوافق يوم الاربعاء           >>--->   1
02/06/2022   >>--->   يوافق يوم الخميس        >>--->   2
03/06/2022   >>--->   يوافق يوم الجمعة          >>--->   0
04/06/2022   >>--->   يوافق يوم السبت          >>--->   0
05/06/2022   >>--->   يوافق يوم الاحد             >>--->   3
06/06/2022   >>--->   يوافق يوم الاثنين           >>--->   4
07/06/2022   >>--->   يوافق يوم الثلاثاء           >>--->   5
08/06/2022   >>--->   يوافق يوم الاربعاء           >>--->   6
09/06/2022   >>--->   يوافق يوم الخميس        >>--->   7
11/06/2022   >>--->   يوافق يوم الجمعة          >>--->   0
11/06/2022   >>--->   يوافق يوم السبت          >>--->   0 
12/06/2022   >>--->   يوافق يوم الاحد             >>--->   8

[ابو جودي]

شوف يا باش مهندس @Eng.Qassim 

قمت فى هذا المرفق ببعض التعديلات الطفيفة والتى تظهر امامك كل شئ تفصيليا 

حمل المرفق وقم بفتح الاستعلام qryActualDays

ActualDaysCalcult Eng.Qassim.accdb

[Eng.Qassim]

3 ساعات مضت, ابو جودي said:

ولاستدعاء الروتين السابق لاحتساب الايام الفعلية بين تاريخين بدون العطل الرسيمة داخل الجدول المحدد لذلك وبدون ايام الجمعة والسبت 

ActualDays([BeginDate],[EndDate])

خدعتني هذه الجملة .. ولم اكلف نفسي بتتبع الكود 🤣