إضافة زر التكبير والتصغير في الفورم .

[mra63]

ارجوا من اصحاب الخبرة كيفية اضافة زر التكبير والتصغير في الفورم بجانب زر الإغلاق . بارك الله فيكم .

[حسونة حسين]

السلام عليكم ورحمه الله وبركاته وبها نبدأ

 

Option Explicit
'http://www.mrexcel.com/archive/VBA/24009.html
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function DrawMenuBar Lib "user32" (ByVal hWnd As Long) As Long
Private Declare Function ShowWindow Lib "user32" (ByVal hWnd As Long, ByVal nCmdShow As Long) As Long

Private Const GWL_STYLE As Long = (-16) 'Sets a new window style
Private Const WS_SYSMENU As Long = &H80000 'Windows style
Private Const WS_MINIMIZEBOX As Long = &H20000
Private Const WS_MAXIMIZEBOX As Long = &H10000
Private Const SW_SHOWMAXIMIZED = 3

Private Sub UserForm_Activate()
Dim lFormHandle As Long, lStyle As Long
'===========================================
'= Originally from Dax =
'= Modified with comments by Ivan F Moala =
'= 22/07/01 =
'===========================================

'Lets find the UserForm Handle the function below retrieves the handle
'to the top-level window whose class name ("ThunderDFrame" for Excel)
'and window name (me.caption or UserformName caption) match the specified strings.
lFormHandle = FindWindow("ThunderDFrame", Me.Caption)

'The GetWindowLong function retrieves information about the specified window.
'The function also retrieves the 32-bit (long) value at the specified offset
'into the extra window memory of a window.
lStyle = GetWindowLong(lFormHandle, GWL_STYLE)

'lStyle is the New window style so lets set it up with the following
lStyle = lStyle Or WS_SYSMENU 'SystemMenu
lStyle = lStyle Or WS_MINIMIZEBOX 'With MinimizeBox
lStyle = lStyle Or WS_MAXIMIZEBOX 'and MaximizeBox

'Now lets set up our New window the SetWindowLong function changes
'the attributes of the specified window , given as lFormHandle,
'GWL_STYLE = New windows style, and our Newly defined style = lStyle
SetWindowLong lFormHandle, GWL_STYLE, (lStyle)

'Remove >'< if you want to show form Maximised
'ShowWindow lFormHandle, SW_SHOWMAXIMIZED 'Shows Form Maximized

'The DrawMenuBar function redraws the menu bar of the specified window.
'We need this as we have changed the menu bar after Windows has created it.
'All we need is the Handle.
DrawMenuBar lFormHandle

End Sub

 

[mra63]

شكراً علي الاهتمام والرد 

ولكن يعطي هذا الخطأ  /

Sub or Function not defined

ويحدد هذا المتغير /

FindWindow

[حسونة حسين]

هذا الكود يوضع في ال userform

[mra63]

شكراً جزيلاً . نجح الأمر انا آسف جداً الخطأ مني انا وضعت الكود الأول في مديول جديد والثاني وضعته في الفورم في وضع الاكتيف بارك الله فيك .

[Mohamed Sayed79]

السلام عليكم 

اجد نفس الخطأ

ممكن تشرح لي طريقة ازالة هذا الخطأ 

شكرا جزيلا لحضرتك وللاخ حسن

[حسونة حسين]

وعليكم السلام ورحمة الله وبركاته

هذا الكود كله يوضع في ال userform