اذهب الي المحتوي
أوفيسنا
بحث مخصص من جوجل فى أوفيسنا
Custom Search

تحديد عناصر قائمة منسدلة وربطها بقائمة أخري

محمود أبوسيف

بواسطه محمود أبوسيف
في قسم الأكسيس Access

 مشاركة
إذهب إلى الإجابة الإجابة بواسطة jjafferr,

الردود الموصى بها

محمود أبوسيف

محمود أبوسيف

قام بنشر
قام بنشر (معدل)

المطلوب 

عندي combo box اسمه (Head_1) أريد عناصره تكون رأس الحقل (اسم الحقل) الموجودة بجدول Stu_select 

ثم ربط هذا combo box  (Head_1) بـــ combo box  (text_1) 

فأريد عند اختيار اسم الحقل من (Head_1) في الأعلي يظهر لي البيانات الخاصة بهذا الحقل فقط في (text_1)

وتكون متوافقة مع بيانات التلميذ

 

تحديد عناصر قائمة منسدلة وربطها بأخري.rar

تم تعديل بواسطه محمود أبوسيف
ابو جودي

ابو جودي

قام بنشر
قام بنشر (معدل)

علشان مش فاهم والله

منذ ساعه, محمود أبوسيف said:

عندي combo box اسمه (Head_1) أريد عناصره تكون رأس الحقل (اسم الحقل) الموجودة بجدول Stu_select

انت عاوز هنا يجيب كل اسماء الحقول كده تقصد

00.png.0ba5e9ee91ca775c917bc39906d2276b.png

تم تعديل بواسطه ابو جودي
ابو جودي

ابو جودي

قام بنشر
قام بنشر

ياباشا اصلا انت كاتب اسامى الحقول بالانجليزى

بص هو ممكن تشرح ببساطه انت عاوز توصل لايه

بلاش تحط فكرتك انت وتجبرنا نوصلك لـ نتيجة بناء على فكرتك انت  لان شكلك انت بتفكر غلط وكده هتجيب لنا جنان اكثر من اللى احنا فيه :biggrin:

  • Like 1
  • Haha 1
محمود أبوسيف

محمود أبوسيف

قام بنشر
  • الكاتب
قام بنشر
منذ ساعه, ناقل said:

هل هذا ما تريدة ؟؟؟؟؟

 

1.png

ناقل_22.mdb 992 kB · 1 download

تمام كده ياغالي .. دي كده أول خطوة

2 ساعات مضت, ابو جودي said:

ياباشا اصلا انت كاتب اسامى الحقول بالانجليزى

بص هو ممكن تشرح ببساطه انت عاوز توصل لايه

بلاش تحط فكرتك انت وتجبرنا نوصلك لـ نتيجة بناء على فكرتك انت  لان شكلك انت بتفكر غلط وكده هتجيب لنا جنان اكثر من اللى احنا فيه 

محمود أبوسيف

محمود أبوسيف

قام بنشر
  • الكاتب
قام بنشر
1 ساعه مضت, ناقل said:

هل هذا ما تريدة ؟؟؟؟؟

 

1.png

ناقل_22.mdb 992 kB · 3 downloads

اخي الفاضل النموذج اصبح متجمد ولا يمكن التحكم في أي شئ كالطباعة أو الضغط علي أي زر 

واقتصر الأمر علي الاختيار من القائمة المنسدلة

أرجو حل المشكلة 

7 ساعات مضت, ابو جودي said:

علشان مش فاهم والله

انت عاوز هنا يجيب كل اسماء الحقول كده تقصد

00.png.0ba5e9ee91ca775c917bc39906d2276b.png

أخي الكريم يمكنك الاستكمال علي ذلك وتقبل اعتذاري علي عدم التوضيح الوافي 

المطلوب فعلا هو هكذا يمكنك الاستمرار 

ناقل

ناقل

قام بنشر
قام بنشر
14 ساعات مضت, محمود أبوسيف said:

اخي الفاضل النموذج اصبح متجمد ولا يمكن التحكم في أي شئ كالطباعة أو الضغط علي أي زر 

واقتصر الأمر علي الاختيار من القائمة المنسدلة

أرجو حل المشكلة 

طيب اخي الكريم هل الحقول الثابتة فقط

الرقم والاسم ام هناك حقوا اخرى ثابتة

محمود أبوسيف

محمود أبوسيف

قام بنشر
  • الكاتب
قام بنشر (معدل)
23 دقائق مضت, ناقل said:

طيب اخي الكريم هل الحقول الثابتة فقط

الرقم والاسم ام هناك حقوا اخرى ثابتة

الحقول الثابتة هي الاسم والرقم فقط 

تم تعديل بواسطه محمود أبوسيف
jjafferr

jjafferr

قام بنشر
قام بنشر

السلام عليكم 🙂

 

هذه الوحدة النمطية تقوم بإدخال القيم مربع التحرير والسرد Head_1 ،

الدالة List_Table_Fields تأخذ مسمى الحقل الذي في الجدول ، واذا لم يكن هناك مسمى ، فتقوم بوضع اسم الحقل ،

ويتم إضافة عمودين لمربع التحرير والسرد Head_1 ، الاول اسم الحقل (وعرضه صفر حتى لا يظهر في القائمة) ، والآخر مسمى الحقل (والذي يظهر في القائمة) : 

Public Function List_Table_Fields(cmb As ComboBox) As String
On Error GoTo err_List_Table_Fields
    
    Dim tbdf As TableDef
    Dim fld As DAO.Field
    Dim iField_Caption As String
    Dim Field_Type As String

    For Each tbdf In CurrentDb.TableDefs

        If tbdf.Name = "Stu_select" Then
            For Each fld In tbdf.Fields
            
                iField_Caption = fld.Properties("Caption")
                Field_Type = DataType_Fields(fld.Type)

                'fListseparator is from Regional setting, list separator
                'add the items for the ComboBox Row Source
                cmb.AddItem fld.Name & fListseparator & iField_Caption
                
                'Debug.Print tbdf.Name & vbTab & fld.Name & vbTab & Field_Type & vbTab & iField_Caption
            Next fld
        End If
        
    Next tbdf


Exit_List_Table_Fields:

    Set tbdf = Nothing: Set fld = Nothing

    Exit Function
err_List_Table_Fields:

    If Err.Number = 3270 Then
        'this field does not have a caption for it, give it the field name
        iField_Caption = fld.Name
        Resume Next
    Else
        MsgBox Err.Number & vbCrLf & Err.Description
    End If
    
End Function

Public Function DataType_Fields(DF)

    Select Case DF
        'Case 4
        '    DataType_Fields = "AutoNumber"
        Case 10
            DataType_Fields = "Text"
        Case 12
            DataType_Fields = "Memo"
        Case 4
            DataType_Fields = "LongInt"
        Case 2
            DataType_Fields = "Byte"
        Case 3
            DataType_Fields = "Integer"
        Case 6
            DataType_Fields = "Single"
        Case 7
            DataType_Fields = "Double"
        Case 15
            DataType_Fields = "Replication"
        Case 8
            DataType_Fields = "DateTime"
        Case 5
            DataType_Fields = "Currency"
        Case 1
            DataType_Fields = "YesNo"
        Case 11
            DataType_Fields = "OLEObject"
        Case 12
            DataType_Fields = "Hyperlink"
        Case 101
            DataType_Fields = "Attachment"
    End Select

End Function

.

ولا عليك من الدالة DataType_Fields ، فوضعتها هنا حتى يكون موضوع حقول الجدول متكامل 🙂

اما الوحدة النمطية fRegional_Settings_info ، فمنها اخذت الفارزة بين قيم مصدر بيانات السطر Head_1 ، ويتم اخذ القيمة من اعدادات الوندوز ، فالنظام الامريكي يستخدم الفاصلة ([كود التلميذ], [الصف], [النوع]) ،

بينما النظام العربي يستخدم الفاصلة المنقوطة ([كود التلميذ]; [الصف]; [النوع]) 

اقتباس

cmb.AddItem fld.Name & fListseparator & iField_Caption

 

  

Option Compare Database
Option Explicit

' This code was originally written by Dev Ashish.
' It is not to be altered or distributed,
' except as part of an application.
' You are free to use it in any application,
' provided the copyright notice is left unchanged.
'
' Code Courtesy of
' Dev Ashish
'
Public Const LOCALE_ILANGUAGE = &H1         '  language id
Public Const LOCALE_SLANGUAGE = &H2         '  localized name of language
Public Const LOCALE_SENGLANGUAGE = &H1001   '  English name of language
Public Const LOCALE_SABBREVLANGNAME = &H3   '  abbreviated language name
Public Const LOCALE_SNATIVELANGNAME = &H4   '  native name of language
Public Const LOCALE_ICOUNTRY = &H5          '  country code
Public Const LOCALE_SCOUNTRY = &H6          '  localized name of country
Public Const LOCALE_SENGCOUNTRY = &H1002    '  English name of country
Public Const LOCALE_SABBREVCTRYNAME = &H7   '  abbreviated country name
Public Const LOCALE_SNATIVECTRYNAME = &H8   '  native name of country
Public Const LOCALE_IDEFAULTLANGUAGE = &H9  '  default language id
Public Const LOCALE_IDEFAULTCOUNTRY = &HA   '  default country code
Public Const LOCALE_IDEFAULTCODEPAGE = &HB  '  default code page
Public Const LOCALE_SLIST = &HC             '  list item separator
Public Const LOCALE_IMEASURE = &HD          '  0 = metric, 1 = US
Public Const LOCALE_SDECIMAL = &HE          '  decimal separator
Public Const LOCALE_STHOUSAND = &HF         '  thousand separator
Public Const LOCALE_SGROUPING = &H10        '  digit grouping
Public Const LOCALE_IDIGITS = &H11          '  number of fractional digits
Public Const LOCALE_ILZERO = &H12           '  leading zeros for decimal
Public Const LOCALE_SNATIVEDIGITS = &H13    '  native ascii 0-9
Public Const LOCALE_SCURRENCY = &H14        '  local monetary symbol
Public Const LOCALE_SINTLSYMBOL = &H15      '  intl monetary symbol
Public Const LOCALE_SMONDECIMALSEP = &H16   '  monetary decimal separator
Public Const LOCALE_SMONTHOUSANDSEP = &H17  '  monetary thousand separator
Public Const LOCALE_SMONGROUPING = &H18     '  monetary grouping
Public Const LOCALE_ICURRDIGITS = &H19      '  # local monetary digits
Public Const LOCALE_IINTLCURRDIGITS = &H1A  '  # intl monetary digits
Public Const LOCALE_ICURRENCY = &H1B        '  positive currency mode
Public Const LOCALE_INEGCURR = &H1C         '  negative currency mode
Public Const LOCALE_SDATE = &H1D            '  date separator
Public Const LOCALE_STIME = &H1E            '  time separator
Public Const LOCALE_SSHORTDATE = &H1F       '  short date format string
Public Const LOCALE_SLONGDATE = &H20        '  long date format string
Public Const LOCALE_STIMEFORMAT = &H1003    '  time format string
Public Const LOCALE_IDATE = &H21            '  short date format ordering
Public Const LOCALE_ILDATE = &H22           '  long date format ordering
Public Const LOCALE_ITIME = &H23            '  time format specifier
Public Const LOCALE_ICENTURY = &H24         '  century format specifier
Public Const LOCALE_ITLZERO = &H25          '  leading zeros in time field
Public Const LOCALE_IDAYLZERO = &H26        '  leading zeros in day field
Public Const LOCALE_IMONLZERO = &H27        '  leading zeros in month field
Public Const LOCALE_S1159 = &H28            '  AM designator
Public Const LOCALE_S2359 = &H29            '  PM designator
Public Const LOCALE_SDAYNAME1 = &H2A        '  long name for Monday
Public Const LOCALE_SDAYNAME2 = &H2B        '  long name for Tuesday
Public Const LOCALE_SDAYNAME3 = &H2C        '  long name for Wednesday
Public Const LOCALE_SDAYNAME4 = &H2D        '  long name for Thursday
Public Const LOCALE_SDAYNAME5 = &H2E        '  long name for Friday
Public Const LOCALE_SDAYNAME6 = &H2F        '  long name for Saturday
Public Const LOCALE_SDAYNAME7 = &H30        '  long name for Sunday
Public Const LOCALE_SABBREVDAYNAME1 = &H31  '  abbreviated name for Monday
Public Const LOCALE_SABBREVDAYNAME2 = &H32  '  abbreviated name for Tuesday
Public Const LOCALE_SABBREVDAYNAME3 = &H33  '  abbreviated name for Wednesday
Public Const LOCALE_SABBREVDAYNAME4 = &H34  '  abbreviated name for Thursday
Public Const LOCALE_SABBREVDAYNAME5 = &H35  '  abbreviated name for Friday
Public Const LOCALE_SABBREVDAYNAME6 = &H36  '  abbreviated name for Saturday
Public Const LOCALE_SABBREVDAYNAME7 = &H37  '  abbreviated name for Sunday
Public Const LOCALE_SMONTHNAME1 = &H38      '  long name for January
Public Const LOCALE_SMONTHNAME2 = &H39      '  long name for February
Public Const LOCALE_SMONTHNAME3 = &H3A      '  long name for March
Public Const LOCALE_SMONTHNAME4 = &H3B      '  long name for April
Public Const LOCALE_SMONTHNAME5 = &H3C      '  long name for May
Public Const LOCALE_SMONTHNAME6 = &H3D      '  long name for June
Public Const LOCALE_SMONTHNAME7 = &H3E      '  long name for July
Public Const LOCALE_SMONTHNAME8 = &H3F      '  long name for August
Public Const LOCALE_SMONTHNAME9 = &H40      '  long name for September
Public Const LOCALE_SMONTHNAME10 = &H41     '  long name for October
Public Const LOCALE_SMONTHNAME11 = &H42     '  long name for November
Public Const LOCALE_SMONTHNAME12 = &H43     '  long name for December
Public Const LOCALE_SABBREVMONTHNAME1 = &H44 '  abbreviated name for January
Public Const LOCALE_SABBREVMONTHNAME2 = &H45 '  abbreviated name for February
Public Const LOCALE_SABBREVMONTHNAME3 = &H46 '  abbreviated name for March
Public Const LOCALE_SABBREVMONTHNAME4 = &H47 '  abbreviated name for April
Public Const LOCALE_SABBREVMONTHNAME5 = &H48 '  abbreviated name for May
Public Const LOCALE_SABBREVMONTHNAME6 = &H49 '  abbreviated name for June
Public Const LOCALE_SABBREVMONTHNAME7 = &H4A '  abbreviated name for July
Public Const LOCALE_SABBREVMONTHNAME8 = &H4B '  abbreviated name for August
Public Const LOCALE_SABBREVMONTHNAME9 = &H4C '  abbreviated name for September
Public Const LOCALE_SABBREVMONTHNAME10 = &H4D '  abbreviated name for October
Public Const LOCALE_SABBREVMONTHNAME11 = &H4E '  abbreviated name for November
Public Const LOCALE_SABBREVMONTHNAME12 = &H4F '  abbreviated name for December
Public Const LOCALE_SABBREVMONTHNAME13 = &H100F

Public Const LOCALE_SYSTEM_DEFAULT& = &H800
Public Const LOCALE_USER_DEFAULT& = &H400

Const cMAXLEN = 255

Private Declare PtrSafe Function apiGetLocaleInfo Lib "kernel32" _
    Alias "GetLocaleInfoA" (ByVal Locale As Long, _
    ByVal LCType As Long, ByVal lpLCData As String, _
    ByVal cchData As Long) As Long

''''
Function CountryName() As String
    
    Dim lngLocale As Long
    Dim strLCData As String, lngData As Long
    Dim lngX As Long
    
    strLCData = String$(cMAXLEN, 0)
    lngData = cMAXLEN - 1
    lngX = apiGetLocaleInfo(LOCALE_USER_DEFAULT, LOCALE_SCOUNTRY, strLCData, lngData)
    
    If lngX <> 0 Then
        CountryName = Left$(strLCData, lngX - 1)
    End If
End Function
''''
Function fLocaleInfo(lngLCType As Long) As String

Dim lngLocale As Long
Dim strLCData As String, lngData As Long
Dim lngX As Long

    strLCData = String$(cMAXLEN, 0)
    lngData = cMAXLEN - 1
    lngX = apiGetLocaleInfo(LOCALE_USER_DEFAULT, lngLCType, strLCData, lngData)
    If lngX <> 0 Then
        fLocaleInfo = Left$(strLCData, lngX - 1)
    End If
End Function

Function fLOCALE_IMEASURE() As String
'  0 = metric, 1 = US

Dim lngLocale As Long
Dim strLCData As String, lngData As Long
Dim lngX As Long

    strLCData = String$(cMAXLEN, 0)
    lngData = cMAXLEN - 1
    lngX = apiGetLocaleInfo(LOCALE_USER_DEFAULT, LOCALE_IMEASURE, strLCData, lngData)
    If lngX <> 0 Then
        fLOCALE_IMEASURE = Left$(strLCData, lngX - 1)
    End If
    
End Function

Function fListseparator() As String

Dim lngLocale As Long
Dim strLCData As String, lngData As Long
Dim lngX As Long

    strLCData = String$(cMAXLEN, 0)
    lngData = cMAXLEN - 1
    lngX = apiGetLocaleInfo(LOCALE_USER_DEFAULT, LOCALE_SLIST, strLCData, lngData)
    If lngX <> 0 Then
        fListseparator = Left$(strLCData, lngX - 1)
    End If
End Function

.

فعند حدث "تحميل النموذج" يتم اضافة اسماء ومسميات الحقول  

 Call List_Table_Fields(Head_1)

فتظهر هكذا

image.png.b66a3ed5be65f33cc531705aec77bcfb.png

.

وعند حدث "عند التركيز" على مربع تحرير وسرد text_1 يتم عمل كود بيانات صفه : 

Private Sub text_1_GotFocus()

    Me.text_1.RowSource = "SELECT " & Me.Head_1 & " FROM Stu_select WHERE stu_code='" & Me.stu_code & "'"
End Sub

.

الى الآن وكل شيء تمام 🙂

ولكن ، ولأن الحقل text_1 غير مرتبط بحقل في الجدول ، فأي قيمة تختارها له ، فإنها ستنطبق على بقية سجلات النموذج المستمر ، 

image.png.b2c55d5682bc52603428b892298833ee.png

.

فيجب عليك معرفة ماذا تريد عمله هنا 🙂

 

جعفر

1425.تحديد عناصر قائمة منسدلة وربطها بأخري.accdb.zip

  • Like 3
محمود أبوسيف

محمود أبوسيف

قام بنشر
  • الكاتب
قام بنشر
في ١٢‏/١٢‏/٢٠٢١ at 19:34, jjafferr said:

الى الآن وكل شيء تمام 🙂

ولكن ، ولأن الحقل text_1 غير مرتبط بحقل في الجدول ، فأي قيمة تختارها له ، فإنها ستنطبق على بقية سجلات النموذج المستمر ، 

image.png.b2c55d5682bc52603428b892298833ee.png

.

فيجب عليك معرفة ماذا تريد عمله هنا 🙂

أريد ربط text_1 بـ Head_1  بحيث عند اختيار أي عنصر (حقل ) من Head_1 تظهر جميع بيانات هذا العنصر ( الحقل ) في text_1

فمثلا لو اخترت ( الصف ) من Head_1 تظهر صفوف جميع التلاميذ في text_1 🙂

jjafferr

jjafferr

قام بنشر
قام بنشر
42 دقائق مضت, محمود أبوسيف said:

فمثلا لو اخترت ( الصف ) من Head_1 تظهر صفوف جميع التلاميذ في text_1 🙂

بس انت سابقا قلت:

في ١٠‏/١٢‏/٢٠٢١ at 18:46, محمود أبوسيف said:

يظهر لي البيانات الخاصة بهذا الحقل فقط في (text_1)

وتكون متوافقة مع بيانات التلميذ

.

 

للتعديل: 

 بدل هاي

    Me.text_1.RowSource = "SELECT " & Me.Head_1 & " FROM Stu_select WHERE stu_code='" & Me.stu_code & "'"




استعمل هاي

    Me.text_1.RowSource = "SELECT " & Me.Head_1 & " FROM Stu_select"

.

جعفر

محمود أبوسيف

محمود أبوسيف

قام بنشر
  • الكاتب
قام بنشر
39 دقائق مضت, jjafferr said:

بس انت سابقا قلت:

.

 

للتعديل: 

 بدل هاي

    Me.text_1.RowSource = "SELECT " & Me.Head_1 & " FROM Stu_select WHERE stu_code='" & Me.stu_code & "'"




استعمل هاي

    Me.text_1.RowSource = "SELECT " & Me.Head_1 & " FROM Stu_select"

.

جعفر

لقد اقتربنا من الحل فبعد الكود الأخير أصبح حقل text_1 يظهر بيانات كل تلميذ علي حدي ويتطلب مني أن أختاره يدويا

والمطلوب هو إظهار البيانات أمام جميع التلاميذ تلقائيا بعد الاختيار من Head_1 مباشرة

 

 

jjafferr

jjafferr

قام بنشر
قام بنشر
19 دقائق مضت, محمود أبوسيف said:

والمطلوب هو إظهار البيانات أمام جميع التلاميذ تلقائيا بعد الاختيار من Head_1 مباشرة

ممكن ولكن بعد ان تقوم بتعديل التالي:

 

في ١٢‏/١٢‏/٢٠٢١ at 21:34, jjafferr said:

ولكن ، ولأن الحقل text_1 غير مرتبط بحقل في الجدول ، فأي قيمة تختارها له ، فإنها ستنطبق على بقية سجلات النموذج المستمر

لذا، يجب عليك ان تجعل هذا الحقل مرتبط بحقل في الجدول

  • تمت الإجابة
jjafferr

jjafferr

قام بنشر
  • تمت الإجابة
قام بنشر

السلام عليكم 🙂

 

1. تم عمل الحقل text_1 في الجدول ،

2. في النموذج ، تم تحويل حقل text_1 الى حقل نص عادي ،

3. لما تختار من القائمة Head_1 ، تظهر لك رسالة تطلب منك التأكيد على ملئ بيانات الحقل text_1 ببيانات الحقل Head_1 ،

 

image.png.6533838211e7e368130e38069104848f.png

.

وهذا هو كود تعبئة البيانات: 

Private Sub Head_1_AfterUpdate()
    
    Dim Msg, Style, Title, Response
    Msg = "ستقوم بتعبأة الحقل" & vbCrLf & _
            " text_1 " & vbCrLf & _
                "ببيانات الطالب من الحقل" & vbCrLf & vbCrLf & _
                    Me.Head_1 & " < " & Me.Head_1.Column(1)
    Style = vbYesNo + vbCritical + vbDefaultButton2    ' Define buttons.
    Title = "هل انت متأكد"    ' Define title.

    Response = MsgBox(Msg, Style, Title)
    If Response = vbYes Then    ' User chose Yes.
    
        DoCmd.SetWarnings False
            mySQL = "UPDATE Stu_select SET text_1 = " & [Forms]![تلاميذ محددين]![Head_1]
            mySQL = mySQL & " WHERE perm3=True"
        
            DoCmd.RunSQL mySQL
        DoCmd.SetWarnings True
        Me.Requery
        
    End If
    

End Sub

 

جعفر

 

1425.تحديد عناصر قائمة منسدلة وربطها بأخري.accdb.zip

  • Like 1
محمود أبوسيف

محمود أبوسيف

قام بنشر
  • الكاتب
قام بنشر
4 ساعات مضت, jjafferr said:

السلام عليكم 🙂

 

1. تم عمل الحقل text_1 في الجدول ،

2. في النموذج ، تم تحويل حقل text_1 الى حقل نص عادي ،

3. لما تختار من القائمة Head_1 ، تظهر لك رسالة تطلب منك التأكيد على ملئ بيانات الحقل text_1 ببيانات الحقل Head_1 ،

 

image.png.6533838211e7e368130e38069104848f.png

.

وهذا هو كود تعبئة البيانات: 

Private Sub Head_1_AfterUpdate()
    
    Dim Msg, Style, Title, Response
    Msg = "ستقوم بتعبأة الحقل" & vbCrLf & _
            " text_1 " & vbCrLf & _
                "ببيانات الطالب من الحقل" & vbCrLf & vbCrLf & _
                    Me.Head_1 & " < " & Me.Head_1.Column(1)
    Style = vbYesNo + vbCritical + vbDefaultButton2    ' Define buttons.
    Title = "هل انت متأكد"    ' Define title.

    Response = MsgBox(Msg, Style, Title)
    If Response = vbYes Then    ' User chose Yes.
    
        DoCmd.SetWarnings False
            mySQL = "UPDATE Stu_select SET text_1 = " & [Forms]![تلاميذ محددين]![Head_1]
            mySQL = mySQL & " WHERE perm3=True"
        
            DoCmd.RunSQL mySQL
        DoCmd.SetWarnings True
        Me.Requery
        
    End If
    

End Sub

 

جعفر

 

1425.تحديد عناصر قائمة منسدلة وربطها بأخري.accdb.zip 99.77 kB · 12 downloads

أشكرك أخي الفاضل علي ماقدمته ولك جزيل التقدير 

هذا هو المطلوب

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.

زائر
اضف رد علي هذا الموضوع....

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
 مشاركة
الذهاب الي قائمه المواضيع

  • تصفح هذا الموضوع مؤخراً   0 اعضاء متواجدين الان

    • لايوجد اعضاء مسجلون يتصفحون هذه الصفحه
×
×
  • اضف...

Important Information

  I accept