نموذج بحث واضافة و تعديل وحذف لشيت اخر

[محمد غطفان]

السلام عليكم

لدي نموذج بحيث و اضافة وتعديل و حذف

البحث و الاضافه تعمل بشكل جيد

لكن التعديل و الحذف لا يعمل الا من خلال نفس الشيت واريده ان اعدل واحذف من شيت اخر بحيث يكون الشيت محدد في الكود

وشكرا

test.xlsm

[سليم حاصبيا]

أولاً اختصار لكود الاضافة

Private Sub CommandButton1_Click()

Dim LR As Integer
Dim i%, bol As Boolean
lrow = Sheet2.Range("C" & Rows.Count).End(xlUp).Row
LR = WorksheetFunction.CountIf(Sheet2.Range("C4:C" & lrow), TextBox1.Value)
    If LR >= 1 Then
      MsgBox "كود الصنف موجود مسبقا"
      Exit Sub
    End If

For i = 1 To 8
    If i = 6 Then i = 7
    If Me.Controls("TextBox" & i) = vbNullString Then
      bol = True
      MsgBox "You Have Empty textbox" & Chr(10) & _
      "I cannot continue"
      Exit Sub
    End If
Next i
    
 If Me.ComboBox6 = vbNullString Then
     bol = True
        MsgBox "You Have Empty Combobox" & Chr(10) & _
      "I cannot continue"
     Exit Sub
 End If
 
 If Not bol Then
      
      With Sheet2.Range("C" & lrow + 1)
        For i = 1 To 8
           If i = 6 Then i = 7
          .Offset(, i - 1) = Me.Controls("TextBox" & i)
           Me.Controls("TextBox" & i) = vbNullString
        Next
         .Offset(, 5) = Me.ComboBox6.Value
         Me.ComboBox6 = vbNullString
      End With
 End If
CheckBox1.Value = False
MsgBox ("تمت الاضافة")

End Sub

Atfan.xlsm

[محمد غطفان]

استاذنا الكبير سليم
شاكر لك جهودك 
استسمحك في تعديل كود التعديل
بحيث يعمل فقط من شيت الاصناف

اما من شيت الرئيسية يقوم بالتعديل على نفس الشيت بحيث يفترض ان يعدل على جدول الاصناف

الذي اريد ان اوضحه ان الكود محتاج توجية الى شيت الاصناف من شيت الرئيسية بحيث يقوم بالبحث عن كود الصنف و تحديد الخليه و التعديل على باقي الصف .

تقبل تحياتي العطره

دمت بخير

[سليم حاصبيا]

الكود المطلوب

Private Sub CommandButton2_Click() 'Ta3dil
Dim lr%, i%
Dim bol As Boolean
Dim Asnaf As Worksheet
Dim F_rg As Range, Where As Range
Dim Ro%, mot

Set Asnaf = Sheets("الاصناف")
lrow = Asnaf.Range("C" & Rows.Count).End(xlUp).Row

If TextBox1.Value = "" Then
  MsgBox ("لا يوجد بيانات للتعديل")
Exit Sub
End If
 mot = TextBox1.Text
 Set Where = Asnaf.Range("C3:C" & lrow)
 Set F_rg = Where.Find(mot, lookat:=1)
 
 If F_rg Is Nothing Then
  MsgBox "I cannot Find: " & Chr(34) & mot & Chr(34) & _
  Chr(10) & "In the column(C)"
   Exit Sub
 End If
 
 Ro = F_rg.Row
 
  With Asnaf.Range("C" & Ro)
        For i = 1 To 8
           If i = 6 Then i = 7
          .Offset(, i - 1) = Me.Controls("TextBox" & i)
         
        Next
         .Offset(, 5) = Me.ComboBox6.Value
         
  End With
 End Sub

 

Atfan_1.xlsm

[محمد غطفان]

الله يعطيك العافيه

شاكر ومقدر لك