كود دمج عدة شيتات اكسيل منفصلة بشيت واحد

[Ahmedghanem19871]

السلام عليكم ورحمة الله وبركاته

هل من طريقة لدمج عدة شيتات اكسيل منفصلة بشيت واحد 

[عبدالفتاح في بي اكسيل]

جرب  هذا  الملف  لعله  يفيدك 

consolidate datat.xls

[Ahmedghanem19871]

عذرا اخي اقصد ملفات اكسيل منفصلة واريد دمجها بملف واحد فقط جديد مع العلم كل الملفات نفس التنسيق

[عبدالفتاح في بي اكسيل]

 عنوان  الموضوع  وطرحك   لم  تقل  ملفات    بناء  عليه  ارفقت طلبك

[Ali Mohamed Ali]

بعد اذن اخى عبد الفتاح ,على الرغم اننا نبهنا كثيراً انه لابد من رفع ملف مدعوم بشرح كافى عن المطلوب فى كل مشاركة وذلك تجنباً لعدم اهدار وقت الأساتذة ولأنه لا يمكن العمل على التخمين ..فيمكنك استخدام هذا الكود

Sub MergeExcelFiles()
    Dim fnameList, fnameCurFile As Variant
    Dim countFiles, countSheets As Integer
    Dim wksCurSheet As Worksheet
    Dim wbkCurBook, wbkSrcBook As Workbook
 
    fnameList = Application.GetOpenFilename(FileFilter:="Microsoft Excel Workbooks (*.xls;*.xlsx;*.xlsm),*.xls;*.xlsx;*.xlsm", Title:="Choose Excel files to merge", MultiSelect:=True)
 
    If (vbBoolean <> VarType(fnameList)) Then
 
        If (UBound(fnameList) > 0) Then
            countFiles = 0
            countSheets = 0
 
            Application.ScreenUpdating = False
            Application.Calculation = xlCalculationManual
 
            Set wbkCurBook = ActiveWorkbook
 
            For Each fnameCurFile In fnameList
                countFiles = countFiles + 1
 
                Set wbkSrcBook = Workbooks.Open(Filename:=fnameCurFile)
 
                For Each wksCurSheet In wbkSrcBook.Sheets
                    countSheets = countSheets + 1
                    wksCurSheet.Copy after:=wbkCurBook.Sheets(wbkCurBook.Sheets.Count)
                Next
 
                wbkSrcBook.Close SaveChanges:=False
 
            Next
 
            Application.ScreenUpdating = True
            Application.Calculation = xlCalculationAutomatic
 
            MsgBox "Processed " & countFiles & " files" & vbCrLf & "Merged " & countSheets & " worksheets", Title:="Merge Excel files"
        End If
 
    Else
        MsgBox "No files selected", Title:="Merge Excel files"
    End If
End Sub

كما يمكنك الإستعانة بهذا الفيديو

COMBINE Multiple Excel WORKBOOKS into One | ExcelJunction.com

كما يمكنك استخدام هذا الكود أيضاً

Sub ConslidateWorkbooks()
'Created by Sumit Bansal from https://trumpexcel.com
Dim FolderPath As String
Dim Filename As String
Dim Sheet As Worksheet
Application.ScreenUpdating = False
FolderPath = Environ("userprofile") & "DesktopTest"
Filename = Dir(FolderPath & "*.xls*")
Do While Filename <> ""
 Workbooks.Open Filename:=FolderPath & Filename, ReadOnly:=True
 For Each Sheet In ActiveWorkbook.Sheets
 Sheet.Copy After:=ThisWorkbook.Sheets(1)
 Next Sheet
 Workbooks(Filename).Close
 Filename = Dir()
Loop
Application.ScreenUpdating = True
End Sub

وهذا أيضاً كود ثالث لطلبك

Sub mergeFiles()
    'Merges all files in a folder to a main file.
    
    'Define variables:
    Dim numberOfFilesChosen, i As Integer
    Dim tempFileDialog As fileDialog
    Dim mainWorkbook, sourceWorkbook As Workbook
    Dim tempWorkSheet As Worksheet
    
    Set mainWorkbook = Application.ActiveWorkbook
    Set tempFileDialog = Application.fileDialog(msoFileDialogFilePicker)
    
    'Allow the user to select multiple workbooks
    tempFileDialog.AllowMultiSelect = True
    
    numberOfFilesChosen = tempFileDialog.Show
    
    'Loop through all selected workbooks
    For i = 1 To tempFileDialog.SelectedItems.Count
        
        'Open each workbook
        Workbooks.Open tempFileDialog.SelectedItems(i)
        
        Set sourceWorkbook = ActiveWorkbook
        
        'Copy each worksheet to the end of the main workbook
        For Each tempWorkSheet In sourceWorkbook.Worksheets
            tempWorkSheet.Copy after:=mainWorkbook.Sheets(mainWorkbook.Worksheets.Count)
        Next tempWorkSheet
        
        'Close the source workbook
        sourceWorkbook.Close
    Next i
    
End Sub

وفى هذا الرابط ايضاً عدة أكواد ستفيدك فى طلبك

How to combine multiple workbooks into one master workbook in Excel?

[Ahmedghanem19871]

استاذ علي

شكرا لاهتمامك

ولكن يجب التوضيح

انه لايوجد ملف حيث انني اريد دمج بيانات ملفات اكسيل بملف واحد وليس دمج شيتات او تبويبات بملف اكسيل واحد بشيت واحد او تبويب واحد

فعندي فولدر به ملفات اكسيل اريد وضعها بملف واحد

جزاك الله خير استاذ عبدالفتاح لاهتمامك وعفوا ان اخطأت في صياغة العنوان

[أحمد يوسف]

Ahmedghanem198

أين انت من كل هذه الأكواد والإجابات الممتازة ؟!!!

أين الضغط على الإعجاب ؟!!!💙