أخي لو ارفقت مثال للمطلوب كان اسرع في حصولك للاجابة ... على العموم
انت صدرت الجداول وتحتاج تصدير للعلاقات جرب الكود التالي لتصدير العلاقات أو ارفق مثال للتجربة ....
Function ExportRelations(DbName As String) As Integer
Dim ThisDb As DAO.Database, ThatDB As DAO.Database
Dim ThisRel As DAO.Relation, ThatRel As DAO.Relation
Dim ThisField As DAO.Field, ThatField As DAO.Field
Dim Cr As String, i As Integer, cnt As Integer, RCount As Integer
Dim j As Integer
Dim ErrBadField As Integer
Cr$ = Chr$(13)
RCount = 0
Set ThisDb = DBEngine.Workspaces(0).OpenDatabase("C:\mydat.mdb")
Set ThatDB = DBEngine.Workspaces(0).OpenDatabase(DbName$)
For i = 0 To ThatDB.Relations.Count - 1
Set ThatRel = ThatDB.Relations(i)
Set ThisRel = ThisDb.CreateRelation(ThatRel.Name, _
ThatRel.Table, ThatRel.ForeignTable, ThatRel.Attributes)
ErrBadField = False
For j = 0 To ThatRel.Fields.Count - 1
Set ThatField = ThatRel.Fields(j)
Set ThisField = ThisRel.CreateField(ThatField.Name)
ThisField.ForeignName = ThatField.ForeignName
On Error Resume Next
ThisRel.Fields.Append ThisField
If Err <> False Then ErrBadField = True
On Error GoTo 0
Next j
If ErrBadField = True Then
Else
On Error Resume Next
ThisDb.Relations.Append ThisRel
If Err <> False Then
Else
RCount = RCount + 1
End If
On Error GoTo 0
End If
Next i
ThisDb.Close
ThatDB.Close
ExportRelations = RCount
End Function
وتستدعيها بالكود التالي ...
Call ExportRelations("C:\ExpAndImp.mdb")
C:\ExpAndImp.mdb هي مسار القاعدة المصدر منها العلاقات ....
جرب وأعلمنا بالنتيجة !!!!!!